git.iko.soy/unity8
on a142f21 help sign in
unity8/qml/Launcher/LauncherPanel.qml
686 lines 33 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.3
18import Ubuntu.Components 1.2
19import Ubuntu.Components.ListItems 1.0 as ListItems
20import Unity.Launcher 0.1
21import Ubuntu.Components.Popups 0.1
22import "../Components/ListItems"
23import "../Components/"
25Rectangle {
26 id: root
27 color: "#B2000000"
29 rotation: inverted ? 180 : 0
31 property var model
32 property bool inverted: false
33 property bool dragging: false
34 property bool moving: launcherListView.moving || launcherListView.flicking
35 property bool preventHiding: moving || dndArea.draggedIndex >= 0 || quickList.state === "open" || dndArea.pressed
36 property int highlightIndex: -1
38 signal applicationSelected(string appId)
39 signal showDashHome()
41 onXChanged: {
42 if (quickList.state == "open") {
43 quickList.state = ""
44 }
45 }
47 Column {
48 id: mainColumn
49 anchors {
50 fill: parent
51 }
53 Item {
54 objectName: "buttonShowDashHome"
55 width: parent.width
56 height: units.gu(7)
57 clip: true
59 UbuntuShape {
60 anchors {
61 fill: parent
62 topMargin: -units.gu(2)
63 }
64 borderSource: "none"
65 color: UbuntuColors.orange
66 }
68 Image {
69 objectName: "dashItem"
70 width: units.gu(5)
71 height: width
72 anchors.centerIn: parent
73 source: "graphics/home.png"
74 rotation: root.rotation
75 }
76 MouseArea {
77 id: dashItem
78 anchors.fill: parent
79 onClicked: root.showDashHome()
80 }
81 }
83 Item {
84 anchors.left: parent.left
85 anchors.right: parent.right
86 height: parent.height - dashItem.height - parent.spacing*2
88 Item {
89 id: launcherListViewItem
90 anchors.fill: parent
91 clip: true
93 ListView {
94 id: launcherListView
95 objectName: "launcherListView"
96 anchors {
97 fill: parent
98 topMargin: -extensionSize + units.gu(0.5)
99 bottomMargin: -extensionSize + units.gu(1)
100 leftMargin: units.gu(0.5)
101 rightMargin: units.gu(0.5)
102 }
103 topMargin: extensionSize
104 bottomMargin: extensionSize
105 height: parent.height - dashItem.height - parent.spacing*2
106 model: root.model
107 cacheBuffer: itemHeight * 3
108 snapMode: interactive ? ListView.SnapToItem : ListView.NoSnap
109 highlightRangeMode: ListView.ApplyRange
110 preferredHighlightBegin: (height - itemHeight) / 2
111 preferredHighlightEnd: (height + itemHeight) / 2
113 // for the single peeking icon, when alert-state is set on delegate
114 property int peekingIndex: -1
116 // The size of the area the ListView is extended to make sure items are not
117 // destroyed when dragging them outside the list. This needs to be at least
118 // itemHeight to prevent folded items from disappearing and DragArea limits
119 // need to be smaller than this size to avoid breakage.
120 property int extensionSize: 0
122 // Setting extensionSize after the list has been populated because it has
123 // the potential to mess up with the intial positioning in combination
124 // with snapping to the center of the list. This catches all the cases
125 // where the item would be outside the list for more than itemHeight / 2.
126 // For the rest, give it a flick to scroll to the beginning. Note that
127 // the flicking alone isn't enough because in some cases it's not strong
128 // enough to overcome the snapping.
129 // https://bugreports.qt-project.org/browse/QTBUG-32251
130 Component.onCompleted: {
131 extensionSize = itemHeight * 3
132 flick(0, clickFlickSpeed)
133 }
135 // The height of the area where icons start getting folded
136 property int foldingStartHeight: units.gu(6.5)
137 // The height of the area where the items reach the final folding angle
138 property int foldingStopHeight: foldingStartHeight - itemHeight - spacing
139 property int itemWidth: units.gu(7)
140 property int itemHeight: units.gu(6.5)
141 property int clickFlickSpeed: units.gu(60)
142 property int draggedIndex: dndArea.draggedIndex
143 property real realContentY: contentY - originY + topMargin
144 property int realItemHeight: itemHeight + spacing
146 // In case the start dragging transition is running, we need to delay the
147 // move because the displaced transition would clash with it and cause items
148 // to be moved to wrong places
149 property bool draggingTransitionRunning: false
150 property int scheduledMoveTo: -1
152 UbuntuNumberAnimation {
153 id: snapToBottomAnimation
154 target: launcherListView
155 property: "contentY"
156 to: launcherListView.originY + launcherListView.topMargin
157 }
159 UbuntuNumberAnimation {
160 id: snapToTopAnimation
161 target: launcherListView
162 property: "contentY"
163 to: launcherListView.contentHeight - launcherListView.height + launcherListView.originY - launcherListView.topMargin
164 }
166 UbuntuNumberAnimation {
167 id: moveAnimation
168 target: launcherListView
169 property: "contentY"
170 function moveTo(contentY) {
171 from = launcherListView.contentY;
172 to = contentY;
173 start();
174 }
175 }
177 displaced: Transition {
178 NumberAnimation { properties: "x,y"; duration: UbuntuAnimation.FastDuration; easing: UbuntuAnimation.StandardEasing }
179 }
181 delegate: FoldingLauncherDelegate {
182 id: launcherDelegate
183 objectName: "launcherDelegate" + index
184 // We need the appId in the delegate in order to find
185 // the right app when running autopilot tests for
186 // multiple apps.
187 readonly property string appId: model.appId
188 itemHeight: launcherListView.itemHeight
189 itemWidth: launcherListView.itemWidth
190 width: itemWidth
191 height: itemHeight
192 iconName: model.icon
193 count: model.count
194 countVisible: model.countVisible
195 progress: model.progress
196 itemRunning: model.running
197 itemFocused: model.focused
198 inverted: root.inverted
199 alerting: model.alerting
200 z: -Math.abs(offset)
201 maxAngle: 55
202 property bool dragging: false
204 SequentialAnimation {
205 id: peekingAnimation
207 // revealing
208 PropertyAction { target: root; property: "visible"; value: (launcher.visibleWidth === 0) ? 1 : 0 }
209 PropertyAction { target: launcherListViewItem; property: "clip"; value: 0 }
211 UbuntuNumberAnimation {
212 target: launcherDelegate
213 alwaysRunToEnd: true
214 loops: 1
215 properties: "x"
216 to: (units.gu(.5) + launcherListView.width * .5) * (root.inverted ? -1 : 1)
217 duration: UbuntuAnimation.BriskDuration
218 }
220 // hiding
221 UbuntuNumberAnimation {
222 target: launcherDelegate
223 alwaysRunToEnd: true
224 loops: 1
225 properties: "x"
226 to: 0
227 duration: UbuntuAnimation.BriskDuration
228 }
230 PropertyAction { target: launcherListViewItem; property: "clip"; value: 1 }
231 PropertyAction { target: root; property: "visible"; value: (launcher.visibleWidth === 0) ? 0 : 1 }
232 }
234 onAlertingChanged: {
235 if(alerting) {
236 if (!dragging && (launcherListView.peekingIndex === -1 || launcher.visibleWidth > 0)) {
237 var itemPosition = index * launcherListView.itemHeight;
238 var height = launcherListView.height - launcherListView.topMargin - launcherListView.bottomMargin
239 var distanceToEnd = index == 0 || index == launcherListView.count - 1 ? 0 : launcherListView.itemHeight
240 if (itemPosition + launcherListView.itemHeight + distanceToEnd > launcherListView.contentY + launcherListView.topMargin + height) {
241 moveAnimation.moveTo(itemPosition + launcherListView.itemHeight - launcherListView.topMargin - height + distanceToEnd);
242 } else if (itemPosition - distanceToEnd < launcherListView.contentY + launcherListView.topMargin) {
243 moveAnimation.moveTo(itemPosition - distanceToEnd - launcherListView.topMargin);
244 }
245 if (!dragging && launcher.state !== "visible") {
246 peekingAnimation.start()
247 }
248 }
250 if (launcherListView.peekingIndex === -1) {
251 launcherListView.peekingIndex = index
252 }
253 } else {
254 if (launcherListView.peekingIndex === index) {
255 launcherListView.peekingIndex = -1
256 }
257 }
258 }
260 ThinDivider {
261 id: dropIndicator
262 objectName: "dropIndicator"
263 anchors.centerIn: parent
264 width: parent.width + mainColumn.anchors.leftMargin + mainColumn.anchors.rightMargin
265 opacity: 0
266 source: "graphics/divider-line.png"
267 }
269 states: [
270 State {
271 name: "selected"
272 when: dndArea.selectedItem === launcherDelegate && fakeDragItem.visible && !dragging
273 PropertyChanges {
274 target: launcherDelegate
275 itemOpacity: 0
276 }
277 },
278 State {
279 name: "dragging"
280 when: dragging
281 PropertyChanges {
282 target: launcherDelegate
283 height: units.gu(1)
284 itemOpacity: 0
285 }
286 PropertyChanges {
287 target: dropIndicator
288 opacity: 1
289 }
290 },
291 State {
292 name: "expanded"
293 when: dndArea.draggedIndex >= 0 && (dndArea.preDragging || dndArea.dragging || dndArea.postDragging) && dndArea.draggedIndex != index
294 PropertyChanges {
295 target: launcherDelegate
296 angle: 0
297 offset: 0
298 itemOpacity: 0.6
299 }
300 }
301 ]
303 transitions: [
304 Transition {
305 from: ""
306 to: "selected"
307 NumberAnimation { properties: "itemOpacity"; duration: UbuntuAnimation.FastDuration }
308 },
309 Transition {
310 from: "*"
311 to: "expanded"
312 NumberAnimation { properties: "itemOpacity"; duration: UbuntuAnimation.FastDuration }
313 UbuntuNumberAnimation { properties: "angle,offset" }
314 },
315 Transition {
316 from: "expanded"
317 to: ""
318 NumberAnimation { properties: "itemOpacity"; duration: UbuntuAnimation.BriskDuration }
319 UbuntuNumberAnimation { properties: "angle,offset" }
320 },
321 Transition {
322 id: draggingTransition
323 from: "selected"
324 to: "dragging"
325 SequentialAnimation {
326 PropertyAction { target: launcherListView; property: "draggingTransitionRunning"; value: true }
327 ParallelAnimation {
328 UbuntuNumberAnimation { properties: "height" }
329 NumberAnimation { target: dropIndicator; properties: "opacity"; duration: UbuntuAnimation.FastDuration }
330 }
331 ScriptAction {
332 script: {
333 if (launcherListView.scheduledMoveTo > -1) {
334 launcherListView.model.move(dndArea.draggedIndex, launcherListView.scheduledMoveTo)
335 dndArea.draggedIndex = launcherListView.scheduledMoveTo
336 launcherListView.scheduledMoveTo = -1
337 }
338 }
339 }
340 PropertyAction { target: launcherListView; property: "draggingTransitionRunning"; value: false }
341 }
342 },
343 Transition {
344 from: "dragging"
345 to: "*"
346 NumberAnimation { target: dropIndicator; properties: "opacity"; duration: UbuntuAnimation.SnapDuration }
347 NumberAnimation { properties: "itemOpacity"; duration: UbuntuAnimation.BriskDuration }
348 SequentialAnimation {
349 ScriptAction { script: if (index == launcherListView.count-1) launcherListView.flick(0, -launcherListView.clickFlickSpeed); }
350 UbuntuNumberAnimation { properties: "height" }
351 ScriptAction { script: if (index == launcherListView.count-1) launcherListView.flick(0, -launcherListView.clickFlickSpeed); }
352 PropertyAction { target: dndArea; property: "postDragging"; value: false }
353 PropertyAction { target: dndArea; property: "draggedIndex"; value: -1 }
354 }
355 }
356 ]
357 }
359 MouseArea {
360 id: dndArea
361 objectName: "dndArea"
362 acceptedButtons: Qt.LeftButton | Qt.RightButton
363 anchors {
364 fill: parent
365 topMargin: launcherListView.topMargin
366 bottomMargin: launcherListView.bottomMargin
367 }
368 drag.minimumY: -launcherListView.topMargin
369 drag.maximumY: height + launcherListView.bottomMargin
371 property int draggedIndex: -1
372 property var selectedItem
373 property bool preDragging: false
374 property bool dragging: !!selectedItem && selectedItem.dragging
375 property bool postDragging: false
376 property int startX
377 property int startY
379 onPressed: {
380 selectedItem = launcherListView.itemAt(mouseX, mouseY + launcherListView.realContentY)
381 }
383 onClicked: {
384 var index = Math.floor((mouseY + launcherListView.realContentY) / launcherListView.realItemHeight);
385 var clickedItem = launcherListView.itemAt(mouseX, mouseY + launcherListView.realContentY)
387 // Check if we actually clicked an item or only at the spacing in between
388 if (clickedItem === null) {
389 return;
390 }
392 if (mouse.button & Qt.RightButton) { // context menu
393 // Opening QuickList
394 quickList.item = clickedItem;
395 quickList.model = launcherListView.model.get(index).quickList;
396 quickList.appId = launcherListView.model.get(index).appId;
397 quickList.state = "open";
398 return
399 }
401 // First/last item do the scrolling at more than 12 degrees
402 if (index == 0 || index == launcherListView.count - 1) {
403 if (clickedItem.angle > 12) {
404 launcherListView.flick(0, -launcherListView.clickFlickSpeed);
405 } else if (clickedItem.angle < -12) {
406 launcherListView.flick(0, launcherListView.clickFlickSpeed);
407 } else {
408 root.applicationSelected(LauncherModel.get(index).appId);
409 }
410 return;
411 }
413 // the rest launches apps up to an angle of 30 degrees
414 if (clickedItem.angle > 30) {
415 launcherListView.flick(0, -launcherListView.clickFlickSpeed);
416 } else if (clickedItem.angle < -30) {
417 launcherListView.flick(0, launcherListView.clickFlickSpeed);
418 } else {
419 root.applicationSelected(LauncherModel.get(index).appId);
420 }
421 }
423 onCanceled: {
424 endDrag();
425 }
427 onReleased: {
428 endDrag();
429 }
431 function endDrag() {
432 var droppedIndex = draggedIndex;
433 if (dragging) {
434 postDragging = true;
435 } else {
436 draggedIndex = -1;
437 }
439 if (!selectedItem) {
440 return;
441 }
443 selectedItem.dragging = false;
444 selectedItem = undefined;
445 preDragging = false;
447 drag.target = undefined
449 progressiveScrollingTimer.stop();
450 launcherListView.interactive = true;
451 if (droppedIndex >= launcherListView.count - 2 && postDragging) {
452 snapToBottomAnimation.start();
453 } else if (droppedIndex < 2 && postDragging) {
454 snapToTopAnimation.start();
455 }
456 }
458 onPressAndHold: {
459 if (Math.abs(selectedItem.angle) > 30) {
460 return;
461 }
463 draggedIndex = Math.floor((mouseY + launcherListView.realContentY) / launcherListView.realItemHeight);
465 // Opening QuickList
466 quickList.item = selectedItem;
467 quickList.model = launcherListView.model.get(draggedIndex).quickList;
468 quickList.appId = launcherListView.model.get(draggedIndex).appId;
469 quickList.state = "open";
471 launcherListView.interactive = false
473 var yOffset = draggedIndex > 0 ? (mouseY + launcherListView.realContentY) % (draggedIndex * launcherListView.realItemHeight) : mouseY + launcherListView.realContentY
475 fakeDragItem.iconName = launcherListView.model.get(draggedIndex).icon
476 fakeDragItem.x = units.gu(0.5)
477 fakeDragItem.y = mouseY - yOffset + launcherListView.anchors.topMargin + launcherListView.topMargin
478 fakeDragItem.angle = selectedItem.angle * (root.inverted ? -1 : 1)
479 fakeDragItem.offset = selectedItem.offset * (root.inverted ? -1 : 1)
480 fakeDragItem.count = LauncherModel.get(draggedIndex).count
481 fakeDragItem.progress = LauncherModel.get(draggedIndex).progress
482 fakeDragItem.flatten()
483 drag.target = fakeDragItem
485 startX = mouseX
486 startY = mouseY
487 }
489 onPositionChanged: {
490 if (draggedIndex >= 0) {
491 if (!selectedItem.dragging) {
492 var distance = Math.max(Math.abs(mouseX - startX), Math.abs(mouseY - startY))
493 if (!preDragging && distance > units.gu(1.5)) {
494 preDragging = true;
495 quickList.state = "";
496 }
497 if (distance > launcherListView.itemHeight) {
498 selectedItem.dragging = true
499 preDragging = false;
500 }
501 }
502 if (!selectedItem.dragging) {
503 return
504 }
506 var itemCenterY = fakeDragItem.y + fakeDragItem.height / 2
508 // Move it down by the the missing size to compensate index calculation with only expanded items
509 itemCenterY += (launcherListView.itemHeight - selectedItem.height) / 2
511 if (mouseY > launcherListView.height - launcherListView.topMargin - launcherListView.bottomMargin - launcherListView.realItemHeight) {
512 progressiveScrollingTimer.downwards = false
513 progressiveScrollingTimer.start()
514 } else if (mouseY < launcherListView.realItemHeight) {
515 progressiveScrollingTimer.downwards = true
516 progressiveScrollingTimer.start()
517 } else {
518 progressiveScrollingTimer.stop()
519 }
521 var newIndex = (itemCenterY + launcherListView.realContentY) / launcherListView.realItemHeight
523 if (newIndex > draggedIndex + 1) {
524 newIndex = draggedIndex + 1
525 } else if (newIndex < draggedIndex) {
526 newIndex = draggedIndex -1
527 } else {
528 return
529 }
531 if (newIndex >= 0 && newIndex < launcherListView.count) {
532 if (launcherListView.draggingTransitionRunning) {
533 launcherListView.scheduledMoveTo = newIndex
534 } else {
535 launcherListView.model.move(draggedIndex, newIndex)
536 draggedIndex = newIndex
537 }
538 }
539 }
540 }
541 }
542 Timer {
543 id: progressiveScrollingTimer
544 interval: 2
545 repeat: true
546 running: false
547 property bool downwards: true
548 onTriggered: {
549 if (downwards) {
550 var minY = -launcherListView.topMargin
551 if (launcherListView.contentY > minY) {
552 launcherListView.contentY = Math.max(launcherListView.contentY - units.dp(2), minY)
553 }
554 } else {
555 var maxY = launcherListView.contentHeight - launcherListView.height + launcherListView.topMargin + launcherListView.originY
556 if (launcherListView.contentY < maxY) {
557 launcherListView.contentY = Math.min(launcherListView.contentY + units.dp(2), maxY)
558 }
559 }
560 }
561 }
562 }
563 }
565 LauncherDelegate {
566 id: fakeDragItem
567 objectName: "fakeDragItem"
568 visible: dndArea.draggedIndex >= 0 && !dndArea.postDragging
569 itemWidth: launcherListView.itemWidth
570 itemHeight: launcherListView.itemHeight
571 height: itemHeight
572 width: itemWidth
573 rotation: root.rotation
574 itemOpacity: 0.9
576 function flatten() {
577 fakeDragItemAnimation.start();
578 }
580 UbuntuNumberAnimation {
581 id: fakeDragItemAnimation
582 target: fakeDragItem;
583 properties: "angle,offset";
584 to: 0
585 }
586 }
587 }
588 }
590 UbuntuShapeForItem {
591 id: quickListShape
592 objectName: "quickListShape"
593 anchors.fill: quickList
594 opacity: quickList.state === "open" ? 0.8 : 0
595 visible: opacity > 0
596 rotation: root.rotation
598 Behavior on opacity {
599 UbuntuNumberAnimation {}
600 }
602 image: quickList
604 Image {
605 anchors {
606 right: parent.left
607 rightMargin: -units.dp(4)
608 verticalCenter: parent.verticalCenter
609 verticalCenterOffset: -quickList.offset * (root.inverted ? -1 : 1)
610 }
611 height: units.gu(1)
612 width: units.gu(2)
613 source: "graphics/quicklist_tooltip.png"
614 rotation: 90
615 }
617 InverseMouseArea {
618 anchors.fill: parent
619 enabled: quickList.state == "open"
620 onClicked: {
621 quickList.state = ""
622 }
623 }
625 }
627 Rectangle {
628 id: quickList
629 objectName: "quickList"
630 color: "#f5f5f5"
631 // Because we're setting left/right anchors depending on orientation, it will break the
632 // width setting after rotating twice. This makes sure we also re-apply width on rotation
633 width: root.inverted ? units.gu(30) : units.gu(30)
634 height: quickListColumn.height
635 visible: quickListShape.visible
636 anchors {
637 left: root.inverted ? undefined : parent.right
638 right: root.inverted ? parent.left : undefined
639 margins: units.gu(1)
640 }
641 y: itemCenter - (height / 2) + offset
642 rotation: root.rotation
644 property var model
645 property string appId
646 property var item
648 // internal
649 property int itemCenter: item ? root.mapFromItem(quickList.item).y + (item.height / 2) : units.gu(1)
650 property int offset: itemCenter + (height/2) + units.gu(1) > parent.height ? -itemCenter - (height/2) - units.gu(1) + parent.height :
651 itemCenter - (height/2) < units.gu(1) ? (height/2) - itemCenter + units.gu(1) : 0
653 Column {
654 id: quickListColumn
655 width: parent.width
656 height: childrenRect.height
658 Repeater {
659 id: popoverRepeater
660 model: quickList.model
662 ListItems.Standard {
663 objectName: "quickListEntry" + index
664 text: (model.clickable ? "" : "<b>") + model.label + (model.clickable ? "" : "</b>")
665 highlightWhenPressed: model.clickable
667 // FIXME: This is a workaround for the theme not being context sensitive. I.e. the
668 // ListItems don't know that they are sitting in a themed Popover where the color
669 // needs to be inverted.
670 __foregroundColor: "black"
672 onClicked: {
673 if (!model.clickable) {
674 return;
675 }
676 quickList.state = "";
677 // Unsetting model to prevent showing changing entries during fading out
678 // that may happen because of triggering an action.
679 LauncherModel.quickListActionInvoked(quickList.appId, index);
680 quickList.model = undefined;
681 }
682 }
683 }
684 }
685 }