git.iko.soy/unity8
on 90a8f00 help sign in
unity8/qml/Notifications/Notification.qml
534 lines 19 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import QtMultimedia 5.0
19import Ubuntu.Components 1.1
20import Unity.Notifications 1.0
21import QMenuModel 0.1
22import Utils 0.1
24import Ubuntu.Components.ListItems 0.1 as ListItem
26Item {
27 id: notification
29 property alias iconSource: icon.fileSource
30 property alias secondaryIconSource: secondaryIcon.source
31 property alias summary: summaryLabel.text
32 property alias body: bodyLabel.text
33 property var actions
34 property var notificationId
35 property var type
36 property var hints
37 property var notification
38 property color color
39 property bool fullscreen: false
40 property int maxHeight
41 property int margins
42 readonly property color red: "#fc4949"
43 readonly property color green: "#3fb24f"
44 readonly property color sdLightGrey: "#eaeaea"
45 readonly property color sdDarkGrey: "#dddddd"
46 readonly property color sdFontColor: "#5d5d5d"
47 readonly property real contentSpacing: units.gu(2)
49 objectName: "background"
50 implicitHeight: type !== Notification.PlaceHolder ? (fullscreen ? maxHeight : outterColumn.height + contentSpacing * 2) : 0
52 color: type == Notification.SnapDecision ? sdLightGrey : Qt.rgba(0.132, 0.117, 0.109, 0.97)
53 opacity: 1
55 state: {
56 var result = "";
58 if (type == Notification.SnapDecision) {
59 if (ListView.view.currentIndex == index) {
60 result = "expanded";
61 } else {
62 if (ListView.view.count > 2) {
63 if (ListView.view.currentIndex == -1 && index == 1) {
64 result = "expanded";
65 } else {
66 result = "contracted";
67 }
68 } else {
69 result = "expanded";
70 }
71 }
72 }
74 return result;
75 }
77 Audio {
78 id: sound
79 objectName: "sound"
80 source: hints["suppress-sound"] != "true" && hints["sound-file"] != undefined ? hints["sound-file"] : ""
81 }
83 onOpacityChanged: {
84 if (opacity == 1.0 && hints["suppress-sound"] != "true" && sound.source) {
85 sound.play();
86 }
87 }
89 Behavior on height {
90 id: normalHeightBehavior
92 //enabled: menuItemFactory.progress == 1
93 enabled: true
94 SequentialAnimation {
95 PauseAnimation {
96 duration: UbuntuAnimation.SnapDuration
97 }
98 UbuntuNumberAnimation {
99 duration: UbuntuAnimation.SnapDuration
100 }
101 }
102 }
104 states:[
105 State {
106 name: "contracted"
107 PropertyChanges {target: notification; height: units.gu(10)}
108 },
109 State {
110 name: "expanded"
111 PropertyChanges {target: notification; height: implicitHeight}
112 }
113 ]
115 clip: fullscreen ? false : true
117 visible: type != Notification.PlaceHolder
119 UbuntuShape {
120 id: shapedBack
122 visible: !fullscreen
123 anchors {
124 fill: parent
125 leftMargin: notification.margins
126 rightMargin: notification.margins
127 }
128 color: parent.color
129 opacity: parent.opacity
130 radius: "medium"
131 }
133 Rectangle {
134 id: nonShapedBack
136 visible: fullscreen
137 anchors.fill: parent
138 color: parent.color
139 opacity: parent.opacity
140 }
142 Item {
143 id: contents
144 anchors.fill: fullscreen ? nonShapedBack : shapedBack
146 UnityMenuModelPaths {
147 id: paths
149 source: hints["x-canonical-private-menu-model"]
151 busNameHint: "busName"
152 actionsHint: "actions"
153 menuObjectPathHint: "menuPath"
154 }
156 UnityMenuModel {
157 id: unityMenuModel
159 property string lastNameOwner: ""
161 busName: paths.busName
162 actions: paths.actions
163 menuObjectPath: paths.menuObjectPath
164 onNameOwnerChanged: {
165 if (lastNameOwner != "" && nameOwner == "" && notification.notification != undefined) {
166 notification.notification.close()
167 }
168 lastNameOwner = nameOwner
169 }
170 }
172 Behavior on implicitHeight {
173 id: heightBehavior
175 enabled: false
176 UbuntuNumberAnimation {
177 duration: UbuntuAnimation.SnapDuration
178 }
179 }
181 // delay enabling height behavior until the add transition is complete
182 onOpacityChanged: if (opacity == 1) heightBehavior.enabled = true
184 MouseArea {
185 id: interactiveArea
187 anchors.fill: parent
188 objectName: "interactiveArea"
189 onClicked: {
190 if (notification.type == Notification.Interactive) {
191 notification.notification.invokeAction(actionRepeater.itemAt(0).actionId)
192 } else {
193 notificationList.currentIndex = index;
194 }
195 }
196 }
198 Column {
199 id: outterColumn
201 anchors {
202 left: parent.left
203 right: parent.right
204 top: parent.top
205 margins: 0
206 topMargin: units.gu(2)
207 }
209 spacing: units.gu(2)
211 Row {
212 id: topRow
214 spacing: contentSpacing
215 anchors {
216 left: parent.left
217 right: parent.right
218 margins: contentSpacing
219 }
221 ShapedIcon {
222 id: icon
224 objectName: "icon"
225 width: type == Notification.Ephemeral && !bodyLabel.visible ? units.gu(3) : units.gu(6)
226 height: width
227 shaped: notification.hints["x-canonical-non-shaped-icon"] == "true" ? false : true
228 visible: iconSource !== undefined && iconSource != ""
229 }
231 Column {
232 id: labelColumn
233 width: secondaryIcon.visible ? parent.width - x - units.gu(4.5) : parent.width - x
235 anchors.verticalCenter: (icon.visible && !bodyLabel.visible) ? icon.verticalCenter : undefined
237 Label {
238 id: summaryLabel
240 objectName: "summaryLabel"
241 anchors {
242 left: parent.left
243 right: parent.right
244 }
245 fontSize: "medium"
246 color: type == Notification.SnapDecision ? sdFontColor : Theme.palette.selected.backgroundText
247 elide: Text.ElideRight
248 textFormat: Text.PlainText
249 }
251 Label {
252 id: bodyLabel
254 objectName: "bodyLabel"
255 anchors {
256 left: parent.left
257 right: parent.right
258 }
259 visible: body != ""
260 fontSize: "small"
261 color: type == Notification.SnapDecision ? sdFontColor : Theme.palette.selected.backgroundText
262 wrapMode: Text.WordWrap
263 maximumLineCount: 2
264 elide: Text.ElideRight
265 textFormat: Text.PlainText
266 }
267 }
269 Image {
270 id: secondaryIcon
272 objectName: "secondaryIcon"
273 width: units.gu(3)
274 height: units.gu(3)
275 visible: status === Image.Ready
276 fillMode: Image.PreserveAspectCrop
277 }
278 }
280 ListItem.ThinDivider {
281 visible: type == Notification.SnapDecision
282 }
284 Column {
285 id: dialogColumn
286 objectName: "dialogListView"
287 spacing: units.gu(2)
289 visible: count > 0
291 anchors {
292 left: parent.left
293 right: parent.right
294 top: fullscreen ? parent.top : undefined
295 bottom: fullscreen ? parent.bottom : undefined
296 }
298 Repeater {
299 model: unityMenuModel
301 NotificationMenuItemFactory {
302 id: menuItemFactory
304 anchors {
305 left: dialogColumn.left
306 right: dialogColumn.right
307 }
309 menuModel: unityMenuModel
310 menuData: model
311 menuIndex: index
312 maxHeight: notification.maxHeight
314 onLoaded: {
315 notification.fullscreen = Qt.binding(function() { return fullscreen; });
316 }
317 onAccepted: {
318 notification.notification.invokeAction(actionRepeater.itemAt(0).actionId)
319 }
320 }
321 }
322 }
324 Column {
325 id: oneOverTwoCase
327 anchors {
328 left: parent.left
329 right: parent.right
330 margins: contentSpacing
331 }
333 spacing: contentSpacing
335 visible: notification.type == Notification.SnapDecision && oneOverTwoRepeaterTop.count == 3
337 Repeater {
338 id: oneOverTwoRepeaterTop
340 model: notification.actions
341 delegate: Loader {
342 id: oneOverTwoLoaderTop
344 property string actionId: id
345 property string actionLabel: label
347 Component {
348 id: oneOverTwoButtonTop
350 Button {
351 objectName: "notify_oot_button" + index
352 width: oneOverTwoCase.width
353 text: oneOverTwoLoaderTop.actionLabel
354 color: notification.hints["x-canonical-private-affirmative-tint"] == "true" ? green : sdDarkGrey
355 onClicked: notification.notification.invokeAction(oneOverTwoLoaderTop.actionId)
356 }
357 }
358 sourceComponent: index == 0 ? oneOverTwoButtonTop : undefined
359 }
360 }
362 Row {
363 spacing: contentSpacing
365 Repeater {
366 id: oneOverTwoRepeaterBottom
368 model: notification.actions
369 delegate: Loader {
370 id: oneOverTwoLoaderBottom
372 property string actionId: id
373 property string actionLabel: label
375 Component {
376 id: oneOverTwoButtonBottom
378 Button {
379 objectName: "notify_oot_button" + index
380 width: oneOverTwoCase.width / 2 - spacing * 2
381 text: oneOverTwoLoaderBottom.actionLabel
382 color: index == 1 && notification.hints["x-canonical-private-rejection-tint"] == "true" ? red : sdDarkGrey
383 onClicked: notification.notification.invokeAction(oneOverTwoLoaderBottom.actionId)
384 }
385 }
386 sourceComponent: (index == 1 || index == 2) ? oneOverTwoButtonBottom : undefined
387 }
388 }
389 }
390 }
392 Row {
393 id: buttonRow
395 objectName: "buttonRow"
396 anchors {
397 left: parent.left
398 right: parent.right
399 margins: contentSpacing
400 }
401 visible: notification.type == Notification.SnapDecision && actionRepeater.count > 0 && !oneOverTwoCase.visible
402 spacing: units.gu(2)
403 layoutDirection: Qt.RightToLeft
405 Repeater {
406 id: actionRepeater
408 model: notification.actions
409 delegate: Loader {
410 id: loader
412 property string actionId: id
413 property string actionLabel: label
415 Component {
416 id: actionButton
418 Button {
419 objectName: "notify_button" + index
420 width: buttonRow.width / 2 - spacing*2
421 text: loader.actionLabel
422 color: {
423 var result = sdDarkGrey;
424 if (index == 0 && notification.hints["x-canonical-private-affirmative-tint"] == "true") {
425 result = green;
426 }
427 if (index == 1 && notification.hints["x-canonical-private-rejection-tint"] == "true") {
428 result = red;
429 }
430 return result;
431 }
432 onClicked: notification.notification.invokeAction(loader.actionId)
433 }
434 }
435 sourceComponent: (index == 0 || index == 1) ? actionButton : undefined
436 }
437 }
438 }
440 ComboButton {
441 id: comboButton
443 objectName: "notify_button2"
444 width: parent.width
445 anchors {
446 left: parent.left
447 right: parent.right
448 margins: contentSpacing
449 }
451 visible: notification.type == Notification.SnapDecision && actionRepeater.count > 3 && !oneOverTwoCase.visible
452 color: sdDarkGrey
453 onClicked: notification.notification.invokeAction(comboRepeater.itemAt(2).actionId)
454 expanded: false
455 expandedHeight: (comboRepeater.count - 2) * units.gu(4) + units.gu(.5)
456 comboList: Flickable {
457 // this has to be wrapped inside a flickable
458 // to work around a feature/bug? of the
459 // ComboButton SDK-element, making a regular
460 // unwrapped Column item flickable
461 // see LP: #1332590
462 interactive: false
463 Column {
464 Repeater {
465 id: comboRepeater
467 onVisibleChanged: {
468 comboButton.text = comboRepeater.count >= 3 ? comboRepeater.itemAt(2).actionLabel : ""
469 }
471 model: notification.actions
472 delegate: Loader {
473 id: comboLoader
475 asynchronous: true
476 visible: status == Loader.Ready
477 property string actionId: id
478 property string actionLabel: label
479 readonly property var splitLabel: actionLabel.match(/(^([-a-z0-9]+):)?(.*)$/)
480 Component {
481 id: comboEntry
483 MouseArea {
484 id: comboInputArea
486 objectName: "notify_button" + index
487 width: comboButton.width
488 height: comboIcon.height + units.gu(2)
490 onClicked: {
491 notification.notification.invokeAction(actionId)
492 }
494 ListItem.ThinDivider {
495 visible: index > 3
496 }
498 Icon {
499 id: comboIcon
501 anchors {
502 left: parent.left
503 leftMargin: units.gu(.5)
504 verticalCenter: parent.verticalCenter
505 }
506 width: units.gu(2)
507 height: units.gu(2)
508 color: sdFontColor
509 name: splitLabel[2]
510 }
512 Label {
513 id: comboLabel
515 anchors {
516 left: comboIcon.right
517 leftMargin: units.gu(1)
518 verticalCenter: comboIcon.verticalCenter
519 }
520 fontSize: "small"
521 color: sdFontColor
522 text: splitLabel[3]
523 }
524 }
525 }
526 sourceComponent: (index > 2) ? comboEntry : undefined
527 }
528 }
529 }
530 }
531 }
532 }
533 }