git.iko.soy/unity8
on 8d0d15c help sign in
unity8/Components/ResponsiveGridView.qml
82 lines 3.2 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Components 0.1
20/*
21 Essentially a GridView where you can specify the maximum number of columns it can have.
22 */
23Item {
24 property int minimumHorizontalSpacing: units.gu(0.5)
25 // property int minimumNumberOfColumns: 2 // FIXME: not implemented
26 property int maximumNumberOfColumns: 6
27 readonly property int columns: gridView.columns
28 property alias verticalSpacing: gridView.verticalSpacing
29 property int delegateWidth
30 property int delegateHeight
31 property alias model: gridView.model
32 property alias delegate: gridView.delegate
33 readonly property int cellWidth: gridView.cellWidth
34 readonly property int cellHeight: gridView.cellHeight
35 readonly property int totalContentHeight: {
36 return contentHeightForRows(Math.ceil(gridView.model.count / columns))
37 }
38 property alias interactive: gridView.interactive
39 readonly property alias flicking: gridView.flicking
40 readonly property alias moving: gridView.moving
41 readonly property alias pressDelay: gridView.pressDelay
43 function contentHeightForRows(rows) {
44 return rows * cellHeight + verticalSpacing
45 }
47 GridView {
48 id: gridView
49 objectName: "responsiveGridViewGrid"
50 anchors {
51 fill: parent
52 leftMargin: margin/2
53 rightMargin: margin/2
54 topMargin: verticalSpacing
55 }
56 clip: parent.height != totalContentHeight
58 function pixelToGU(value) {
59 return Math.floor(value / units.gu(1));
60 }
62 function spacingForColumns(columns) {
63 // spacing between columns as an integer number of GU, the remainder goes in the margins
64 var spacingGU = pixelToGU(allocatableHorizontalSpace / columns);
65 return units.gu(spacingGU);
66 }
68 function columnsForSpacing(spacing) {
69 // minimum margin is half of the spacing
70 return Math.floor((parent.width - spacing/2) / (delegateWidth + spacing));
71 }
73 property real allocatableHorizontalSpace: parent.width - columns * delegateWidth
74 property int columns: Math.min(columnsForSpacing(minimumHorizontalSpacing), maximumNumberOfColumns)
75 property real horizontalSpacing: spacingForColumns(columns)
76 property real verticalSpacing: horizontalSpacing
77 property int margin: allocatableHorizontalSpace - columns * horizontalSpacing
79 cellWidth: delegateWidth + horizontalSpacing
80 cellHeight: delegateHeight + verticalSpacing
81 }