git.iko.soy/unity8
on a5f9da8 help sign in
unity8/qml/Shell.qml
711 lines 25 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import QtQuick.Window 2.0
19import AccountsService 0.1
20import GSettings 1.0
21import Unity.Application 0.1
22import Ubuntu.Components 0.1
23import Ubuntu.Components.Popups 1.0
24import Ubuntu.Gestures 0.1
25import Ubuntu.Telephony 0.1 as Telephony
26import Unity.Connectivity 0.1
27import Unity.Launcher 0.1
28import Utils 0.1
29import Powerd 0.1
30import SessionBroadcast 0.1
31import "Greeter"
32import "Launcher"
33import "Panel"
34import "Components"
35import "Notifications"
36import "Stages"
37import "Tutorial"
38import "Wizard"
39import Unity.Notifications 1.0 as NotificationBackend
40import Unity.Session 0.1
41import Unity.DashCommunicator 0.1
42import Unity.Indicators 0.1 as Indicators
44Item {
45 id: shell
47 // to be set from outside
48 property int orientationAngle: 0
49 property int orientation
50 property int primaryOrientation
51 property int nativeOrientation
52 property real nativeWidth
53 property real nativeHeight
54 property alias indicatorAreaShowProgress: panel.indicatorAreaShowProgress
55 property bool beingResized
56 property string usageScenario: "phone" // supported values: "phone", "tablet" or "desktop"
57 property string mode: "full-greeter"
58 function updateFocusedAppOrientation() {
59 applicationsDisplayLoader.item.updateFocusedAppOrientation();
60 }
61 function updateFocusedAppOrientationAnimated() {
62 applicationsDisplayLoader.item.updateFocusedAppOrientationAnimated();
63 }
65 // to be read from outside
66 readonly property int mainAppWindowOrientationAngle:
67 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainAppWindowOrientationAngle : 0
69 readonly property bool orientationChangesEnabled: panel.indicators.fullyClosed
70 && (applicationsDisplayLoader.item && applicationsDisplayLoader.item.orientationChangesEnabled)
71 && (!greeter || !greeter.animating)
73 readonly property bool showingGreeter: greeter && greeter.shown
75 property bool startingUp: true
76 Timer { id: finishStartUpTimer; interval: 500; onTriggered: startingUp = false }
78 property int supportedOrientations: {
79 if (startingUp) {
80 // Ensure we don't rotate during start up
81 return Qt.PrimaryOrientation;
82 } else if (greeter && greeter.shown) {
83 return Qt.PrimaryOrientation;
84 } else if (mainApp) {
85 return mainApp.supportedOrientations;
86 } else {
87 // we just don't care
88 return Qt.PortraitOrientation
89 | Qt.LandscapeOrientation
90 | Qt.InvertedPortraitOrientation
91 | Qt.InvertedLandscapeOrientation;
92 }
93 }
95 // For autopilot consumption
96 readonly property string focusedApplicationId: ApplicationManager.focusedApplicationId
98 // internal props from here onwards
99 readonly property var mainApp:
100 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainApp : null
102 // Disable everything while greeter is waiting, so that the user can't swipe
103 // the greeter or launcher until we know whether the session is locked.
104 enabled: greeter && !greeter.waiting
106 property real edgeSize: units.gu(2)
107 property url defaultBackground: Qt.resolvedUrl(shell.width >= units.gu(60) ? "graphics/tablet_background.jpg" : "graphics/phone_background.jpg")
108 property url background: asImageTester.status == Image.Ready ? asImageTester.source
109 : gsImageTester.status == Image.Ready ? gsImageTester.source : defaultBackground
111 readonly property alias greeter: greeterLoader.item
113 function activateApplication(appId) {
114 if (ApplicationManager.findApplication(appId)) {
115 ApplicationManager.requestFocusApplication(appId);
116 } else {
117 var execFlags = shell.usageScenario === "phone" ? ApplicationManager.ForceMainStage
118 : ApplicationManager.NoFlag;
119 ApplicationManager.startApplication(appId, execFlags);
120 }
121 }
123 function startLockedApp(app) {
124 if (greeter.locked) {
125 greeter.lockedApp = app;
126 }
127 shell.activateApplication(app);
128 }
130 // This is a dummy image to detect if the custom AS set wallpaper loads successfully.
131 Image {
132 id: asImageTester
133 source: AccountsService.backgroundFile != undefined && AccountsService.backgroundFile.length > 0 ? AccountsService.backgroundFile : ""
134 height: 0
135 width: 0
136 sourceSize.height: 0
137 sourceSize.width: 0
138 }
140 GSettings {
141 id: backgroundSettings
142 schema.id: "org.gnome.desktop.background"
143 }
145 // This is a dummy image to detect if the custom GSettings set wallpaper loads successfully.
146 Image {
147 id: gsImageTester
148 source: backgroundSettings.pictureUri != undefined && backgroundSettings.pictureUri.length > 0 ? backgroundSettings.pictureUri : ""
149 height: 0
150 width: 0
151 sourceSize.height: 0
152 sourceSize.width: 0
153 }
155 Binding {
156 target: LauncherModel
157 property: "applicationManager"
158 value: ApplicationManager
159 }
161 Component.onCompleted: {
162 Theme.name = "Ubuntu.Components.Themes.SuruGradient"
163 if (ApplicationManager.count > 0) {
164 ApplicationManager.focusApplication(ApplicationManager.get(0).appId);
165 }
166 finishStartUpTimer.start();
167 }
169 LightDM{id: lightDM} // Provide backend access
170 VolumeControl {
171 id: volumeControl
172 }
174 DashCommunicator {
175 id: dash
176 objectName: "dashCommunicator"
177 }
179 PhysicalKeysMapper {
180 id: physicalKeysMapper
182 onPowerKeyLongPressed: dialogs.showPowerDialog()
183 onVolumeDownTriggered: volumeControl.volumeDown();
184 onVolumeUpTriggered: volumeControl.volumeUp();
185 onScreenshotTriggered: screenGrabber.capture();
186 }
188 ScreenGrabber {
189 id: screenGrabber
190 z: dialogs.z + 10
191 enabled: Powerd.status === Powerd.On
192 }
194 Binding {
195 target: ApplicationManager
196 property: "forceDashActive"
197 value: launcher.shown || launcher.dashSwipe
198 }
200 WindowKeysFilter {
201 Keys.onPressed: physicalKeysMapper.onKeyPressed(event);
202 Keys.onReleased: physicalKeysMapper.onKeyReleased(event);
203 }
205 HomeKeyWatcher {
206 onActivated: { launcher.fadeOut(); shell.showHome(); }
207 }
209 Item {
210 id: stages
211 objectName: "stages"
212 width: parent.width
213 height: parent.height
215 Connections {
216 target: ApplicationManager
218 // This signal is also fired when we try to focus the current app
219 // again. We rely on this!
220 onFocusedApplicationIdChanged: {
221 var appId = ApplicationManager.focusedApplicationId;
223 if (tutorial.running && appId != "" && appId != "unity8-dash") {
224 // If this happens on first boot, we may be in edge
225 // tutorial or wizard while receiving a call. But a call
226 // is more important than wizard so just bail out of those.
227 tutorial.finish();
228 wizard.hide();
229 }
231 if (appId === "dialer-app" && callManager.hasCalls && greeter.locked) {
232 // If we are in the middle of a call, make dialer lockedApp and show it.
233 // This can happen if user backs out of dialer back to greeter, then
234 // launches dialer again.
235 greeter.lockedApp = appId;
236 }
237 greeter.notifyAppFocused(appId);
239 panel.indicators.hide();
240 }
242 onApplicationAdded: {
243 launcher.hide();
244 }
245 }
247 Loader {
248 id: applicationsDisplayLoader
249 objectName: "applicationsDisplayLoader"
250 anchors.fill: parent
252 // When we have a locked app, we only want to show that one app.
253 // FIXME: do this in a less traumatic way. We currently only allow
254 // locked apps in phone mode (see FIXME in Lockscreen component in
255 // this same file). When that changes, we need to do something
256 // nicer here. But this code is currently just to prevent a
257 // theoretical attack where user enters lockedApp mode, then makes
258 // the screen larger (maybe connects to monitor) and tries to enter
259 // tablet mode.
261 property string usageScenario: shell.usageScenario === "phone" || greeter.hasLockedApp
262 ? "phone"
263 : shell.usageScenario
264 source: {
265 if(shell.mode === "greeter") {
266 return "Stages/ShimStage.qml"
267 } else if (applicationsDisplayLoader.usageScenario === "phone") {
268 return "Stages/PhoneStage.qml";
269 } else if (applicationsDisplayLoader.usageScenario === "tablet") {
270 return "Stages/TabletStage.qml";
271 } else {
272 return "Stages/DesktopStage.qml";
273 }
274 }
276 property bool interactive: tutorial.spreadEnabled
277 && (!greeter || !greeter.shown)
278 && panel.indicators.fullyClosed
279 && launcher.progress == 0
280 && !notifications.useModal
282 onInteractiveChanged: { if (interactive) { focus = true; } }
284 Binding {
285 target: applicationsDisplayLoader.item
286 property: "objectName"
287 value: "stage"
288 }
289 Binding {
290 target: applicationsDisplayLoader.item
291 property: "dragAreaWidth"
292 value: shell.edgeSize
293 }
294 Binding {
295 target: applicationsDisplayLoader.item
296 property: "maximizedAppTopMargin"
297 // Not just using panel.panelHeight as that changes depending on the focused app.
298 value: panel.indicators.minimizedPanelHeight + units.dp(2) // dp(2) for orange line
299 }
300 Binding {
301 target: applicationsDisplayLoader.item
302 property: "interactive"
303 value: applicationsDisplayLoader.interactive
304 }
305 Binding {
306 target: applicationsDisplayLoader.item
307 property: "spreadEnabled"
308 value: tutorial.spreadEnabled && (!greeter || (!greeter.hasLockedApp && !greeter.shown))
309 }
310 Binding {
311 target: applicationsDisplayLoader.item
312 property: "inverseProgress"
313 value: greeter && greeter.locked ? 0 : launcher.progress
314 }
315 Binding {
316 target: applicationsDisplayLoader.item
317 property: "shellOrientationAngle"
318 value: shell.orientationAngle
319 }
320 Binding {
321 target: applicationsDisplayLoader.item
322 property: "shellOrientation"
323 value: shell.orientation
324 }
325 Binding {
326 target: applicationsDisplayLoader.item
327 property: "background"
328 value: shell.background
329 }
330 Binding {
331 target: applicationsDisplayLoader.item
332 property: "shellPrimaryOrientation"
333 value: shell.primaryOrientation
334 }
335 Binding {
336 target: applicationsDisplayLoader.item
337 property: "nativeOrientation"
338 value: shell.nativeOrientation
339 }
340 Binding {
341 target: applicationsDisplayLoader.item
342 property: "nativeWidth"
343 value: shell.nativeWidth
344 }
345 Binding {
346 target: applicationsDisplayLoader.item
347 property: "nativeHeight"
348 value: shell.nativeHeight
349 }
350 Binding {
351 target: applicationsDisplayLoader.item
352 property: "beingResized"
353 value: shell.beingResized
354 }
355 }
357 Tutorial {
358 id: tutorial
359 objectName: "tutorial"
360 anchors.fill: parent
361 active: AccountsService.demoEdges && shell.mode !== "greeter"
362 paused: lightDM.greeter.active
363 launcher: launcher
364 panel: panel
365 edgeSize: shell.edgeSize
367 // EdgeDragAreas don't work with mice. So to avoid trapping the user,
368 // we'll tell the tutorial to avoid using them on the Desktop. The
369 // Desktop doesn't use the same spread design anyway. The tutorial is
370 // all a bit of a placeholder on non-phone form factors right now.
371 // When the design team gives us more guidance, we can do something
372 // more clever here.
373 // TODO: use DeviceConfiguration instead of checking source
374 useEdgeDragArea: applicationsDisplayLoader.source != Qt.resolvedUrl("Stages/DesktopStage.qml")
376 onFinished: {
377 AccountsService.demoEdges = false;
378 active = false; // for immediate response / if AS is having problems
379 }
380 }
381 }
383 InputMethod {
384 id: inputMethod
385 objectName: "inputMethod"
386 anchors { fill: parent; topMargin: panel.panelHeight }
387 z: notifications.useModal || panel.indicators.shown || wizard.active ? overlay.z + 1 : overlay.z - 1
388 }
390 Connections {
391 target: SurfaceManager
392 onSurfaceCreated: {
393 if (surface.type == MirSurfaceItem.InputMethod) {
394 inputMethod.surface = surface;
395 }
396 }
398 onSurfaceDestroyed: {
399 if (inputMethod.surface == surface) {
400 inputMethod.surface = null;
401 surface.parent = null;
402 }
403 if (!surface.parent) {
404 // there's no one displaying it. delete it right away
405 surface.release();
406 }
407 }
408 }
409 Connections {
410 target: SessionManager
411 onSessionStopping: {
412 if (!session.parentSession && !session.application) {
413 // nothing is using it. delete it right away
414 session.release();
415 }
416 }
417 }
419 Loader {
420 id: greeterLoader
421 anchors.fill: parent
422 anchors.topMargin: panel.panelHeight
423 sourceComponent: shell.mode != "shell" ? integratedGreeter :
424 Qt.createComponent(Qt.resolvedUrl("Greeter/ShimGreeter.qml"));
425 onLoaded: {
426 item.objectName = "greeter"
427 }
428 }
430 Component {
431 id: integratedGreeter
432 Greeter {
434 hides: [launcher, panel.indicators]
435 tabletMode: shell.usageScenario != "phone"
436 launcherOffset: launcher.progress
437 forcedUnlock: tutorial.running
438 background: shell.background
440 // avoid overlapping with Launcher's edge drag area
441 // FIXME: Fix TouchRegistry & friends and remove this workaround
442 // Issue involves launcher's DDA getting disabled on a long
443 // left-edge drag
444 dragHandleLeftMargin: launcher.available ? launcher.dragAreaWidth + 1 : 0
446 onSessionStarted: {
447 launcher.hide();
448 }
450 onTease: {
451 if (!tutorial.running) {
452 launcher.tease();
453 }
454 }
456 onEmergencyCall: startLockedApp("dialer-app")
458 Binding {
459 target: ApplicationManager
460 property: "suspended"
461 value: greeter.shown
462 }
463 }
464 }
466 Timer {
467 // See powerConnection for why this is useful
468 id: showGreeterDelayed
469 interval: 1
470 onTriggered: {
471 greeter.forceShow();
472 }
473 }
475 Connections {
476 id: callConnection
477 target: callManager
479 onHasCallsChanged: {
480 if (greeter.locked && callManager.hasCalls && greeter.lockedApp !== "dialer-app") {
481 // We just received an incoming call while locked. The
482 // indicator will have already launched dialer-app for us, but
483 // there is a race between "hasCalls" changing and the dialer
484 // starting up. So in case we lose that race, we'll start/
485 // focus the dialer ourselves here too. Even if the indicator
486 // didn't launch the dialer for some reason (or maybe a call
487 // started via some other means), if an active call is
488 // happening, we want to be in the dialer.
489 startLockedApp("dialer-app")
490 }
491 }
492 }
494 Connections {
495 id: powerConnection
496 target: Powerd
498 onStatusChanged: {
499 if (Powerd.status === Powerd.Off && reason !== Powerd.Proximity &&
500 !callManager.hasCalls && !tutorial.running) {
501 // We don't want to simply call greeter.showNow() here, because
502 // that will take too long. Qt will delay button event
503 // handling until the greeter is done loading and may think the
504 // user held down the power button the whole time, leading to a
505 // power dialog being shown. Instead, delay showing the
506 // greeter until we've finished handling the event. We could
507 // make the greeter load asynchronously instead, but that
508 // introduces a whole host of timing issues, especially with
509 // its animations. So this is simpler.
510 showGreeterDelayed.start();
511 }
512 }
513 }
515 function showHome() {
516 if (tutorial.running) {
517 return
518 }
520 greeter.notifyAboutToFocusApp("unity8-dash");
522 var animate = !lightDM.greeter.active && !stages.shown
523 dash.setCurrentScope(0, animate, false)
524 ApplicationManager.requestFocusApplication("unity8-dash")
525 }
527 function showDash() {
528 if (greeter.notifyShowingDashFromDrag()) {
529 launcher.fadeOut();
530 }
532 if (!greeter.locked && ApplicationManager.focusedApplicationId != "unity8-dash") {
533 ApplicationManager.requestFocusApplication("unity8-dash")
534 launcher.fadeOut();
535 }
536 }
538 Item {
539 id: overlay
540 z: 10
542 anchors.fill: parent
544 Panel {
545 id: panel
546 objectName: "panel"
547 anchors.fill: parent //because this draws indicator menus
548 indicators {
549 hides: [launcher]
550 available: tutorial.panelEnabled
551 && ((!greeter || !greeter.locked) || AccountsService.enableIndicatorsWhileLocked)
552 && (!greeter || !greeter.hasLockedApp)
553 contentEnabled: tutorial.panelContentEnabled
554 width: parent.width > units.gu(60) ? units.gu(40) : parent.width
556 minimizedPanelHeight: units.gu(3)
557 expandedPanelHeight: units.gu(7)
559 indicatorsModel: Indicators.IndicatorsModel {
560 // tablet and phone both use the same profile
561 profile: shell.usageScenario === "desktop" ? "desktop" : "phone"
562 Component.onCompleted: load();
563 }
564 }
566 callHint {
567 greeterShown: greeter.shown
568 }
570 property bool mainAppIsFullscreen: shell.mainApp && shell.mainApp.fullscreen
571 fullscreenMode: (mainAppIsFullscreen && !LightDM.Greeter.active && launcher.progress == 0)
572 || greeter.hasLockedApp
573 }
575 Launcher {
576 id: launcher
577 objectName: "launcher"
579 readonly property bool dashSwipe: progress > 0
581 anchors.top: parent.top
582 anchors.topMargin: inverted ? 0 : panel.panelHeight
583 anchors.bottom: parent.bottom
584 width: parent.width
585 dragAreaWidth: shell.edgeSize
586 available: tutorial.launcherEnabled
587 && (!greeter.locked || AccountsService.enableLauncherWhileLocked)
588 && !greeter.hasLockedApp
589 inverted: shell.usageScenario !== "desktop"
590 shadeBackground: !tutorial.running
592 onShowDashHome: showHome()
593 onDash: showDash()
594 onDashSwipeChanged: {
595 if (dashSwipe) {
596 dash.setCurrentScope(0, false, true)
597 }
598 }
599 onLauncherApplicationSelected: {
600 if (!tutorial.running) {
601 greeter.notifyAboutToFocusApp(appId);
602 shell.activateApplication(appId)
603 }
604 }
605 onShownChanged: {
606 if (shown) {
607 panel.indicators.hide()
608 }
609 }
610 }
612 Wizard {
613 id: wizard
614 objectName: "wizard"
615 anchors.fill: parent
616 background: shell.background
618 function unlockWhenDoneWithWizard() {
619 if (!active) {
620 Connectivity.unlockAllModems();
621 }
622 }
624 Component.onCompleted: unlockWhenDoneWithWizard()
625 onActiveChanged: unlockWhenDoneWithWizard()
626 }
628 Rectangle {
629 id: modalNotificationBackground
631 visible: notifications.useModal
632 color: "#000000"
633 anchors.fill: parent
634 opacity: 0.9
636 MouseArea {
637 anchors.fill: parent
638 }
639 }
641 Notifications {
642 id: notifications
644 model: NotificationBackend.Model
645 margin: units.gu(1)
647 y: topmostIsFullscreen ? 0 : panel.panelHeight
648 height: parent.height - (topmostIsFullscreen ? 0 : panel.panelHeight)
650 states: [
651 State {
652 name: "narrow"
653 when: overlay.width <= units.gu(60)
654 AnchorChanges {
655 target: notifications
656 anchors.left: parent.left
657 anchors.right: parent.right
658 }
659 },
660 State {
661 name: "wide"
662 when: overlay.width > units.gu(60)
663 AnchorChanges {
664 target: notifications
665 anchors.left: undefined
666 anchors.right: parent.right
667 }
668 PropertyChanges { target: notifications; width: units.gu(38) }
669 }
670 ]
671 }
672 }
674 Dialogs {
675 id: dialogs
676 objectName: "dialogs"
677 anchors.fill: parent
678 z: overlay.z + 10
679 onPowerOffClicked: {
680 shutdownFadeOutRectangle.enabled = true;
681 shutdownFadeOutRectangle.visible = true;
682 shutdownFadeOut.start();
683 }
684 }
686 Connections {
687 target: SessionBroadcast
688 onShowHome: showHome()
689 }
691 Rectangle {
692 id: shutdownFadeOutRectangle
693 z: screenGrabber.z + 10
694 enabled: false
695 visible: false
696 color: "black"
697 anchors.fill: parent
698 opacity: 0.0
699 NumberAnimation on opacity {
700 id: shutdownFadeOut
701 from: 0.0
702 to: 1.0
703 onStopped: {
704 if (shutdownFadeOutRectangle.enabled && shutdownFadeOutRectangle.visible) {
705 DBusUnitySessionService.Shutdown();
706 }
707 }
708 }
709 }