git.iko.soy/unity8
on a6d77df help sign in
unity8/qml/Panel/IndicatorsMenu.qml
323 lines 11 kB history raw
1/*
2 * Copyright (C) 2014 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.2
18import Ubuntu.Components 1.1
19import Ubuntu.Gestures 0.1
20import "../Components"
21import "Indicators"
23Showable {
24 id: root
25 property alias indicatorsModel: bar.indicatorsModel
26 property alias showDragHandle: __showDragHandle
27 property alias hideDragHandle: __hideDragHandle
28 property alias overFlowWidth: bar.overFlowWidth
29 property alias verticalVelocityThreshold: yVelocityCalculator.velocityThreshold
30 property int minimizedPanelHeight: units.gu(3)
31 property int expandedPanelHeight: units.gu(7)
32 property real openedHeight: units.gu(71)
33 readonly property real unitProgress: Math.max(0, (height - minimizedPanelHeight) / (openedHeight - minimizedPanelHeight))
34 readonly property bool fullyOpened: unitProgress >= 1
35 readonly property bool partiallyOpened: unitProgress > 0 && unitProgress < 1.0
36 readonly property bool fullyClosed: unitProgress == 0
37 property bool enableHint: true
38 property bool contentEnabled: true
39 property color panelColor: "black"
41 signal showTapped(point position)
43 // TODO: Perhaps we need a animation standard for showing/hiding? Each showable seems to
44 // use its own values. Need to ask design about this.
45 showAnimation: StandardAnimation {
46 property: "height"
47 to: openedHeight
48 duration: UbuntuAnimation.BriskDuration
49 easing.type: Easing.OutCubic
50 }
52 hideAnimation: StandardAnimation {
53 property: "height"
54 to: minimizedPanelHeight
55 duration: UbuntuAnimation.BriskDuration
56 easing.type: Easing.OutCubic
57 }
59 height: minimizedPanelHeight
61 onUnitProgressChanged: d.updateState()
62 clip: root.partiallyOpened
64 IndicatorsLight {
65 id: indicatorLights
66 }
68 // eater
69 MouseArea {
70 anchors.fill: parent
71 }
73 MenuContent {
74 id: content
75 objectName: "menuContent"
77 anchors {
78 left: parent.left
79 right: parent.right
80 top: bar.bottom
81 }
82 height: openedHeight - bar.height - handle.height
83 indicatorsModel: root.indicatorsModel
84 visible: root.unitProgress > 0
85 enabled: contentEnabled
86 currentMenuIndex: bar.currentItemIndex
87 }
89 Handle {
90 id: handle
91 anchors {
92 left: parent.left
93 right: parent.right
94 bottom: parent.bottom
95 }
96 height: units.gu(2)
97 active: d.activeDragHandle ? true : false
99 //small shadow gradient at bottom of menu
100 Rectangle {
101 anchors {
102 left: parent.left
103 right: parent.right
104 bottom: parent.top
105 }
106 height: units.gu(0.5)
107 gradient: Gradient {
108 GradientStop { position: 0.0; color: "transparent" }
109 GradientStop { position: 1.0; color: "black" }
110 }
111 opacity: 0.3
112 }
113 }
115 Rectangle {
116 anchors.fill: bar
117 color: panelColor
118 }
120 IndicatorsBar {
121 id: bar
122 objectName: "indicatorsBar"
124 anchors {
125 left: parent.left
126 right: parent.right
127 }
128 expanded: false
129 enableLateralChanges: false
130 lateralPosition: -1
131 unitProgress: root.unitProgress
133 height: expanded ? expandedPanelHeight : minimizedPanelHeight
134 Behavior on height { NumberAnimation { duration: UbuntuAnimation.SnapDuration; easing: UbuntuAnimation.StandardEasing } }
135 }
137 ScrollCalculator {
138 id: leftScroller
139 width: units.gu(5)
140 anchors.left: bar.left
141 height: bar.height
143 forceScrollingPercentage: 0.33
144 stopScrollThreshold: units.gu(0.75)
145 direction: Qt.RightToLeft
146 lateralPosition: -1
148 onScroll: bar.addScrollOffset(-scrollAmount);
149 }
151 ScrollCalculator {
152 id: rightScroller
153 width: units.gu(5)
154 anchors.right: bar.right
155 height: bar.height
157 forceScrollingPercentage: 0.33
158 stopScrollThreshold: units.gu(0.75)
159 direction: Qt.LeftToRight
160 lateralPosition: -1
162 onScroll: bar.addScrollOffset(scrollAmount);
163 }
165 DragHandle {
166 id: __showDragHandle
167 anchors.bottom: parent.bottom
168 anchors.left: parent.left
169 anchors.right: parent.right
170 height: minimizedPanelHeight
171 direction: Direction.Downwards
172 enabled: !root.shown && root.available
173 autoCompleteDragThreshold: maxTotalDragDistance / 2
174 stretch: true
175 distanceThreshold: enableHint ? 0 : minimizedPanelHeight
177 onTapped: showTapped(Qt.point(touchSceneX, touchSceneY));
179 // using hint regulates minimum to hint displacement, but in fullscreen mode, we need to do it manually.
180 overrideStartValue: enableHint ? minimizedPanelHeight : expandedPanelHeight + handle.height
181 maxTotalDragDistance: openedHeight - (enableHint ? minimizedPanelHeight : expandedPanelHeight + handle.height)
182 hintDisplacement: enableHint ? expandedPanelHeight - minimizedPanelHeight + handle.height : 0
183 }
185 DragHandle {
186 id: __hideDragHandle
187 anchors.fill: handle
188 direction: Direction.Upwards
189 enabled: root.shown && root.available
190 hintDisplacement: units.gu(3)
191 autoCompleteDragThreshold: maxTotalDragDistance / 6
192 stretch: true
193 maxTotalDragDistance: openedHeight - expandedPanelHeight - handle.height
195 onTouchSceneXChanged: {
196 if (root.state === "locked") {
197 d.xDisplacementSinceLock += (touchSceneX - d.lastHideTouchSceneX)
198 d.lastHideTouchSceneX = touchSceneX;
199 }
200 }
201 }
203 PanelVelocityCalculator {
204 id: yVelocityCalculator
205 velocityThreshold: d.hasCommitted ? 0.1 : 0.3
206 trackedValue: d.activeDragHandle ? d.activeDragHandle.touchSceneY : 0
208 onVelocityAboveThresholdChanged: d.updateState()
209 }
211 Connections {
212 target: showAnimation
213 onRunningChanged: {
214 if (showAnimation.running) {
215 root.state = "commit";
216 }
217 }
218 }
220 Connections {
221 target: hideAnimation
222 onRunningChanged: {
223 if (hideAnimation.running) {
224 root.state = "initial";
225 }
226 }
227 }
229 QtObject {
230 id: d
231 property var activeDragHandle: showDragHandle.dragging ? showDragHandle : hideDragHandle.dragging ? hideDragHandle : null
232 property bool hasCommitted: false
233 property real lastHideTouchSceneX: 0
234 property real xDisplacementSinceLock: 0
235 onXDisplacementSinceLockChanged: d.updateState()
237 property real rowMappedLateralPosition: {
238 if (!d.activeDragHandle) return -1;
239 return d.activeDragHandle.mapToItem(bar, d.activeDragHandle.touchX, 0).x;
240 }
242 function updateState() {
243 if (!showAnimation.running && !hideAnimation.running) {
244 if (unitProgress <= 0) {
245 root.state = "initial";
246 // lock indicator if we've been committed and aren't moving too much laterally or too fast up.
247 } else if (d.hasCommitted && (Math.abs(d.xDisplacementSinceLock) < units.gu(2) || yVelocityCalculator.velocityAboveThreshold)) {
248 root.state = "locked";
249 } else {
250 root.state = "reveal";
251 }
252 }
253 }
254 }
256 states: [
257 State {
258 name: "initial"
259 PropertyChanges { target: d; hasCommitted: false; restoreEntryValues: false }
260 },
261 State {
262 name: "reveal"
263 StateChangeScript {
264 script: {
265 yVelocityCalculator.reset();
266 // initial item selection
267 if (!d.hasCommitted) bar.selectItemAt(d.activeDragHandle ? d.activeDragHandle.touchX : -1);
268 d.hasCommitted = false;
269 }
270 }
271 PropertyChanges {
272 target: bar
273 expanded: true
274 // changes to lateral touch position effect which indicator is selected
275 lateralPosition: d.rowMappedLateralPosition
276 // vertical velocity determines if changes in lateral position has an effect
277 enableLateralChanges: d.activeDragHandle &&
278 !yVelocityCalculator.velocityAboveThreshold
279 }
280 // left scroll bar handling
281 PropertyChanges {
282 target: leftScroller
283 lateralPosition: {
284 if (!d.activeDragHandle) return -1;
285 var mapped = d.activeDragHandle.mapToItem(leftScroller, d.activeDragHandle.touchX, 0);
286 return mapped.x;
287 }
288 }
289 // right scroll bar handling
290 PropertyChanges {
291 target: rightScroller
292 lateralPosition: {
293 if (!d.activeDragHandle) return -1;
294 var mapped = d.activeDragHandle.mapToItem(rightScroller, d.activeDragHandle.touchX, 0);
295 return mapped.x;
296 }
297 }
298 },
299 State {
300 name: "locked"
301 StateChangeScript {
302 script: {
303 d.xDisplacementSinceLock = 0;
304 d.lastHideTouchSceneX = hideDragHandle.touchSceneX;
305 }
306 }
307 PropertyChanges { target: bar; expanded: true }
308 },
309 State {
310 name: "commit"
311 extend: "locked"
312 PropertyChanges { target: bar; interactive: true }
313 PropertyChanges {
314 target: d;
315 hasCommitted: true
316 lastHideTouchSceneX: 0
317 xDisplacementSinceLock: 0
318 restoreEntryValues: false
319 }
320 }
321 ]
322 state: "initial"