git.iko.soy/unity8
on a6cff49 help sign in
unity8/qml/Panel/Panel.qml
449 lines 16 kB history raw
1/*
2 * Copyright (C) 2013-2016 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import Ubuntu.Layouts 1.0
20import Unity.Application 0.1
21import Unity.Indicators 0.1
22import Utils 0.1
23import Unity.ApplicationMenu 0.1
25import QtQuick.Window 2.2
26// for indicator-keyboard
27import AccountsService 0.1
28import Unity.InputInfo 0.1
30import "../ApplicationMenus"
31import "../Components"
32import "../Components/PanelState"
33import ".."
34import "Indicators"
36Item {
37 id: root
38 readonly property real panelHeight: panelArea.y + minimizedPanelHeight
40 property real minimizedPanelHeight: units.gu(3)
41 property real expandedPanelHeight: units.gu(7)
42 property real indicatorMenuWidth: width
43 property real applicationMenuWidth: width
45 property alias applicationMenus: __applicationMenus
46 property alias indicators: __indicators
47 property bool fullscreenMode: false
48 property real panelAreaShowProgress: 1.0
49 property bool greeterShown: false
50 property string mode: "staged"
51 property PanelState panelState
53 MouseArea {
54 id: backMouseEater
55 anchors.fill: parent
56 anchors.topMargin: panelHeight
57 visible: !indicators.fullyClosed || !applicationMenus.fullyClosed
58 enabled: visible
59 hoverEnabled: true // should also eat hover events, otherwise they will pass through
61 onClicked: {
62 __applicationMenus.hide();
63 __indicators.hide();
64 }
65 }
67 Binding {
68 target: panelState
69 property: "panelHeight"
70 value: minimizedPanelHeight
71 }
73 RegisteredApplicationMenuModel {
74 id: registeredMenuModel
75 persistentSurfaceId: panelState.focusedPersistentSurfaceId
76 }
78 QtObject {
79 id: d
81 property bool revealControls: !greeterShown &&
82 !applicationMenus.shown &&
83 !indicators.shown &&
84 (decorationMouseArea.containsMouse || menuBarLoader.menusRequested)
86 property bool showWindowDecorationControls: (revealControls && panelState.decorationsVisible) ||
87 panelState.decorationsAlwaysVisible
89 property bool showPointerMenu: revealControls &&
90 (panelState.decorationsVisible || mode == "staged")
92 property bool enablePointerMenu: revealControls &&
93 applicationMenus.available &&
94 applicationMenus.model
96 property bool showTouchMenu: !greeterShown &&
97 !showPointerMenu
99 property bool enableTouchMenus: showTouchMenu &&
100 applicationMenus.available &&
101 applicationMenus.model
102 }
104 Item {
105 id: panelArea
106 objectName: "panelArea"
108 anchors.fill: parent
110 transform: Translate {
111 y: indicators.state === "initial"
112 ? (1.0 - panelAreaShowProgress) * - minimizedPanelHeight
113 : 0
114 }
116 BorderImage {
117 id: indicatorsDropShadow
118 anchors {
119 fill: __indicators
120 margins: -units.gu(1)
121 }
122 visible: !__indicators.fullyClosed
123 source: "graphics/rectangular_dropshadow.sci"
124 }
126 BorderImage {
127 id: appmenuDropShadow
128 anchors {
129 fill: __applicationMenus
130 margins: -units.gu(1)
131 }
132 visible: !__applicationMenus.fullyClosed
133 source: "graphics/rectangular_dropshadow.sci"
134 }
136 BorderImage {
137 id: panelDropShadow
138 anchors {
139 fill: panelAreaBackground
140 bottomMargin: -units.gu(1)
141 }
142 visible: panelState.dropShadow
143 source: "graphics/rectangular_dropshadow.sci"
144 }
146 Rectangle {
147 id: panelAreaBackground
148 color: callHint.visible ? theme.palette.normal.positive : theme.palette.normal.background
149 anchors {
150 top: parent.top
151 left: parent.left
152 right: parent.right
153 }
154 height: minimizedPanelHeight
156 Behavior on color { ColorAnimation { duration: UbuntuAnimation.FastDuration } }
157 }
159 MouseArea {
160 id: decorationMouseArea
161 objectName: "windowControlArea"
162 anchors {
163 left: parent.left
164 right: parent.right
165 }
166 height: minimizedPanelHeight
167 hoverEnabled: !__indicators.shown
168 onClicked: {
169 if (callHint.visible) {
170 callHint.showLiveCall();
171 }
172 }
174 onPressed: {
175 if (!callHint.visible) {
176 // let it fall through to the window decoration of the maximized window behind, if any
177 mouse.accepted = false;
178 }
179 }
181 Row {
182 anchors.fill: parent
183 spacing: units.gu(2)
185 // WindowControlButtons inside the mouse area, otherwise QML doesn't grok nested hover events :/
186 // cf. https://bugreports.qt.io/browse/QTBUG-32909
187 WindowControlButtons {
188 id: windowControlButtons
189 objectName: "panelWindowControlButtons"
190 height: indicators.minimizedPanelHeight
191 opacity: d.showWindowDecorationControls ? 1 : 0
192 visible: opacity != 0
193 Behavior on opacity { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
195 active: panelState.decorationsVisible || panelState.decorationsAlwaysVisible
196 windowIsMaximized: true
197 onCloseClicked: panelState.closeClicked()
198 onMinimizeClicked: panelState.minimizeClicked()
199 onMaximizeClicked: panelState.restoreClicked()
200 closeButtonShown: panelState.closeButtonShown
201 }
203 Loader {
204 id: menuBarLoader
205 height: parent.height
206 enabled: d.enablePointerMenu
207 opacity: d.showPointerMenu ? 1 : 0
208 visible: opacity != 0
209 Behavior on opacity { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
210 active: __applicationMenus.model
212 property bool menusRequested: menuBarLoader.item ? menuBarLoader.item.showRequested : false
214 sourceComponent: MenuBar {
215 id: bar
216 objectName: "menuBar"
217 anchors.left: parent.left
218 anchors.margins: units.gu(1)
219 height: menuBarLoader.height
220 enableKeyFilter: valid && panelState.decorationsVisible
221 unityMenuModel: __applicationMenus.model
223 Connections {
224 target: __applicationMenus
225 onShownChanged: bar.dismiss();
226 }
228 Connections {
229 target: __indicators
230 onShownChanged: bar.dismiss();
231 }
232 }
233 }
234 }
236 ActiveCallHint {
237 id: callHint
238 objectName: "callHint"
240 anchors.centerIn: parent
241 height: minimizedPanelHeight
243 visible: active && indicators.state == "initial" && __applicationMenus.state == "initial"
244 greeterShown: root.greeterShown
245 }
246 }
248 PanelMenu {
249 id: __applicationMenus
251 model: registeredMenuModel.model
252 width: root.applicationMenuWidth
253 minimizedPanelHeight: root.minimizedPanelHeight
254 expandedPanelHeight: root.expandedPanelHeight
255 openedHeight: root.height
256 alignment: Qt.AlignLeft
257 enableHint: !callHint.active && !fullscreenMode
258 showOnClick: false
259 panelColor: panelAreaBackground.color
261 onShowTapped: {
262 if (callHint.active) {
263 callHint.showLiveCall();
264 }
265 }
267 showRowTitle: !expanded
268 rowTitle: panelState.title
269 rowItemDelegate: ActionItem {
270 id: actionItem
271 property int ownIndex: index
272 objectName: "appMenuItem"+index
274 width: _title.width + units.gu(2)
275 height: parent.height
277 action: Action {
278 text: model.label.replace("_", "&")
279 }
281 Label {
282 id: _title
283 anchors.centerIn: parent
284 text: actionItem.text
285 horizontalAlignment: Text.AlignLeft
286 color: enabled ? "white" : "#5d5d5d"
287 }
288 }
290 pageDelegate: PanelMenuPage {
291 menuModel: __applicationMenus.model
292 submenuIndex: modelIndex
294 factory: ApplicationMenuItemFactory {
295 rootModel: __applicationMenus.model
296 }
297 }
299 enabled: d.enableTouchMenus
300 opacity: d.showTouchMenu ? 1 : 0
301 visible: opacity != 0
302 Behavior on opacity { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
304 onEnabledChanged: {
305 if (!enabled) hide();
306 }
307 }
309 PanelMenu {
310 id: __indicators
311 objectName: "indicators"
313 anchors {
314 top: parent.top
315 right: parent.right
316 }
317 width: root.indicatorMenuWidth
318 minimizedPanelHeight: root.minimizedPanelHeight
319 expandedPanelHeight: root.expandedPanelHeight
320 openedHeight: root.height
322 overFlowWidth: root.width
323 enableHint: !callHint.active && !fullscreenMode
324 showOnClick: !callHint.visible
325 panelColor: panelAreaBackground.color
327 onShowTapped: {
328 if (callHint.active) {
329 callHint.showLiveCall();
330 }
331 }
333 rowItemDelegate: IndicatorItem {
334 id: indicatorItem
335 objectName: identifier+"-panelItem"
337 property int ownIndex: index
338 property bool overflow: parent.width - x > __indicators.overFlowWidth
339 property bool hidden: !expanded && (overflow || !indicatorVisible || hideSessionIndicator || hideKeyboardIndicator)
340 // HACK for indicator-session
341 readonly property bool hideSessionIndicator: identifier == "indicator-session" && Math.min(Screen.width, Screen.height) <= units.gu(60)
342 // HACK for indicator-keyboard
343 readonly property bool hideKeyboardIndicator: identifier == "indicator-keyboard" && (AccountsService.keymaps.length < 2 || keyboardsModel.count == 0)
345 height: parent.height
346 expanded: indicators.expanded
347 selected: ListView.isCurrentItem
349 identifier: model.identifier
350 busName: indicatorProperties.busName
351 actionsObjectPath: indicatorProperties.actionsObjectPath
352 menuObjectPath: indicatorProperties.menuObjectPath
354 opacity: hidden ? 0.0 : 1.0
355 Behavior on opacity { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
357 width: ((expanded || indicatorVisible) && !hideSessionIndicator && !hideKeyboardIndicator) ? implicitWidth : 0
359 Behavior on width { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
360 }
362 pageDelegate: PanelMenuPage {
363 objectName: modelData.identifier + "-page"
364 submenuIndex: 0
366 menuModel: delegate.menuModel
368 factory: IndicatorMenuItemFactory {
369 indicator: {
370 var context = modelData.identifier;
371 if (context && context.indexOf("fake-") === 0) {
372 context = context.substring("fake-".length)
373 }
374 return context;
375 }
376 rootModel: delegate.menuModel
377 }
379 IndicatorDelegate {
380 id: delegate
381 busName: modelData.indicatorProperties.busName
382 actionsObjectPath: modelData.indicatorProperties.actionsObjectPath
383 menuObjectPath: modelData.indicatorProperties.menuObjectPath
384 }
385 }
387 enabled: !applicationMenus.expanded
388 opacity: !applicationMenus.expanded ? 1 : 0
389 Behavior on opacity { UbuntuNumberAnimation { duration: UbuntuAnimation.SnapDuration } }
391 onEnabledChanged: {
392 if (!enabled) hide();
393 }
394 }
395 }
397 InputDeviceModel {
398 id: keyboardsModel
399 deviceFilter: InputInfo.Keyboard
400 }
402 IndicatorsLight {
403 id: indicatorLights
404 }
406 states: [
407 State {
408 name: "onscreen" //fully opaque and visible at top edge of screen
409 when: !fullscreenMode
410 PropertyChanges {
411 target: panelArea;
412 anchors.topMargin: 0
413 opacity: 1;
414 }
415 },
416 State {
417 name: "offscreen" //pushed off screen
418 when: fullscreenMode
419 PropertyChanges {
420 target: panelArea;
421 anchors.topMargin: {
422 if (indicators.state !== "initial") return 0;
423 if (applicationMenus.state !== "initial") return 0;
424 return -minimizedPanelHeight;
425 }
426 opacity: indicators.fullyClosed && applicationMenus.fullyClosed ? 0.0 : 1.0
427 }
428 PropertyChanges {
429 target: indicators.showDragHandle;
430 anchors.bottomMargin: -units.gu(1)
431 }
432 PropertyChanges {
433 target: applicationMenus.showDragHandle;
434 anchors.bottomMargin: -units.gu(1)
435 }
436 }
437 ]
439 transitions: [
440 Transition {
441 to: "onscreen"
442 UbuntuNumberAnimation { target: panelArea; properties: "anchors.topMargin,opacity" }
443 },
444 Transition {
445 to: "offscreen"
446 UbuntuNumberAnimation { target: panelArea; properties: "anchors.topMargin,opacity" }
447 }
448 ]