git.iko.soy/unity8
on b271c0b help sign in
unity8/plugins/Unity/Indicators/qml/MenuItemFactory.qml
212 lines 7.4 kB history raw
1/*
2 * Copyright 2013 Canonical Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU Lesser General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU Lesser General Public License for more details.
12 *
13 * You should have received a copy of the GNU Lesser General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 *
16 * Authors:
17 * Nick Dedekind <nick.dedekind@canonical.com>
18 */
20import QtQuick 2.0
21import Unity.Indicators 0.1 as Indicators
22import Unity.Indicators.Network 0.1 as ICNetwork
23import QMenuModel 0.1 as QMenuModel
25Item {
26 id: menuFactory
28 property var model: null
30 property var _map: {
31 "unity.widgets.systemsettings.tablet.volumecontrol" : sliderMenu,
32 "unity.widgets.systemsettings.tablet.switch" : switchMenu,
34 "com.canonical.indicator.button" : buttonMenu,
35 "com.canonical.indicator.div" : divMenu,
36 "com.canonical.indicator.section" : sectionMenu,
37 "com.canonical.indicator.progress" : progressMenu,
38 "com.canonical.indicator.slider" : sliderMenu,
39 "com.canonical.indicator.switch" : switchMenu,
41 "com.canonical.unity.slider" : sliderMenu,
42 "com.canonical.unity.switch" : switchMenu,
44 "unity.widgets.systemsettings.tablet.wifisection" : wifiSection,
45 "unity.widgets.systemsettings.tablet.accesspoint" : accessPoint,
46 }
48 Component {
49 id: sliderMenu;
50 Indicators.SliderMenuItem {
51 property QtObject menu: null
53 text: menu && menu.label ? menu.label : ""
54 icon: menu ? menu.icon : ""
55 minIcon: menu.ext.minIcon
56 maxIcon: menu.ext.maxIcon
58 minimumValue: menu.ext.minValue ? menu.ext.minValue : 0.0
59 maximumValue: {
60 var maximum = menu.ext.maxValue ? menu.ext.maxValue : 1.0
61 if (maximum <= minimumValue) {
62 return minimumValue + 1;
63 }
64 return maximum;
65 }
66 value: menu ? menu.actionState : 0.0
67 enabled: menu ? menu.sensitive : false
69 Component.onCompleted: {
70 model.loadExtendedAttributes(modelIndex, {'min-value': 'double',
71 'max-value': 'double',
72 'min-icon': 'icon',
73 'max-icon': 'icon'});
74 }
76 // FIXME: The interval should be [0.0 - 1.0]. Unfortunately, when
77 // reaching the boundaries (0.0 or 1.0), the value is converted
78 // to an integer when automatically wrapped in a variant when
79 // passed to QStateAction::updateState(…). The server chokes on
80 // those values, complaining that they’re not of the right type…
81 onChangeState: {
82 if (value == Math.round(value)) {
83 if (value >= maximumValue) {
84 model.changeState(modelIndex, maximumValue - 0.000001);
85 } else if (value <= minimumValue) {
86 model.changeState(modelIndex, minimumValue + 0.000001);
87 } else {
88 model.changeState(modelIndex, value * 1.000001);
89 }
90 } else {
91 model.changeState(modelIndex, value);
92 }
93 }
94 }
95 }
97 Component { id: divMenu; Indicators.DivMenuItem {} }
99 Component {
100 id: buttonMenu;
101 Indicators.ButtonMenuItem {
102 property QtObject menu: null
104 text: menu && menu.label ? menu.label : ""
105 enabled: menu ? menu.sensitive : false
107 onActivate: model.activate(modelIndex);
108 }
109 }
110 Component {
111 id: sectionMenu;
112 Indicators.SectionMenuItem {
113 property QtObject menu: null
115 text: menu && menu.label ? menu.label : ""
116 }
117 }
119 Component {
120 id: progressMenu;
121 Indicators.ProgressMenuItem {
122 property QtObject menu: null
124 text: menu && menu.label ? menu.label : ""
125 icon: menu ? menu.icon : ""
126 value : menu ? menu.actionState : 0.0
127 }
128 }
130 Component {
131 id: standardMenu;
132 Indicators.StandardMenuItem {
133 property QtObject menu: null
135 text: menu && menu.label ? menu.label : ""
136 icon: menu ? menu.icon : ""
137 checkable: menu ? (menu.isCheck || menu.isRadio) : false
138 checked: checkable ? menu.isToggled : false
139 enabled: menu ? menu.sensitive : false
141 onActivate: model.activate(modelIndex);
142 }
143 }
145 Component {
146 id: switchMenu;
147 Indicators.SwitchMenuItem {
148 property QtObject menu: null
150 text: menu && menu.label ? menu.label : ""
151 icon: menu ? menu.icon : ""
152 checked: menu ? menu.isToggled : false
153 enabled: menu ? menu.sensitive : false
155 onActivate: model.activate(modelIndex);
156 }
157 }
159 Component {
160 id: wifiSection;
161 Indicators.SectionMenuItem {
162 property QtObject menu: null
164 text: menu && menu.label ? menu.label : ""
165 busy: menu ? menu.ext.xCanonicalBusyAction : false
167 Component.onCompleted: {
168 model.loadExtendedAttributes(modelIndex, {'x-canonical-busy-action': 'bool'});
169 }
170 }
171 }
173 Component {
174 id: accessPoint;
175 ICNetwork.AccessPoint {
176 property QtObject menu: null
177 property var strengthAction: QMenuModel.UnityMenuAction {
178 model: menuFactory.model ? menuFactory.model : null
179 name: menu ? menu.ext.xCanonicalWifiApStrengthAction : ""
180 }
182 text: menu && menu.label ? menu.label : ""
183 icon: menu ? menu.icon : ""
184 secure: menu ? menu.ext.xCanonicalWifiApIsSecure : false
185 adHoc: menu ? menu.ext.xCanonicalWifiApIsAdhoc : false
186 checked: menu ? menu.isToggled : false
187 signalStrength: strengthAction.valid ? strengthAction.state : 0
188 enabled: menu ? menu.sensitive : false
190 Component.onCompleted: {
191 model.loadExtendedAttributes(modelIndex, {'x-canonical-wifi-ap-is-adhoc': 'bool',
192 'x-canonical-wifi-ap-is-secure': 'bool',
193 'x-canonical-wifi-ap-strength-action': 'string'});
194 }
195 onActivate: model.activate(modelIndex);
196 }
197 }
199 function load(modelData) {
200 if (modelData.type !== undefined) {
201 var component = _map[modelData.type];
202 if (component !== undefined) {
203 return component;
204 }
205 } else {
206 if (modelData.isSeparator) {
207 return divMenu;
208 }
209 }
210 return standardMenu;
211 }