git.iko.soy/unity8
on a361c93 help sign in
unity8/qml/Shell.qml
811 lines 29 kB history raw
1/*
2 * Copyright (C) 2013-2016 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import QtQuick.Window 2.2
19import AccountsService 0.1
20import Unity.Application 0.1
21import Ubuntu.Components 1.3
22import Ubuntu.Components.Popups 1.3
23import Ubuntu.Gestures 0.1
24import Ubuntu.Telephony 0.1 as Telephony
25import Unity.Connectivity 0.1
26import Unity.Launcher 0.1
27import GlobalShortcut 1.0 // has to be before Utils, because of WindowInputFilter
28import GSettings 1.0
29import ImageCache 0.1
30import Utils 0.1
31import Powerd 0.1
32import SessionBroadcast 0.1
33import "Greeter"
34import "Launcher"
35import "Panel"
36import "Components"
37import "Notifications"
38import "Stage"
39import "Tutorial"
40import "Wizard"
41import Unity.Notifications 1.0 as NotificationBackend
42import Unity.Session 0.1
43import Unity.DashCommunicator 0.1
44import Unity.Indicators 0.1 as Indicators
45import Cursor 1.1
46import WindowManager 0.1
49StyledItem {
50 id: shell
52 theme.name: "Ubuntu.Components.Themes.SuruDark"
54 // to be set from outside
55 property int orientationAngle: 0
56 property int orientation
57 property Orientations orientations
58 property real nativeWidth
59 property real nativeHeight
60 property alias indicatorAreaShowProgress: panel.indicatorAreaShowProgress
61 property string usageScenario: "phone" // supported values: "phone", "tablet" or "desktop"
62 property string mode: "full-greeter"
63 property alias oskEnabled: inputMethod.enabled
64 function updateFocusedAppOrientation() {
65 stage.updateFocusedAppOrientation();
66 }
67 function updateFocusedAppOrientationAnimated() {
68 stage.updateFocusedAppOrientationAnimated();
69 }
70 property bool hasMouse: false
72 // to be read from outside
73 readonly property int mainAppWindowOrientationAngle: stage.mainAppWindowOrientationAngle
75 readonly property bool orientationChangesEnabled: panel.indicators.fullyClosed
76 && stage.orientationChangesEnabled
77 && (!greeter || !greeter.animating)
79 readonly property bool showingGreeter: greeter && greeter.shown
81 property bool startingUp: true
82 Timer { id: finishStartUpTimer; interval: 500; onTriggered: startingUp = false }
84 property int supportedOrientations: {
85 if (startingUp) {
86 // Ensure we don't rotate during start up
87 return Qt.PrimaryOrientation;
88 } else if (showingGreeter || notifications.topmostIsFullscreen) {
89 return Qt.PrimaryOrientation;
90 } else {
91 return shell.orientations.map(stage.supportedOrientations);
92 }
93 }
95 readonly property var mainApp: stage.mainApp
97 onMainAppChanged: {
98 if (mainApp) {
99 _onMainAppChanged(mainApp.appId);
100 }
101 }
102 Connections {
103 target: ApplicationManager
104 onFocusRequested: {
105 if (shell.mainApp && shell.mainApp.appId === appId) {
106 _onMainAppChanged(appId);
107 }
108 }
109 }
110 function _onMainAppChanged(appId) {
111 if (wizard.active && appId != "" && appId != "unity8-dash") {
112 // If this happens on first boot, we may be in the
113 // wizard while receiving a call. But a call is more
114 // important than the wizard so just bail out of it.
115 wizard.hide();
116 }
118 if (appId === "dialer-app" && callManager.hasCalls && greeter.locked) {
119 // If we are in the middle of a call, make dialer lockedApp and show it.
120 // This can happen if user backs out of dialer back to greeter, then
121 // launches dialer again.
122 greeter.lockedApp = appId;
123 }
124 greeter.notifyAppFocusRequested(appId);
126 panel.indicators.hide();
127 launcher.hide();
128 }
130 // For autopilot consumption
131 readonly property string focusedApplicationId: ApplicationManager.focusedApplicationId
133 // Note when greeter is waiting on PAM, so that we can disable edges until
134 // we know which user data to show and whether the session is locked.
135 readonly property bool waitingOnGreeter: greeter && greeter.waiting
137 property real edgeSize: units.gu(settings.edgeDragWidth)
139 WallpaperResolver {
140 id: wallpaperResolver
141 objectName: "wallpaperResolver"
143 readonly property url defaultBackground: "file://" + Constants.defaultWallpaper
144 readonly property bool hasCustomBackground: background != defaultBackground
146 // Use a cached version of the scaled-down wallpaper (as sometimes the
147 // image can be quite big compared to the device size, including for
148 // our default wallpaper). We use a name=wallpaper argument here to
149 // make sure we don't litter our cache with lots of scaled images. We
150 // only need to bother caching one at a time.
151 readonly property url cachedBackground: background.toString().indexOf("file:///") === 0 ? "image://unity8imagecache/" + background + "?name=wallpaper" : background
153 GSettings {
154 id: backgroundSettings
155 schema.id: "org.gnome.desktop.background"
156 }
158 candidates: [
159 AccountsService.backgroundFile,
160 backgroundSettings.pictureUri,
161 defaultBackground
162 ]
163 }
165 readonly property alias greeter: greeterLoader.item
167 function activateApplication(appId) {
168 // Either open the app in our own session, or -- if we're acting as a
169 // greeter -- ask the user's session to open it for us.
170 if (shell.mode === "greeter") {
171 activateURL("application:///" + appId + ".desktop");
172 } else {
173 startApp(appId);
174 }
175 }
177 function activateURL(url) {
178 SessionBroadcast.requestUrlStart(AccountsService.user, url);
179 greeter.notifyUserRequestedApp();
180 panel.indicators.hide();
181 }
183 function startApp(appId) {
184 if (ApplicationManager.findApplication(appId)) {
185 ApplicationManager.requestFocusApplication(appId);
186 } else {
187 ApplicationManager.startApplication(appId);
188 }
189 }
191 function startLockedApp(app) {
192 if (greeter.locked) {
193 greeter.lockedApp = app;
194 }
195 startApp(app); // locked apps are always in our same session
196 }
198 Binding {
199 target: LauncherModel
200 property: "applicationManager"
201 value: ApplicationManager
202 }
204 Component.onCompleted: {
205 finishStartUpTimer.start();
206 }
208 VolumeControl {
209 id: volumeControl
210 }
212 DashCommunicator {
213 id: dash
214 objectName: "dashCommunicator"
215 }
217 PhysicalKeysMapper {
218 id: physicalKeysMapper
219 objectName: "physicalKeysMapper"
221 onPowerKeyLongPressed: dialogs.showPowerDialog();
222 onVolumeDownTriggered: volumeControl.volumeDown();
223 onVolumeUpTriggered: volumeControl.volumeUp();
224 onScreenshotTriggered: itemGrabber.capture(shell);
225 }
227 GlobalShortcut {
228 // dummy shortcut to force creation of GlobalShortcutRegistry before WindowInputFilter
229 }
231 WindowInputFilter {
232 id: inputFilter
233 Keys.onPressed: physicalKeysMapper.onKeyPressed(event, lastInputTimestamp);
234 Keys.onReleased: physicalKeysMapper.onKeyReleased(event, lastInputTimestamp);
235 }
237 WindowInputMonitor {
238 objectName: "windowInputMonitor"
239 onHomeKeyActivated: {
240 // Ignore when greeter is active, to avoid pocket presses
241 if (!greeter.active) {
242 launcher.fadeOut();
243 shell.showHome();
244 }
245 }
246 onTouchBegun: { cursor.opacity = 0; }
247 onTouchEnded: {
248 // move the (hidden) cursor to the last known touch position
249 var mappedCoords = mapFromItem(null, pos.x, pos.y);
250 cursor.x = mappedCoords.x;
251 cursor.y = mappedCoords.y;
252 cursor.mouseNeverMoved = false;
253 }
254 }
256 GSettings {
257 id: settings
258 schema.id: "com.canonical.Unity8"
259 }
261 Item {
262 id: stages
263 objectName: "stages"
264 width: parent.width
265 height: parent.height
267 TopLevelSurfaceList {
268 id: topLevelSurfaceList
269 objectName: "topLevelSurfaceList"
270 applicationsModel: ApplicationManager
271 }
273 Stage {
274 id: stage
275 objectName: "stage"
276 anchors.fill: parent
277 focus: true
279 dragAreaWidth: shell.edgeSize
280 background: wallpaperResolver.background
281 leftEdgeDragProgress: !greeter || greeter.locked || !tutorial.launcherLongSwipeEnabled ? 0 :
282 Math.max(0, (launcher.dragDistance * (stage.width - launcher.panelWidth) / stage.width) - launcher.panelWidth)
284 applicationManager: ApplicationManager
285 topLevelSurfaceList: topLevelSurfaceList
286 inputMethodRect: inputMethod.visibleRect
288 property string usageScenario: shell.usageScenario === "phone" || greeter.hasLockedApp
289 ? "phone"
290 : shell.usageScenario
292 mode: usageScenario == "phone" ? "staged"
293 : usageScenario == "tablet" ? "stagedWithSideStage"
294 : "windowed"
296 shellOrientation: shell.orientation
297 shellOrientationAngle: shell.orientationAngle
298 orientations: shell.orientations
299 nativeWidth: shell.nativeWidth
300 nativeHeight: shell.nativeHeight
302 interactive: (!greeter || !greeter.shown)
303 && panel.indicators.fullyClosed
304 && launcher.progress == 0
305 && !notifications.useModal
307 onInteractiveChanged: { if (interactive) { focus = true; } }
309 leftMargin: shell.usageScenario == "desktop" && !settings.autohideLauncher ? launcher.panelWidth: 0
310 suspended: greeter.shown
311 keepDashRunning: launcher.shown || launcher.dashSwipe
312 altTabPressed: physicalKeysMapper.altTabPressed
313 oskEnabled: shell.oskEnabled
314 spreadEnabled: tutorial.spreadEnabled && (!greeter || (!greeter.hasLockedApp && !greeter.shown))
315 }
316 }
318 InputMethod {
319 id: inputMethod
320 objectName: "inputMethod"
321 anchors {
322 fill: parent
323 topMargin: panel.panelHeight
324 leftMargin: launcher.lockedVisible ? launcher.panelWidth : 0
325 }
326 z: notifications.useModal || panel.indicators.shown || wizard.active || tutorial.running ? overlay.z + 1 : overlay.z - 1
327 }
329 Loader {
330 id: greeterLoader
331 objectName: "greeterLoader"
332 anchors.fill: parent
333 anchors.topMargin: panel.panelHeight
334 sourceComponent: shell.mode != "shell" ? integratedGreeter :
335 Qt.createComponent(Qt.resolvedUrl("Greeter/ShimGreeter.qml"));
336 onLoaded: {
337 item.objectName = "greeter"
338 }
339 }
341 Component {
342 id: integratedGreeter
343 Greeter {
345 enabled: panel.indicators.fullyClosed // hides OSK when panel is open
346 hides: [launcher, panel.indicators]
347 tabletMode: shell.usageScenario != "phone"
348 launcherOffset: launcher.progress
349 forcedUnlock: wizard.active || shell.mode === "full-shell"
350 background: wallpaperResolver.cachedBackground
351 hasCustomBackground: wallpaperResolver.hasCustomBackground
352 allowFingerprint: !dialogs.hasActiveDialog &&
353 !notifications.topmostIsFullscreen &&
354 !panel.indicators.shown
356 // avoid overlapping with Launcher's edge drag area
357 // FIXME: Fix TouchRegistry & friends and remove this workaround
358 // Issue involves launcher's DDA getting disabled on a long
359 // left-edge drag
360 dragHandleLeftMargin: launcher.available ? launcher.dragAreaWidth + 1 : 0
362 onSessionStarted: {
363 launcher.hide();
364 }
366 onTease: {
367 if (!tutorial.running) {
368 launcher.tease();
369 }
370 }
372 onEmergencyCall: startLockedApp("dialer-app")
373 }
374 }
376 Timer {
377 // See powerConnection for why this is useful
378 id: showGreeterDelayed
379 interval: 1
380 onTriggered: {
381 greeter.forceShow();
382 }
383 }
385 Connections {
386 id: callConnection
387 target: callManager
389 onHasCallsChanged: {
390 if (greeter.locked && callManager.hasCalls && greeter.lockedApp !== "dialer-app") {
391 // We just received an incoming call while locked. The
392 // indicator will have already launched dialer-app for us, but
393 // there is a race between "hasCalls" changing and the dialer
394 // starting up. So in case we lose that race, we'll start/
395 // focus the dialer ourselves here too. Even if the indicator
396 // didn't launch the dialer for some reason (or maybe a call
397 // started via some other means), if an active call is
398 // happening, we want to be in the dialer.
399 startLockedApp("dialer-app")
400 }
401 }
402 }
404 Connections {
405 id: powerConnection
406 target: Powerd
408 onStatusChanged: {
409 if (Powerd.status === Powerd.Off && reason !== Powerd.Proximity &&
410 !callManager.hasCalls && !wizard.active) {
411 // We don't want to simply call greeter.showNow() here, because
412 // that will take too long. Qt will delay button event
413 // handling until the greeter is done loading and may think the
414 // user held down the power button the whole time, leading to a
415 // power dialog being shown. Instead, delay showing the
416 // greeter until we've finished handling the event. We could
417 // make the greeter load asynchronously instead, but that
418 // introduces a whole host of timing issues, especially with
419 // its animations. So this is simpler.
420 showGreeterDelayed.start();
421 }
422 }
423 }
425 function showHome() {
426 greeter.notifyUserRequestedApp();
428 if (shell.mode === "greeter") {
429 SessionBroadcast.requestHomeShown(AccountsService.user);
430 } else {
431 var animate = !LightDMService.greeter.active && !stages.shown;
432 dash.setCurrentScope(0, animate, false);
433 ApplicationManager.requestFocusApplication("unity8-dash");
434 }
435 }
437 function showDash() {
438 if (greeter.notifyShowingDashFromDrag()) {
439 launcher.fadeOut();
440 }
442 if (!greeter.locked && tutorial.launcherLongSwipeEnabled
443 && (ApplicationManager.focusedApplicationId != "unity8-dash" || stage.spreadShown)) {
444 ApplicationManager.requestFocusApplication("unity8-dash")
445 launcher.fadeOut();
446 stage.closeSpread();
447 }
448 }
450 Item {
451 id: overlay
452 z: 10
454 anchors.fill: parent
456 Panel {
457 id: panel
458 objectName: "panel"
459 anchors.fill: parent //because this draws indicator menus
460 indicators {
461 hides: [launcher]
462 available: tutorial.panelEnabled
463 && ((!greeter || !greeter.locked) || AccountsService.enableIndicatorsWhileLocked)
464 && (!greeter || !greeter.hasLockedApp)
465 && !shell.waitingOnGreeter
466 && settings.enableIndicatorMenu
467 width: parent.width > units.gu(60) ? units.gu(40) : parent.width
469 minimizedPanelHeight: units.gu(3)
470 expandedPanelHeight: units.gu(7)
472 indicatorsModel: Indicators.IndicatorsModel {
473 // tablet and phone both use the same profile
474 // FIXME: use just "phone" for greeter too, but first fix
475 // greeter app launching to either load the app inside the
476 // greeter or tell the session to load the app. This will
477 // involve taking the url-dispatcher dbus name and using
478 // SessionBroadcast to tell the session.
479 profile: shell.mode === "greeter" ? "desktop_greeter" : "phone"
480 Component.onCompleted: load();
481 }
482 }
484 callHint {
485 greeterShown: greeter.shown
486 }
488 readonly property bool focusedSurfaceIsFullscreen: MirFocusController.focusedSurface
489 ? MirFocusController.focusedSurface.state === Mir.FullscreenState
490 : false
491 fullscreenMode: (focusedSurfaceIsFullscreen && !LightDMService.greeter.active && launcher.progress == 0)
492 || greeter.hasLockedApp
493 locked: greeter && greeter.active
494 }
496 Launcher {
497 id: launcher
498 objectName: "launcher"
500 /*
501 * Since the Dash doesn't have the same controll over surfaces that the
502 * Shell does, it can't slowly move the scope out of the way, as the shell
503 * does with apps, and the dash is show instantly. This allows for some
504 * leeway and prevents accidental home swipes.
505 */
506 readonly property real offset: shell.focusedApplicationId == "unity8-dash" ? units.gu(12) : 0
507 readonly property bool dashSwipe: progress > offset
509 anchors.top: parent.top
510 anchors.topMargin: inverted ? 0 : panel.panelHeight
511 anchors.bottom: parent.bottom
512 width: parent.width
513 dragAreaWidth: shell.edgeSize
514 available: tutorial.launcherEnabled
515 && (!greeter.locked || AccountsService.enableLauncherWhileLocked)
516 && !greeter.hasLockedApp
517 && !shell.waitingOnGreeter
518 && settings.enableLauncher
519 inverted: shell.usageScenario !== "desktop"
520 superPressed: physicalKeysMapper.superPressed
521 superTabPressed: physicalKeysMapper.superTabPressed
522 panelWidth: units.gu(settings.launcherWidth)
523 lockedVisible: shell.usageScenario == "desktop" && !settings.autohideLauncher && !panel.fullscreenMode
525 onShowDashHome: showHome()
526 onDash: showDash()
527 onDashSwipeChanged: {
528 if (dashSwipe) {
529 dash.setCurrentScope(0, false, true)
530 }
531 }
532 onLauncherApplicationSelected: {
533 greeter.notifyUserRequestedApp();
534 shell.activateApplication(appId);
535 }
536 onShownChanged: {
537 if (shown) {
538 panel.indicators.hide()
539 }
540 }
541 onFocusChanged: {
542 if (!focus) {
543 stage.focus = true;
544 }
545 }
547 GlobalShortcut {
548 shortcut: Qt.AltModifier | Qt.Key_F1
549 onTriggered: {
550 launcher.openForKeyboardNavigation();
551 }
552 }
553 GlobalShortcut {
554 shortcut: Qt.MetaModifier | Qt.Key_0
555 onTriggered: {
556 if (LauncherModel.get(9)) {
557 activateApplication(LauncherModel.get(9).appId);
558 }
559 }
560 }
561 Repeater {
562 model: 9
563 GlobalShortcut {
564 shortcut: Qt.MetaModifier | (Qt.Key_1 + index)
565 onTriggered: {
566 if (LauncherModel.get(index)) {
567 activateApplication(LauncherModel.get(index).appId);
568 }
569 }
570 }
571 }
572 }
574 KeyboardShortcutsOverlay {
575 objectName: "shortcutsOverlay"
576 enabled: launcher.shortcutHintsShown && width < parent.width - (launcher.lockedVisible ? launcher.panelWidth : 0) - padding
577 && height < parent.height - padding - panel.panelHeight
578 anchors.centerIn: parent
579 anchors.horizontalCenterOffset: launcher.lockedVisible ? launcher.panelWidth/2 : 0
580 anchors.verticalCenterOffset: panel.panelHeight/2
581 visible: opacity > 0
582 opacity: enabled ? 0.95 : 0
584 Behavior on opacity {
585 UbuntuNumberAnimation {}
586 }
587 }
589 Tutorial {
590 id: tutorial
591 objectName: "tutorial"
592 anchors.fill: parent
594 paused: callManager.hasCalls || !greeter || greeter.active ||
595 wizard.active
596 delayed: dialogs.hasActiveDialog || notifications.hasNotification ||
597 inputMethod.visible ||
598 (launcher.shown && !launcher.lockedVisible) ||
599 panel.indicators.shown || stage.rightEdgeDragProgress > 0
600 usageScenario: shell.usageScenario
601 lastInputTimestamp: inputFilter.lastInputTimestamp
602 launcher: launcher
603 panel: panel
604 stage: stage
605 }
607 Wizard {
608 id: wizard
609 objectName: "wizard"
610 anchors.fill: parent
611 deferred: shell.mode === "greeter"
613 function unlockWhenDoneWithWizard() {
614 if (!active) {
615 Connectivity.unlockAllModems();
616 }
617 }
619 Component.onCompleted: unlockWhenDoneWithWizard()
620 onActiveChanged: unlockWhenDoneWithWizard()
621 }
623 MouseArea { // modal notifications prevent interacting with other contents
624 anchors.fill: parent
625 visible: notifications.useModal
626 enabled: visible
627 }
629 Notifications {
630 id: notifications
632 model: NotificationBackend.Model
633 margin: units.gu(1)
634 hasMouse: shell.hasMouse
635 background: wallpaperResolver.cachedBackground
637 y: topmostIsFullscreen ? 0 : panel.panelHeight
638 height: parent.height - (topmostIsFullscreen ? 0 : panel.panelHeight)
640 states: [
641 State {
642 name: "narrow"
643 when: overlay.width <= units.gu(60)
644 AnchorChanges {
645 target: notifications
646 anchors.left: parent.left
647 anchors.right: parent.right
648 }
649 },
650 State {
651 name: "wide"
652 when: overlay.width > units.gu(60)
653 AnchorChanges {
654 target: notifications
655 anchors.left: undefined
656 anchors.right: parent.right
657 }
658 PropertyChanges { target: notifications; width: units.gu(38) }
659 }
660 ]
661 }
662 }
664 Dialogs {
665 id: dialogs
666 objectName: "dialogs"
667 anchors.fill: parent
668 z: overlay.z + 10
669 usageScenario: shell.usageScenario
670 onPowerOffClicked: {
671 shutdownFadeOutRectangle.enabled = true;
672 shutdownFadeOutRectangle.visible = true;
673 shutdownFadeOut.start();
674 }
675 }
677 Connections {
678 target: SessionBroadcast
679 onShowHome: if (shell.mode !== "greeter") showHome()
680 }
682 URLDispatcher {
683 id: urlDispatcher
684 objectName: "urlDispatcher"
685 active: shell.mode === "greeter"
686 onUrlRequested: shell.activateURL(url)
687 }
689 ItemGrabber {
690 id: itemGrabber
691 anchors.fill: parent
692 z: dialogs.z + 10
693 GlobalShortcut { shortcut: Qt.Key_Print; onTriggered: itemGrabber.capture(shell) }
694 Connections {
695 target: stage
696 ignoreUnknownSignals: true
697 onItemSnapshotRequested: itemGrabber.capture(item)
698 }
699 }
701 Timer {
702 id: cursorHidingTimer
703 interval: 3000
704 running: panel.focusedSurfaceIsFullscreen && cursor.opacity > 0
705 onTriggered: cursor.opacity = 0;
706 }
708 Cursor {
709 id: cursor
710 objectName: "cursor"
711 visible: shell.hasMouse
712 z: itemGrabber.z + 1
713 topBoundaryOffset: panel.panelHeight
715 confiningItem: stage.itemConfiningMouseCursor
717 property bool mouseNeverMoved: true
718 Binding {
719 target: cursor; property: "x"; value: shell.width / 2
720 when: cursor.mouseNeverMoved && cursor.visible
721 }
722 Binding {
723 target: cursor; property: "y"; value: shell.height / 2
724 when: cursor.mouseNeverMoved && cursor.visible
725 }
727 height: units.gu(3)
729 readonly property var previewRectangle: stage.previewRectangle.target &&
730 stage.previewRectangle.target.dragging ?
731 stage.previewRectangle : null
733 onPushedLeftBoundary: {
734 if (buttons === Qt.NoButton) {
735 launcher.pushEdge(amount);
736 } else if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeMaximizedLeftRight) {
737 previewRectangle.maximizeLeft(amount);
738 }
739 }
741 onPushedRightBoundary: {
742 if (buttons === Qt.NoButton) {
743 stage.pushRightEdge(amount);
744 } else if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeMaximizedLeftRight) {
745 previewRectangle.maximizeRight(amount);
746 }
747 }
749 onPushedTopBoundary: {
750 if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeMaximized) {
751 previewRectangle.maximize(amount);
752 }
753 }
754 onPushedTopLeftCorner: {
755 if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeCornerMaximized) {
756 previewRectangle.maximizeTopLeft(amount);
757 }
758 }
759 onPushedTopRightCorner: {
760 if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeCornerMaximized) {
761 previewRectangle.maximizeTopRight(amount);
762 }
763 }
764 onPushedBottomLeftCorner: {
765 if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeCornerMaximized) {
766 previewRectangle.maximizeBottomLeft(amount);
767 }
768 }
769 onPushedBottomRightCorner: {
770 if (buttons === Qt.LeftButton && previewRectangle && previewRectangle.target.canBeCornerMaximized) {
771 previewRectangle.maximizeBottomRight(amount);
772 }
773 }
774 onPushStopped: {
775 if (previewRectangle) {
776 previewRectangle.stop();
777 }
778 }
780 onMouseMoved: {
781 mouseNeverMoved = false;
782 cursor.opacity = 1;
783 }
785 Behavior on opacity { UbuntuNumberAnimation {} }
786 }
788 // non-visual objects
789 KeymapSwitcher {}
790 BrightnessControl {}
792 Rectangle {
793 id: shutdownFadeOutRectangle
794 z: cursor.z + 1
795 enabled: false
796 visible: false
797 color: "black"
798 anchors.fill: parent
799 opacity: 0.0
800 NumberAnimation on opacity {
801 id: shutdownFadeOut
802 from: 0.0
803 to: 1.0
804 onStopped: {
805 if (shutdownFadeOutRectangle.enabled && shutdownFadeOutRectangle.visible) {
806 DBusUnitySessionService.shutdown();
807 }
808 }
809 }
810 }