git.iko.soy/unity8
on af0bee6 help sign in
unity8/qml/Notifications/NotificationMenuItemFactory.qml
132 lines 3.7 kB history raw
1/*
2 * Copyright 2013 Canonical Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU Lesser General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU Lesser General Public License for more details.
12 *
13 * You should have received a copy of the GNU Lesser General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 *
16 * Authors:
17 * Nick Dedekind <nick.dedekind@canonical.com>
18 */
20import QtQuick 2.0
21import Ubuntu.Components 0.1
22import "../Components"
24Loader {
25 id: menuFactory
27 property QtObject menuModel: null
28 property QtObject menuData: null
29 property int menuIndex
30 property int maxHeight
31 readonly property bool fullscreen: menuData.type === "com.canonical.snapdecision.pinlock"
33 signal accepted()
35 property var _map: {
36 "com.canonical.snapdecision.textfield": textfield,
37 "com.canonical.snapdecision.pinlock" : pinLock,
38 }
40 sourceComponent: {
41 if (menuData.type !== undefined) {
42 var component = _map[menuData.type];
43 if (component !== undefined) {
44 return component;
45 }
46 }
47 }
49 Component {
50 id: textfield
52 Column {
53 spacing: units.gu(2)
55 anchors {
56 left: parent.left
57 right: parent.right
58 }
60 Component.onCompleted: {
61 menuModel.loadExtendedAttributes(menuIndex, {"x-echo-mode-password": "bool"});
62 checkBox.checked = menuData.ext.xEchoModePassword ? false : true
63 checkBoxRow.visible = menuData.ext.xEchoModePassword
64 }
66 Label {
67 text: menuData.label
68 }
70 TextField {
71 id: textfield
73 // TODO using Qt.ImhNoPredictiveText here until lp #1291575 is fixed for ubuntu-ui-toolkit
74 inputMethodHints: Qt.ImhNoAutoUppercase | Qt.ImhNoPredictiveText
75 anchors {
76 left: parent.left
77 right: parent.right
78 }
79 echoMode: checkBox.checked ? TextInput.Normal : TextInput.Password
80 height: units.gu(5)
81 Component.onCompleted: {
82 forceActiveFocus();
83 }
84 onTextChanged: {
85 menuModel.changeState(menuIndex, text);
86 }
87 onAccepted: {
88 menuFactory.accepted()
89 }
90 }
92 Row {
93 id: checkBoxRow
95 spacing: units.gu(.5)
97 CheckBox {
98 id: checkBox
100 checked: false
101 }
103 Label {
104 anchors.verticalCenter: checkBox.verticalCenter
105 text: i18n.tr("Show password")
106 }
107 }
108 }
109 }
111 Component {
112 id: pinLock
114 Lockscreen {
115 anchors {
116 left: parent.left
117 right: parent.right
118 }
119 height: menuFactory.maxHeight
120 placeholderText: i18n.tr("Please enter SIM PIN")
121 background: shell.background
123 onEntered: {
124 menuModel.changeState(menuIndex, passphrase);
125 }
127 onCancel: {
128 menuModel.activate(menuIndex, false);
129 }
130 }
131 }