git.iko.soy/unity8
on 9e7d210 help sign in
unity8/qml/Stages/WindowControlsOverlay.qml
213 lines 7.6 kB history raw
1/*
2 * Copyright (C) 2016 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import Ubuntu.Gestures 0.1
20import Unity.Application 0.1
21import "../Components/PanelState"
23Item {
24 id: root
26 // to be set from outside
27 property Item target // appDelegate
29 readonly property bool overlayShown: overlay.visible
31 TouchGestureArea {
32 id: gestureArea
33 anchors.fill: parent
35 // NB: for testing set to 2, not to clash with unity7 touch overlay controls
36 minimumTouchPoints: 3
37 maximumTouchPoints: minimumTouchPoints
38 releaseRejectPeriod: 500
40 readonly property bool recognizedPress: status == TouchGestureArea.Recognized &&
41 touchPoints.length >= minimumTouchPoints &&
42 touchPoints.length <= maximumTouchPoints
43 onRecognizedPressChanged: {
44 if (recognizedPress && target && !target.fullscreen) {
45 overlayTimer.start();
46 }
47 }
49 readonly property bool recognizedDrag: recognizedPress && dragging
50 onRecognizedDragChanged: {
51 if (recognizedDrag) {
52 priv.handlePressedChanged(true, tp.x, tp.y);
53 } else if (!moveHandler.containsPress) { // prevent interfering with the central piece drag/move
54 priv.dragging = false;
55 }
56 }
58 readonly property point tp: recognizedPress ? Qt.point(touchPoints[0].x, touchPoints[0].y) : Qt.point(-1, -1)
59 onUpdated: {
60 if (recognizedDrag) {
61 priv.handlePositionChanged(tp.x, tp.y);
62 }
63 }
64 }
66 // dismiss timer
67 Timer {
68 id: overlayTimer
69 interval: 2000
70 repeat: priv.dragging || (priv.resizeArea && priv.resizeArea.dragging)
71 }
73 QtObject {
74 id: priv
75 property real distanceX
76 property real distanceY
77 property bool dragging
79 readonly property var resizeArea: root.target && root.target.resizeArea ? root.target.resizeArea : null
81 function handlePressedChanged(pressed, mouseX, mouseY) {
82 if (pressed) {
83 var pos = mapToItem(root.target, mouseX, mouseY);
84 priv.distanceX = pos.x;
85 priv.distanceY = pos.y;
86 priv.dragging = true;
87 } else {
88 priv.dragging = false;
89 }
90 }
92 function handlePositionChanged(mouseX, mouseY) {
93 if (priv.dragging) {
94 var pos = mapToItem(root.target.parent, mouseX, mouseY);
95 root.target.x = Math.round(pos.x - priv.distanceX);
96 root.target.y = Math.round(Math.max(pos.y - priv.distanceY, PanelState.panelHeight));
97 }
98 }
99 }
101 // the visual overlay
102 Item {
103 id: overlay
104 objectName: "windowControlsOverlay"
105 anchors.fill: parent
106 enabled: target && overlayTimer.running
107 visible: opacity > 0
108 opacity: enabled ? 0.95 : 0
110 Behavior on opacity {
111 UbuntuNumberAnimation {}
112 }
114 readonly property bool anyMaximized: target && (target.maximized || target.maximizedLeft || target.maximizedRight)
116 Image {
117 source: "graphics/arrows-centre.png"
118 width: units.gu(10)
119 height: width
120 sourceSize: Qt.size(width, height)
121 anchors.centerIn: parent
122 opacity: 0.95
123 visible: target && target.width > units.gu(12) && target.height > units.gu(12)
125 // move handler
126 MouseArea {
127 id: moveHandler
128 anchors.fill: parent
129 visible: overlay.visible
130 enabled: visible
131 hoverEnabled: true
132 cursorShape: priv.dragging ? Qt.ClosedHandCursor : (overlay.visible ? Qt.OpenHandCursor : Qt.ArrowCursor)
134 onPressedChanged: priv.handlePressedChanged(pressed, mouseX, mouseY)
135 onPositionChanged: priv.handlePositionChanged(mouseX, mouseY)
136 }
138 // dismiss area
139 InverseMouseArea {
140 anchors.fill: parent
141 visible: overlay.visible
142 enabled: visible
143 onPressed: {
144 overlayTimer.stop();
145 mouse.accepted = false;
146 }
147 propagateComposedEvents: true
148 }
149 }
151 ResizeGrip { // top left
152 anchors.horizontalCenter: parent.left
153 anchors.verticalCenter: parent.top
154 visible: target && !overlay.anyMaximized && !target.maximizedHorizontally && !target.maximizedVertically
155 resizeTarget: priv.resizeArea
156 }
158 ResizeGrip { // top center
159 anchors.horizontalCenter: parent.horizontalCenter
160 anchors.verticalCenter: parent.top
161 rotation: 45
162 visible: target && !overlay.anyMaximized && !target.maximizedVertically
163 resizeTarget: priv.resizeArea
164 }
166 ResizeGrip { // top right
167 anchors.horizontalCenter: parent.right
168 anchors.verticalCenter: parent.top
169 rotation: 90
170 visible: target && !overlay.anyMaximized && !target.maximizedHorizontally && !target.maximizedVertically
171 resizeTarget: priv.resizeArea
172 }
174 ResizeGrip { // right
175 anchors.horizontalCenter: parent.right
176 anchors.verticalCenter: parent.verticalCenter
177 rotation: 135
178 visible: target && !target.maximizedRight && !target.maximized && !target.maximizedHorizontally
179 resizeTarget: priv.resizeArea
180 }
182 ResizeGrip { // bottom right
183 anchors.horizontalCenter: parent.right
184 anchors.verticalCenter: parent.bottom
185 visible: target && !overlay.anyMaximized && !target.maximizedHorizontally && !target.maximizedVertically
186 resizeTarget: priv.resizeArea
187 }
189 ResizeGrip { // bottom center
190 anchors.horizontalCenter: parent.horizontalCenter
191 anchors.verticalCenter: parent.bottom
192 rotation: 45
193 visible: target && !overlay.anyMaximized && !target.maximizedVertically
194 resizeTarget: priv.resizeArea
195 }
197 ResizeGrip { // bottom left
198 anchors.horizontalCenter: parent.left
199 anchors.verticalCenter: parent.bottom
200 rotation: 90
201 visible: target && !overlay.anyMaximized && !target.maximizedHorizontally && !target.maximizedVertically
202 resizeTarget: priv.resizeArea
203 }
205 ResizeGrip { // left
206 anchors.horizontalCenter: parent.left
207 anchors.verticalCenter: parent.verticalCenter
208 rotation: 135
209 visible: target && !target.maximizedLeft && !target.maximized && !target.maximizedHorizontally
210 resizeTarget: priv.resizeArea
211 }
212 }