git.iko.soy/unity8
on a91dd21 help sign in
unity8/qml/Dash/GenericScopeView.qml
814 lines 37 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import Utils 0.1
20import Unity 0.2
21import Dash 0.1
22import "../Components"
23import "../Components/ListItems" as ListItems
25FocusScope {
26 id: scopeView
28 readonly property bool navigationDisableParentInteractive: pageHeaderLoader.item ? pageHeaderLoader.item.bottomItem[0].disableParentInteractive : false
29 property bool forceNonInteractive: false
30 property var scope: null
31 property UnitySortFilterProxyModel categories: categoryFilter
32 property bool isCurrent: false
33 property alias moving: categoryView.moving
34 property bool hasBackAction: false
35 property bool enableHeightBehaviorOnNextCreation: false
36 property var categoryView: categoryView
37 property bool showPageHeader: true
38 readonly property alias subPageShown: subPageLoader.subPageShown
39 property int paginationCount: 0
40 property int paginationIndex: 0
41 property bool visibleToParent: false
42 property alias pageHeaderTotallyVisible: categoryView.pageHeaderTotallyVisible
43 property var holdingList: null
44 property bool wasCurrentOnMoveStart: false
46 property var scopeStyle: ScopeStyle {
47 style: scope ? scope.customizations : {}
48 }
50 readonly property bool processing: scope ? scope.searchInProgress || subPageLoader.processing : false
52 signal backClicked()
54 onScopeChanged: {
55 floatingSeeLess.companionBase = null;
56 }
58 function positionAtBeginning() {
59 categoryView.positionAtBeginning()
60 }
62 function showHeader() {
63 categoryView.showHeader()
64 }
66 function closePreview() {
67 subPageLoader.closeSubPage()
68 }
70 function resetSearch() {
71 if(pageHeaderLoader.item && showPageHeader)
72 pageHeaderLoader.item.resetSearch()
73 }
75 property var maybePreviewResult;
76 property int maybePreviewIndex;
77 property var maybePreviewResultsModel;
78 property int maybePreviewLimitedCategoryItemCount;
79 property string maybePreviewCategoryId;
81 function clearMaybePreviewData() {
82 scopeView.maybePreviewResult = undefined;
83 scopeView.maybePreviewIndex = -1;
84 scopeView.maybePreviewResultsModel = undefined;
85 scopeView.maybePreviewLimitedCategoryItemCount = -1;
86 scopeView.maybePreviewCategoryId = "";
87 }
89 function itemClicked(index, result, itemModel, resultsModel, limitedCategoryItemCount, categoryId) {
90 scopeView.maybePreviewResult = result;
91 scopeView.maybePreviewIndex = index;
92 scopeView.maybePreviewResultsModel = resultsModel;
93 scopeView.maybePreviewLimitedCategoryItemCount = limitedCategoryItemCount;
94 scopeView.maybePreviewCategoryId = categoryId;
96 scope.activate(result, categoryId);
97 }
99 function itemPressedAndHeld(index, result, resultsModel, limitedCategoryItemCount, categoryId) {
100 clearMaybePreviewData();
102 openPreview(result, index, resultsModel, limitedCategoryItemCount, categoryId);
103 }
105 function openPreview(result, index, resultsModel, limitedCategoryItemCount, categoryId) {
106 var previewStack = scope.preview(result, categoryId);
107 if (previewStack) {
108 if (limitedCategoryItemCount > 0) {
109 previewLimitModel.model = resultsModel;
110 previewLimitModel.limit = limitedCategoryItemCount;
111 subPageLoader.model = previewLimitModel;
112 } else {
113 subPageLoader.model = resultsModel;
114 }
115 subPageLoader.initialIndex = -1;
116 subPageLoader.initialIndex = index;
117 subPageLoader.categoryId = categoryId;
118 subPageLoader.previewStack = previewStack;
119 subPageLoader.openSubPage("preview");
120 }
121 }
123 Binding {
124 target: scope
125 property: "isActive"
126 value: isCurrent && !subPageLoader.open && (Qt.application.state == Qt.ApplicationActive)
127 }
129 UnitySortFilterProxyModel {
130 id: categoryFilter
131 model: scope ? scope.categories : null
132 dynamicSortFilter: true
133 filterRole: Categories.RoleCount
134 filterRegExp: /^0$/
135 invertMatch: true
136 }
138 onIsCurrentChanged: {
139 if (!holdingList || !holdingList.moving) {
140 wasCurrentOnMoveStart = scopeView.isCurrent;
141 }
142 if (pageHeaderLoader.item && showPageHeader) {
143 pageHeaderLoader.item.resetSearch();
144 }
145 subPageLoader.closeSubPage();
146 }
148 Binding {
149 target: scopeView.scope
150 property: "searchQuery"
151 value: pageHeaderLoader.item ? pageHeaderLoader.item.searchQuery : ""
152 when: isCurrent && showPageHeader
153 }
155 Binding {
156 target: pageHeaderLoader.item
157 property: "searchQuery"
158 value: scopeView.scope ? scopeView.scope.searchQuery : ""
159 when: isCurrent && showPageHeader
160 }
162 Connections {
163 target: scopeView.scope
164 onShowDash: subPageLoader.closeSubPage()
165 onHideDash: subPageLoader.closeSubPage()
166 onPreviewRequested: { // (QVariant const& result)
167 if (result === scopeView.maybePreviewResult) {
168 openPreview(result,
169 scopeView.maybePreviewIndex,
170 scopeView.maybePreviewResultsModel,
171 scopeView.maybePreviewLimitedCategoryItemCount,
172 scopeView.maybePreviewCategoryId);
174 clearMaybePreviewData();
175 }
176 }
177 }
179 Connections {
180 target: holdingList
181 onMovingChanged: {
182 if (!moving) {
183 wasCurrentOnMoveStart = scopeView.isCurrent;
184 }
185 }
186 }
188 Rectangle {
189 anchors.fill: parent
190 color: scopeView.scopeStyle ? scopeView.scopeStyle.background : "transparent"
191 visible: color != "transparent"
192 }
194 ScopeListView {
195 id: categoryView
196 objectName: "categoryListView"
197 interactive: !forceNonInteractive
199 x: subPageLoader.open ? -width : 0
200 visible: x != -width
201 Behavior on x { UbuntuNumberAnimation { } }
202 width: parent.width
203 height: floatingSeeLess.visible ? parent.height - floatingSeeLess.height + floatingSeeLess.yOffset
204 : parent.height
205 clip: height != parent.height
207 model: scopeView.categories
208 forceNoClip: subPageLoader.open
209 pixelAligned: true
211 property string expandedCategoryId: ""
212 property int runMaximizeAfterSizeChanges: 0
214 readonly property bool pageHeaderTotallyVisible: scopeView.showPageHeader &&
215 ((headerItemShownHeight == 0 && categoryView.contentY <= categoryView.originY) || (headerItemShownHeight == pageHeaderLoader.item.height))
217 onExpandedCategoryIdChanged: {
218 var firstCreated = firstCreatedIndex();
219 var shrinkingAny = false;
220 var shrinkHeightDifference = 0;
221 for (var i = 0; i < createdItemCount(); ++i) {
222 var baseItem = item(firstCreated + i);
223 if (baseItem.expandable) {
224 var shouldExpand = baseItem.category === expandedCategoryId;
225 if (shouldExpand != baseItem.expanded) {
226 var animate = false;
227 if (!subPageLoader.open) {
228 var animateShrinking = !shouldExpand && baseItem.y + baseItem.item.collapsedHeight + baseItem.seeAllButton.height < categoryView.height;
229 var animateGrowing = shouldExpand && baseItem.y + baseItem.height < categoryView.height;
230 animate = shrinkingAny || animateShrinking || animateGrowing;
231 }
233 if (!shouldExpand) {
234 shrinkingAny = true;
235 shrinkHeightDifference = baseItem.item.expandedHeight - baseItem.item.collapsedHeight;
236 }
238 if (shouldExpand && !subPageLoader.open) {
239 if (!shrinkingAny) {
240 categoryView.maximizeVisibleArea(firstCreated + i, baseItem.item.expandedHeight + baseItem.seeAllButton.height);
241 } else {
242 // If the space that shrinking is smaller than the one we need to grow we'll call maximizeVisibleArea
243 // after the shrink/grow animation ends
244 var growHeightDifference = baseItem.item.expandedHeight - baseItem.item.collapsedHeight;
245 if (growHeightDifference > shrinkHeightDifference) {
246 runMaximizeAfterSizeChanges = 2;
247 } else {
248 runMaximizeAfterSizeChanges = 0;
249 }
250 }
251 }
253 baseItem.expand(shouldExpand, animate);
254 }
255 }
256 }
257 }
259 delegate: DashCategoryBase {
260 id: baseItem
261 objectName: "dashCategory" + category
263 property Item seeAllButton: seeAll
265 readonly property bool expandable: {
266 if (categoryView.model.count === 1) return false;
267 if (cardTool.template && cardTool.template["collapsed-rows"] === 0) return false;
268 if (item && item.expandedHeight > item.collapsedHeight) return true;
269 return false;
270 }
271 property bool expanded: false
272 readonly property string category: categoryId
273 readonly property string headerLink: model.headerLink
274 readonly property var item: rendererLoader.item
276 function expand(expand, animate) {
277 heightBehaviour.enabled = animate;
278 expanded = expand;
279 }
281 CardTool {
282 id: cardTool
283 objectName: "cardTool"
284 count: results ? results.count : 0
285 template: model.renderer
286 components: model.components
287 viewWidth: parent.width
288 }
290 onExpandableChanged: {
291 // This can happen with the VJ that doesn't know how height it will be on creation
292 // so doesn't set expandable until a bit too late for onLoaded
293 if (expandable) {
294 var shouldExpand = baseItem.category === categoryView.expandedCategoryId;
295 baseItem.expand(shouldExpand, false /*animate*/);
296 }
297 }
299 onHeightChanged: rendererLoader.updateRanges();
300 onYChanged: rendererLoader.updateRanges();
302 Loader {
303 id: rendererLoader
304 anchors {
305 top: parent.top
306 left: parent.left
307 right: parent.right
308 topMargin: name != "" ? 0 : units.gu(2)
309 }
311 Behavior on height {
312 id: heightBehaviour
313 enabled: false
314 animation: UbuntuNumberAnimation {
315 duration: UbuntuAnimation.FastDuration
316 onRunningChanged: {
317 if (!running) {
318 heightBehaviour.enabled = false
319 if (categoryView.runMaximizeAfterSizeChanges > 0) {
320 categoryView.runMaximizeAfterSizeChanges--;
321 if (categoryView.runMaximizeAfterSizeChanges == 0) {
322 var firstCreated = categoryView.firstCreatedIndex();
323 for (var i = 0; i < categoryView.createdItemCount(); ++i) {
324 var baseItem = categoryView.item(firstCreated + i);
325 if (baseItem.category === categoryView.expandedCategoryId) {
326 categoryView.maximizeVisibleArea(firstCreated + i, baseItem.item.expandedHeight + baseItem.seeAllButton.height);
327 break;
328 }
329 }
330 }
331 }
332 }
333 }
334 }
335 }
337 readonly property bool expanded: baseItem.expanded || !baseItem.expandable
338 height: expanded ? item.expandedHeight : item.collapsedHeight
340 source: {
341 switch (cardTool.categoryLayout) {
342 case "carousel": return "CardCarousel.qml";
343 case "vertical-journal": return "CardVerticalJournal.qml";
344 case "horizontal-list": return "CardHorizontalList.qml";
345 case "grid":
346 default: return "CardGrid.qml";
347 }
348 }
350 onLoaded: {
351 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
352 item.enableHeightBehavior = scopeView.enableHeightBehaviorOnNextCreation;
353 scopeView.enableHeightBehaviorOnNextCreation = false;
354 }
355 item.model = Qt.binding(function() { return results })
356 item.objectName = Qt.binding(function() { return categoryId })
357 item.scopeStyle = scopeView.scopeStyle;
358 if (baseItem.expandable) {
359 var shouldExpand = baseItem.category === categoryView.expandedCategoryId;
360 baseItem.expand(shouldExpand, false /*animate*/);
361 }
362 updateRanges();
363 if (scope && scope.id === "clickscope" && (categoryId === "predefined" || categoryId === "local")) {
364 // Yeah, hackish :/
365 if (scopeView.width > units.gu(45)) {
366 if (scopeView.width >= units.gu(70)) {
367 cardTool.cardWidth = units.gu(9);
368 } else {
369 cardTool.cardWidth = units.gu(10);
370 }
371 }
372 cardTool.artShapeSize = Qt.size(units.gu(8), units.gu(7.5));
373 item.artShapeStyle = "icon";
374 }
375 item.cardTool = cardTool;
376 }
378 Component.onDestruction: {
379 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
380 scopeView.enableHeightBehaviorOnNextCreation = item.enableHeightBehaviorOnNextCreation;
381 }
382 }
384 Connections {
385 target: rendererLoader.item
386 onClicked: { // (int index, var result, var item, var itemModel)
387 scopeView.itemClicked(index, result, itemModel, target.model, categoryItemCount(), baseItem.category);
388 }
390 onPressAndHold: { // (int index, var result, var itemModel)
391 scopeView.itemPressedAndHeld(index, result, target.model, categoryItemCount(), baseItem.category);
392 }
394 function categoryItemCount() {
395 var categoryItemCount = -1;
396 if (!rendererLoader.expanded && !seeAllLabel.visible && target.collapsedItemCount > 0) {
397 categoryItemCount = target.collapsedItemCount;
398 }
399 return categoryItemCount;
400 }
401 }
402 Connections {
403 target: categoryView
404 onOriginYChanged: rendererLoader.updateRanges();
405 onContentYChanged: rendererLoader.updateRanges();
406 onHeightChanged: rendererLoader.updateRanges();
407 onContentHeightChanged: rendererLoader.updateRanges();
408 }
409 Connections {
410 target: scopeView
411 onIsCurrentChanged: rendererLoader.updateRanges();
412 onVisibleToParentChanged: rendererLoader.updateRanges();
413 }
414 Connections {
415 target: holdingList
416 onMovingChanged: if (!moving) rendererLoader.updateRanges();
417 }
419 function updateRanges() {
420 // Don't want to create stress by requesting more items during scope
421 // changes so unless you're not part of the visible scopes just return.
422 // For the visible scopes we need to do some work, the previously non visible
423 // scope needs to adjust its ranges so that we define the new visible range,
424 // that still means no creation/destruction of delegates, it's just about changing
425 // the culling of the items so they are actually visible
426 if (holdingList && holdingList.moving && !scopeView.visibleToParent) {
427 return;
428 }
430 if (categoryView.moving) {
431 // Do not update the range if we are overshooting up or down, since we'll come back
432 // to the stable position and delete/create items without any reason
433 if (categoryView.contentY < categoryView.originY) {
434 return;
435 } else if (categoryView.contentHeight - categoryView.originY > categoryView.height &&
436 categoryView.contentY + categoryView.height > categoryView.contentHeight) {
437 return;
438 }
439 }
441 if (item && item.hasOwnProperty("displayMarginBeginning")) {
442 var buffer = wasCurrentOnMoveStart ? categoryView.height * 1.5 : 0;
443 var onViewport = baseItem.y + baseItem.height > 0 &&
444 baseItem.y < categoryView.height;
445 var onBufferViewport = baseItem.y + baseItem.height > -buffer &&
446 baseItem.y < categoryView.height + buffer;
448 if (item.growsVertically) {
449 // A item view creates its delegates synchronously from
450 // -displayMarginBeginning
451 // to
452 // height + displayMarginEnd
453 // Around that area it adds the cacheBuffer area where delegates are created async
454 //
455 // We adjust displayMarginBeginning and displayMarginEnd so
456 // * In non visible scopes nothing is considered visible and we set cacheBuffer
457 // so that creates the items that would be in the viewport asynchronously
458 // * For the current scope set the visible range to the viewport and then
459 // use cacheBuffer to create extra items for categoryView.height * 1.5
460 // to make scrolling nicer by mantaining a higher number of
461 // cached items
462 // * For non current but visible scopes (i.e. when the user changes from one scope
463 // to the next, we set the visible range to the viewport so
464 // items are not culled (invisible) but still use no cacheBuffer
465 // (it will be set once the scope is the current one)
466 var displayMarginBeginning = baseItem.y + rendererLoader.anchors.topMargin;
467 displayMarginBeginning = -Math.max(-displayMarginBeginning, 0);
468 displayMarginBeginning = -Math.min(-displayMarginBeginning, baseItem.height);
469 displayMarginBeginning = Math.round(displayMarginBeginning);
470 var displayMarginEnd = -baseItem.height + seeAll.height + categoryView.height - baseItem.y;
471 displayMarginEnd = -Math.max(-displayMarginEnd, 0);
472 displayMarginEnd = -Math.min(-displayMarginEnd, baseItem.height);
473 displayMarginEnd = Math.round(displayMarginEnd);
475 if (onBufferViewport && (scopeView.isCurrent || scopeView.visibleToParent)) {
476 item.displayMarginBeginning = displayMarginBeginning;
477 item.displayMarginEnd = displayMarginEnd;
478 if (holdingList && holdingList.moving) {
479 // If we are moving we need to reset the cache buffer of the
480 // view that was not visible (i.e. !wasCurrentOnMoveStart) to 0 since
481 // otherwise the cache buffer we had set to preload the items of the
482 // visible range will trigger some item creations and we want move to
483 // be as smooth as possible meaning no need creations
484 if (!wasCurrentOnMoveStart) {
485 item.cacheBuffer = 0;
486 }
487 } else {
488 // Protect us against cases where the item hasn't yet been positioned
489 if (!(categoryView.contentY === 0 && baseItem.y === 0 && index !== 0)) {
490 item.cacheBuffer = categoryView.height * 1.5;
491 }
492 }
493 } else {
494 var visibleRange = baseItem.height + displayMarginEnd + displayMarginBeginning;
495 if (visibleRange < 0) {
496 item.displayMarginBeginning = displayMarginBeginning;
497 item.displayMarginEnd = displayMarginEnd;
498 item.cacheBuffer = 0;
499 } else {
500 // This should be visibleRange/2 in each of the properties
501 // but some item views still (like GridView) like creating sync delegates even if
502 // the visible range is 0 so let's make sure the visible range is negative
503 item.displayMarginBeginning = displayMarginBeginning - visibleRange;
504 item.displayMarginEnd = displayMarginEnd - visibleRange;
505 item.cacheBuffer = visibleRange;
506 }
507 }
508 } else {
509 if (!onBufferViewport) {
510 // If not on the buffered viewport, don't load anything
511 item.displayMarginBeginning = 0;
512 item.displayMarginEnd = -item.innerWidth;
513 item.cacheBuffer = 0;
514 } else {
515 if (onViewport && (scopeView.isCurrent || scopeView.visibleToParent)) {
516 // If on the buffered viewport and the viewport and the on a visible scope
517 // Set displayMargin so that cards are rendered
518 // And if not moving the parent list also give it some extra asynchronously
519 // buffering
520 item.displayMarginBeginning = 0;
521 item.displayMarginEnd = 0;
522 if (holdingList && holdingList.moving) {
523 // If we are moving we need to reset the cache buffer of the
524 // view that was not visible (i.e. !wasCurrentOnMoveStart) to 0 since
525 // otherwise the cache buffer we had set to preload the items of the
526 // visible range will trigger some item creations and we want move to
527 // be as smooth as possible meaning no need creations
528 if (!wasCurrentOnMoveStart) {
529 item.cacheBuffer = 0;
530 }
531 } else {
532 item.cacheBuffer = baseItem.width * 1.5;
533 }
534 } else {
535 // If on the buffered viewport but either not in the real viewport
536 // or in the viewport of the non current scope, use displayMargin + cacheBuffer
537 // to render asynchronously the width of cards
538 item.displayMarginBeginning = 0;
539 item.displayMarginEnd = -item.innerWidth;
540 item.cacheBuffer = item.innerWidth;
541 }
542 }
543 }
544 }
545 }
546 }
548 AbstractButton {
549 id: seeAll
550 objectName: "seeAll"
551 anchors {
552 top: rendererLoader.bottom
553 left: parent.left
554 right: parent.right
555 }
556 height: baseItem.expandable && !baseItem.headerLink ? seeAllLabel.font.pixelSize + units.gu(4) : 0
557 visible: height != 0
559 onClicked: {
560 if (categoryView.expandedCategoryId !== baseItem.category) {
561 categoryView.expandedCategoryId = baseItem.category;
562 floatingSeeLess.companionBase = baseItem;
563 } else {
564 categoryView.expandedCategoryId = "";
565 }
566 }
568 Label {
569 id: seeAllLabel
570 text: baseItem.expanded ? i18n.tr("See less") : i18n.tr("See all")
571 anchors {
572 centerIn: parent
573 verticalCenterOffset: units.gu(-0.5)
574 }
575 fontSize: "small"
576 font.weight: Font.Bold
577 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
578 }
579 }
581 Image {
582 visible: index != 0
583 anchors {
584 top: parent.top
585 left: parent.left
586 right: parent.right
587 }
588 fillMode: Image.Stretch
589 source: "graphics/dash_divider_top_lightgrad.png"
590 z: -1
591 }
593 Image {
594 // FIXME Should not rely on model.count but view.count, but ListViewWithPageHeader doesn't expose it yet.
595 visible: index != categoryView.model.count - 1
596 anchors {
597 bottom: seeAll.bottom
598 left: parent.left
599 right: parent.right
600 }
601 fillMode: Image.Stretch
602 source: "graphics/dash_divider_top_darkgrad.png"
603 z: -1
604 }
605 }
607 sectionProperty: "name"
608 sectionDelegate: ListItems.Header {
609 objectName: "dashSectionHeader" + (delegate ? delegate.category : "")
610 readonly property var delegate: categoryView.item(delegateIndex)
611 width: categoryView.width
612 height: section != "" ? units.gu(5) : 0
613 text: section
614 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
615 iconName: delegate && delegate.headerLink ? "go-next" : ""
616 onClicked: {
617 if (delegate.headerLink) scopeView.scope.performQuery(delegate.headerLink);
618 }
619 }
621 pageHeader: scopeView.showPageHeader ? pageHeaderLoader : null
622 Loader {
623 id: pageHeaderLoader
624 width: parent.width
625 sourceComponent: scopeView.showPageHeader ? pageHeaderComponent : undefined
626 Component {
627 id: pageHeaderComponent
628 DashPageHeader {
629 objectName: "scopePageHeader"
630 width: parent.width
631 title: scopeView.scope ? scopeView.scope.name : ""
632 searchHint: scopeView.scope && scopeView.scope.searchHint || i18n.ctr("Label: Hint for dash search line edit", "Search")
633 showBackButton: scopeView.hasBackAction
634 searchEntryEnabled: true
635 settingsEnabled: scopeView.scope && scopeView.scope.settings && scopeView.scope.settings.count > 0 || false
636 favoriteEnabled: scopeView.scope && scopeView.scope.id !== "clickscope"
637 favorite: scopeView.scope && scopeView.scope.favorite
638 scopeStyle: scopeView.scopeStyle
639 paginationCount: scopeView.paginationCount
640 paginationIndex: scopeView.paginationIndex
642 bottomItem: DashNavigation {
643 scope: scopeView.scope
644 anchors { left: parent.left; right: parent.right }
645 windowHeight: scopeView.height
646 windowWidth: scopeView.width
647 scopeStyle: scopeView.scopeStyle
648 }
650 onBackClicked: scopeView.backClicked()
651 onSettingsClicked: subPageLoader.openSubPage("settings")
652 onFavoriteClicked: scopeView.scope.favorite = !scopeView.scope.favorite
653 onSearchTextFieldFocused: scopeView.showHeader()
654 }
655 }
656 }
657 }
659 Item {
660 id: pullToRefreshClippingItem
661 anchors.left: parent.left
662 anchors.right: parent.right
663 anchors.bottom: parent.bottom
664 height: parent.height - pullToRefresh.contentY + (pageHeaderLoader.item ? pageHeaderLoader.item.bottomItem[0].height - pageHeaderLoader.item.height : 0)
665 clip: true
667 PullToRefresh {
668 id: pullToRefresh
669 objectName: "pullToRefresh"
670 target: categoryView
672 readonly property real contentY: categoryView.contentY - categoryView.originY
673 y: -contentY - units.gu(5)
675 onRefresh: {
676 refreshing = true
677 scopeView.scope.refresh()
678 }
679 anchors.left: parent.left
680 anchors.right: parent.right
682 Connections {
683 target: scopeView
684 onProcessingChanged: if (!scopeView.processing) pullToRefresh.refreshing = false
685 }
687 style: PullToRefreshScopeStyle {
688 anchors.fill: parent
689 activationThreshold: units.gu(14)
690 }
691 }
692 }
694 AbstractButton {
695 id: floatingSeeLess
696 objectName: "floatingSeeLess"
698 property Item companionTo: companionBase ? companionBase.seeAllButton : null
699 property Item companionBase: null
700 property bool showBecausePosition: false
701 property real yOffset: 0
703 anchors {
704 left: categoryView.left
705 right: categoryView.right
706 }
707 y: parent.height - height + yOffset
708 height: seeLessLabel.font.pixelSize + units.gu(4)
709 visible: companionTo && showBecausePosition
711 onClicked: categoryView.expandedCategoryId = "";
713 function updateVisibility() {
714 var companionPos = companionTo.mapToItem(floatingSeeLess, 0, 0);
715 showBecausePosition = companionPos.y > 0;
717 var posToBase = floatingSeeLess.mapToItem(companionBase, 0, -yOffset).y;
718 yOffset = Math.max(0, companionBase.item.collapsedHeight - posToBase);
719 yOffset = Math.min(yOffset, height);
721 if (!showBecausePosition && categoryView.expandedCategoryId === "") {
722 companionBase = null;
723 }
724 }
726 Label {
727 id: seeLessLabel
728 text: i18n.tr("See less")
729 anchors {
730 centerIn: parent
731 verticalCenterOffset: units.gu(-0.5)
732 }
733 fontSize: "small"
734 font.weight: Font.Bold
735 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
736 }
738 Connections {
739 target: floatingSeeLess.companionTo ? categoryView : null
740 onContentYChanged: floatingSeeLess.updateVisibility();
741 }
743 Connections {
744 target: floatingSeeLess.companionTo
745 onYChanged: floatingSeeLess.updateVisibility();
746 }
747 }
749 LimitProxyModel {
750 id: previewLimitModel
751 }
753 Loader {
754 id: subPageLoader
755 objectName: "subPageLoader"
756 visible: x != width
757 width: parent.width
758 height: parent.height
759 anchors.left: categoryView.right
761 property bool open: false
762 property var scope: scopeView.scope
763 property var scopeStyle: scopeView.scopeStyle
764 property int initialIndex: -1
765 property var previewStack;
766 property string categoryId
767 property var model: null
769 readonly property bool processing: item && item.processing || false
770 readonly property int count: item && item.count || 0
771 readonly property int currentIndex: item && item.currentIndex || 0
772 readonly property var currentItem: item && item.currentItem || null
774 property string subPage: ""
775 readonly property bool subPageShown: visible && status === Loader.Ready
777 function openSubPage(page) {
778 subPage = page;
779 }
781 function closeSubPage() {
782 open = false;
783 }
785 source: switch(subPage) {
786 case "preview": return "PreviewListView.qml";
787 case "settings": return "ScopeSettingsPage.qml";
788 default: return "";
789 }
791 onLoaded: {
792 item.scope = Qt.binding(function() { return subPageLoader.scope; } )
793 item.scopeStyle = Qt.binding(function() { return subPageLoader.scopeStyle; } )
794 if (subPage == "preview") {
795 item.open = Qt.binding(function() { return subPageLoader.open; } )
796 item.initialIndex = Qt.binding(function() { return subPageLoader.initialIndex; } )
797 item.model = Qt.binding(function() { return subPageLoader.model; } )
798 item.categoryId = Qt.binding(function() { return subPageLoader.categoryId; } )
799 item.initialIndexPreviewStack = subPageLoader.previewStack;
800 subPageLoader.previewStack = null;
801 }
802 open = true;
803 }
805 onOpenChanged: pageHeaderLoader.item.unfocus()
807 onVisibleChanged: if (!visible) subPage = ""
809 Connections {
810 target: subPageLoader.item
811 onBackClicked: subPageLoader.closeSubPage()
812 }
813 }