git.iko.soy/unity8
on 84064e5 help sign in
unity8/qml/Components/PageHeader.qml
325 lines 11 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.2
18import Ubuntu.Components 1.1
19import Ubuntu.Components.Themes.Ambiance 1.1
20import Ubuntu.Components.Popups 1.0
21import Ubuntu.Components.ListItems 1.0
22import "SearchHistoryModel"
24Item {
25 id: root
26 objectName: "pageHeader"
27 implicitHeight: headerContainer.height + units.gu(2) + bottomContainer.height
29 property bool showBackButton: false
30 property string title
32 property bool searchEntryEnabled: false
33 property ListModel searchHistory: SearchHistoryModel
34 property alias searchQuery: searchTextField.text
35 property bool searchInProgress: false
37 property alias bottomItem: bottomContainer.children
39 // TODO We should use foreground for the icons
40 // of the toolbar but unfortunately Action does not have
41 // the keyColor property as Icon does :-/
42 property var scopeStyle: null
44 signal backClicked()
46 onScopeStyleChanged: refreshLogo()
48 function triggerSearch() {
49 if (searchEntryEnabled) {
50 headerContainer.showSearch = true;
51 searchTextField.forceActiveFocus();
52 }
53 }
55 function resetSearch(keepFocus) {
56 if (searchHistory) {
57 searchHistory.addQuery(searchTextField.text);
58 }
59 if (!keepFocus) {
60 unfocus();
61 }
62 searchTextField.text = "";
63 if (headerContainer.popover != null) {
64 PopupUtils.close(headerContainer.popover);
65 }
66 }
68 function unfocus() {
69 searchTextField.focus = false;
70 if (!searchTextField.text) {
71 headerContainer.showSearch = false;
72 }
73 }
75 function openSearchHistory() {
76 if (openSearchAnimation.running) {
77 openSearchAnimation.openSearchHistory = true;
78 } else if (root.searchHistory.count > 0 && headerContainer.popover == null) {
79 headerContainer.popover = PopupUtils.open(popoverComponent, searchTextField,
80 {
81 "contentWidth": searchTextField.width,
82 "edgeMargins": units.gu(1)
83 }
84 );
85 }
86 }
88 function refreshLogo() {
89 if (scopeStyle ? scopeStyle.headerLogo != "" : false) {
90 header.contents = imageComponent.createObject();
91 } else if (header.contents) {
92 header.contents.destroy();
93 header.contents = null;
94 }
95 }
97 Connections {
98 target: root.scopeStyle
99 onHeaderLogoChanged: root.refreshLogo()
100 }
102 InverseMouseArea {
103 anchors { fill: parent; margins: units.gu(1); bottomMargin: units.gu(3) + bottomContainer.height }
104 visible: headerContainer.showSearch
105 onPressed: {
106 if (headerContainer.popover) {
107 PopupUtils.close(headerContainer.popover);
108 }
109 if (!searchTextField.text) {
110 headerContainer.showSearch = false;
111 }
112 searchTextField.focus = false;
113 mouse.accepted = false;
114 }
115 }
117 Flickable {
118 id: headerContainer
119 objectName: "headerContainer"
120 clip: true
121 anchors { left: parent.left; top: parent.top; right: parent.right }
122 height: units.gu(6.5)
123 contentHeight: headersColumn.height
124 interactive: false
125 contentY: showSearch ? 0 : height
127 property bool showSearch: false
128 property var popover: null
130 Background {
131 objectName: "headerBackground"
132 style: scopeStyle.headerBackground
133 }
135 Behavior on contentY {
136 UbuntuNumberAnimation {
137 id: openSearchAnimation
138 property bool openSearchHistory: false
140 onRunningChanged: {
141 if (!running && openSearchAnimation.openSearchHistory) {
142 openSearchAnimation.openSearchHistory = false;
143 root.openSearchHistory();
144 }
145 }
146 }
147 }
149 Column {
150 id: headersColumn
151 anchors { left: parent.left; right: parent.right }
153 PageHeadStyle {
154 id: searchHeader
155 anchors { left: parent.left; right: parent.right }
156 height: headerContainer.height
157 contentHeight: height
158 separatorSource: ""
159 // Required to keep PageHeadStyle noise down as it expects the Page's properties around.
160 property var styledItem: searchHeader
161 property string title
162 property var config: PageHeadConfiguration {
163 backAction: Action {
164 iconName: "back"
165 onTriggered: {
166 root.resetSearch();
167 headerContainer.showSearch = false;
168 }
169 }
170 }
171 property var contents: TextField {
172 id: searchTextField
173 objectName: "searchTextField"
174 hasClearButton: false
175 anchors {
176 fill: parent
177 leftMargin: units.gu(1)
178 topMargin: units.gu(1)
179 bottomMargin: units.gu(1)
180 rightMargin: root.width > units.gu(60) ? root.width - units.gu(40) : units.gu(1)
181 }
183 secondaryItem: AbstractButton {
184 height: searchTextField.height
185 width: height
186 enabled: searchTextField.text.length > 0
188 Image {
189 objectName: "clearIcon"
190 anchors.fill: parent
191 anchors.margins: units.gu(.75)
192 source: "image://theme/clear"
193 opacity: searchTextField.text.length > 0
194 visible: opacity > 0
195 Behavior on opacity {
196 UbuntuNumberAnimation { duration: UbuntuAnimation.FastDuration }
197 }
198 }
200 onClicked: {
201 root.resetSearch(true);
202 root.openSearchHistory();
203 }
204 }
206 onActiveFocusChanged: {
207 if (activeFocus) {
208 root.openSearchHistory();
209 }
210 }
211 }
212 }
214 PageHeadStyle {
215 id: header
216 objectName: "innerPageHeader"
217 anchors { left: parent.left; right: parent.right }
218 height: headerContainer.height
219 contentHeight: height
220 separatorSource: ""
221 textColor: root.scopeStyle ? root.scopeStyle.headerForeground : "grey"
222 property var styledItem: header
223 property string title: root.title
224 property var config: PageHeadConfiguration {
225 backAction: Action {
226 iconName: "back"
227 visible: root.showBackButton
228 onTriggered: {
229 root.backClicked();
230 }
231 }
233 actions: [
234 Action {
235 iconName: "search"
236 visible: root.searchEntryEnabled
237 onTriggered: {
238 headerContainer.showSearch = true;
239 searchTextField.forceActiveFocus();
240 }
241 }
242 ]
243 }
245 property var contents: null
246 Component.onCompleted: root.refreshLogo()
248 Component {
249 id: imageComponent
251 Item {
252 anchors { fill: parent; topMargin: units.gu(1); bottomMargin: units.gu(1) }
253 clip: true
254 Image {
255 objectName: "titleImage"
256 anchors.fill: parent
257 source: root.scopeStyle ? root.scopeStyle.headerLogo : ""
258 fillMode: Image.PreserveAspectFit
259 horizontalAlignment: Image.AlignLeft
260 sourceSize.height: height
261 }
262 }
263 }
264 }
265 }
266 }
268 Component {
269 id: popoverComponent
270 Popover {
271 id: popover
272 autoClose: false
274 Component.onDestruction: {
275 headerContainer.popover = null;
276 }
278 Column {
279 anchors {
280 top: parent.top
281 left: parent.left
282 right: parent.right
283 }
285 Repeater {
286 id: recentSearches
287 model: searchHistory
289 delegate: Standard {
290 showDivider: index < recentSearches.count - 1
291 text: query
292 onClicked: {
293 searchHistory.addQuery(text);
294 searchTextField.text = text;
295 PopupUtils.close(popover);
296 }
297 }
298 }
299 }
300 }
301 }
303 Rectangle {
304 id: bottomBorder
305 anchors {
306 top: headerContainer.bottom
307 left: parent.left
308 right: parent.right
309 bottom: bottomContainer.top
310 }
312 color: "#d7d7d7"
313 }
315 Item {
316 id: bottomContainer
318 anchors {
319 left: parent.left
320 right: parent.right
321 bottom: parent.bottom
322 }
323 height: childrenRect.height
324 }