git.iko.soy/unity8
on 8d0601f help sign in
unity8/Greeter/Greeter.qml
123 lines 3.8 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Components 0.1
19import Ubuntu.Gestures 0.1
20import LightDM 0.1 as LightDM
21import "../Components"
22import "../Components/Math.js" as MathLocal
24Showable {
25 id: greeter
26 enabled: shown
27 created: greeterContentLoader.status == Loader.Ready && greeterContentLoader.item.ready
29 // 1 when fully shown and 0 when fully hidden
30 property real showProgress: MathLocal.clamp((width + x) / width, 0, 1)
32 showAnimation: StandardAnimation { property: "x"; to: 0 }
33 hideAnimation: StandardAnimation { property: "x"; to: -width }
35 property alias dragHandleWidth: dragHandle.width
36 property alias model: greeterContentLoader.model
37 property bool locked: shown && !LightDM.Greeter.promptless
39 readonly property bool narrowMode: !multiUser && width <= units.gu(60)
40 readonly property bool multiUser: LightDM.Users.count > 1
42 readonly property bool leftTeaserPressed: greeterContentLoader.status == Loader.Ready &&
43 greeterContentLoader.item.leftTeaserPressed
44 readonly property bool rightTeaserPressed: greeterContentLoader.status == Loader.Ready &&
45 greeterContentLoader.item.rightTeaserPressed
47 readonly property int currentIndex: greeterContentLoader.currentIndex
49 signal selected(int uid)
50 signal unlocked(int uid)
52 onRightTeaserPressedChanged: {
53 if (rightTeaserPressed && !locked) {
54 teasingTimer.start();
55 }
56 }
58 Loader {
59 id: greeterContentLoader
60 objectName: "greeterContentLoader"
61 anchors.fill: parent
62 property var model: LightDM.Users
63 property int currentIndex: 0
64 property var infographicModel: LightDM.Infographic
66 source: required ? "GreeterContent.qml" : ""
68 Connections {
69 target: greeterContentLoader.item
71 onSelected: {
72 greeter.selected(uid);
73 greeterContentLoader.currentIndex = uid;
74 }
75 onUnlocked: greeter.unlocked(uid);
76 }
77 }
79 Timer {
80 id: teasingTimer
81 interval: 200
82 }
84 states: [
85 State {
86 name: "teasing"
87 when: teasingTimer.running
88 PropertyChanges {
89 target: greeter
90 x: -units.gu(2)
91 }
92 }
93 ]
94 transitions: [
95 Transition {
96 from: "*"
97 to: "*"
98 NumberAnimation {
99 target: greeter
100 property: "x"
101 duration: 300
102 easing.type: Easing.OutCubic
103 }
104 }
105 ]
107 DragHandle {
108 id: dragHandle
110 anchors.top: parent.top
111 anchors.bottom: parent.bottom
112 anchors.right: parent.right
114 // no need for requiring a directional drag since we are covering the screen
115 // anyway (i.e., no change user could be trying to interact with some other
116 // UI element)
117 distanceThreshold: 0
119 enabled: greeter.narrowMode || !greeter.locked
121 direction: Direction.Leftwards
122 }