git.iko.soy/unity8
on b3d028d help sign in
unity8/qml/Shell.qml
777 lines 27 kB history raw
1/*
2 * Copyright (C) 2013-2016 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import QtQuick.Window 2.2
19import AccountsService 0.1
20import Unity.Application 0.1
21import Ubuntu.Components 1.3
22import Ubuntu.Components.Popups 1.3
23import Ubuntu.Gestures 0.1
24import Ubuntu.Telephony 0.1 as Telephony
25import Unity.Connectivity 0.1
26import Unity.Launcher 0.1
27import GlobalShortcut 1.0 // has to be before Utils, because of WindowInputFilter
28import GSettings 1.0
29import Utils 0.1
30import Powerd 0.1
31import SessionBroadcast 0.1
32import "Greeter"
33import "Launcher"
34import "Panel"
35import "Components"
36import "Notifications"
37import "Stages"
38import "Tutorial"
39import "Wizard"
40import Unity.Notifications 1.0 as NotificationBackend
41import Unity.Session 0.1
42import Unity.DashCommunicator 0.1
43import Unity.Indicators 0.1 as Indicators
44import Cursor 1.0
45import WindowManager 0.1
48Item {
49 id: shell
51 // to be set from outside
52 property int orientationAngle: 0
53 property int orientation
54 property Orientations orientations
55 property real nativeWidth
56 property real nativeHeight
57 property alias indicatorAreaShowProgress: panel.indicatorAreaShowProgress
58 property bool beingResized
59 property string usageScenario: "phone" // supported values: "phone", "tablet" or "desktop"
60 property string mode: "full-greeter"
61 property alias oskEnabled: inputMethod.enabled
62 function updateFocusedAppOrientation() {
63 applicationsDisplayLoader.item.updateFocusedAppOrientation();
64 }
65 function updateFocusedAppOrientationAnimated() {
66 applicationsDisplayLoader.item.updateFocusedAppOrientationAnimated();
67 }
68 property bool hasMouse: false
70 // to be read from outside
71 readonly property int mainAppWindowOrientationAngle:
72 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainAppWindowOrientationAngle : 0
74 readonly property bool orientationChangesEnabled: panel.indicators.fullyClosed
75 && (applicationsDisplayLoader.item && applicationsDisplayLoader.item.orientationChangesEnabled)
76 && (!greeter || !greeter.animating)
78 readonly property bool showingGreeter: greeter && greeter.shown
80 property bool startingUp: true
81 Timer { id: finishStartUpTimer; interval: 500; onTriggered: startingUp = false }
83 property int supportedOrientations: {
84 if (startingUp) {
85 // Ensure we don't rotate during start up
86 return Qt.PrimaryOrientation;
87 } else if (greeter && greeter.shown) {
88 return Qt.PrimaryOrientation;
89 } else if (applicationsDisplayLoader.item) {
90 return shell.orientations.map(applicationsDisplayLoader.item.supportedOrientations);
91 } else {
92 // we just don't care
93 return Qt.PortraitOrientation
94 | Qt.LandscapeOrientation
95 | Qt.InvertedPortraitOrientation
96 | Qt.InvertedLandscapeOrientation;
97 }
98 }
100 readonly property var mainApp:
101 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainApp : null
102 onMainAppChanged: {
103 if (mainApp) {
104 _onMainAppChanged(mainApp.appId);
105 }
106 }
107 Connections {
108 target: ApplicationManager
109 onFocusRequested: {
110 if (shell.mainApp && shell.mainApp.appId === appId) {
111 _onMainAppChanged(appId);
112 }
113 }
114 }
115 function _onMainAppChanged(appId) {
116 if (wizard.active && appId != "" && appId != "unity8-dash") {
117 // If this happens on first boot, we may be in edge
118 // tutorial or wizard while receiving a call. But a call
119 // is more important than wizard so just bail out of those.
120 tutorial.finish();
121 wizard.hide();
122 }
124 if (appId === "dialer-app" && callManager.hasCalls && greeter.locked) {
125 // If we are in the middle of a call, make dialer lockedApp and show it.
126 // This can happen if user backs out of dialer back to greeter, then
127 // launches dialer again.
128 greeter.lockedApp = appId;
129 }
130 greeter.notifyAppFocusRequested(appId);
132 panel.indicators.hide();
133 launcher.hide();
134 }
136 // For autopilot consumption
137 readonly property string focusedApplicationId: ApplicationManager.focusedApplicationId
139 // Disable everything while greeter is waiting, so that the user can't swipe
140 // the greeter or launcher until we know whether the session is locked.
141 enabled: greeter && !greeter.waiting
143 property real edgeSize: units.gu(settings.edgeDragWidth)
145 WallpaperResolver {
146 id: wallpaperResolver
147 width: shell.width
148 }
150 readonly property alias greeter: greeterLoader.item
152 function activateApplication(appId) {
153 if (ApplicationManager.findApplication(appId)) {
154 ApplicationManager.requestFocusApplication(appId);
155 } else {
156 ApplicationManager.startApplication(appId);
157 }
158 }
160 function startLockedApp(app) {
161 if (greeter.locked) {
162 greeter.lockedApp = app;
163 }
164 shell.activateApplication(app);
165 }
167 Binding {
168 target: LauncherModel
169 property: "applicationManager"
170 value: ApplicationManager
171 }
173 Component.onCompleted: {
174 theme.name = "Ubuntu.Components.Themes.SuruDark"
175 finishStartUpTimer.start();
176 }
178 LightDM{id: lightDM} // Provide backend access
179 VolumeControl {
180 id: volumeControl
181 indicators: panel.indicators
182 }
184 DashCommunicator {
185 id: dash
186 objectName: "dashCommunicator"
187 }
189 PhysicalKeysMapper {
190 id: physicalKeysMapper
191 objectName: "physicalKeysMapper"
193 onPowerKeyLongPressed: dialogs.showPowerDialog();
194 onVolumeDownTriggered: volumeControl.volumeDown();
195 onVolumeUpTriggered: volumeControl.volumeUp();
196 onScreenshotTriggered: itemGrabber.capture(shell);
197 }
199 GlobalShortcut {
200 // dummy shortcut to force creation of GlobalShortcutRegistry before WindowInputFilter
201 }
203 WindowInputFilter {
204 id: inputFilter
205 Keys.onPressed: physicalKeysMapper.onKeyPressed(event, lastInputTimestamp);
206 Keys.onReleased: physicalKeysMapper.onKeyReleased(event, lastInputTimestamp);
207 }
209 WindowInputMonitor {
210 objectName: "windowInputMonitor"
211 onHomeKeyActivated: {
212 // Ignore when greeter is active, to avoid pocket presses
213 if (!greeter.active) {
214 launcher.fadeOut();
215 shell.showHome();
216 }
217 }
218 onTouchBegun: { cursor.opacity = 0; }
219 onTouchEnded: {
220 // move the (hidden) cursor to the last known touch position
221 var mappedCoords = mapFromItem(null, pos.x, pos.y);
222 cursor.x = mappedCoords.x;
223 cursor.y = mappedCoords.y;
224 }
225 }
227 GSettings {
228 id: settings
229 schema.id: "com.canonical.Unity8"
230 }
232 Item {
233 id: stages
234 objectName: "stages"
235 width: parent.width
236 height: parent.height
238 TopLevelSurfaceList {
239 id: topLevelSurfaceList
240 objectName: "topLevelSurfaceList"
241 applicationsModel: ApplicationManager
242 }
244 Loader {
245 id: applicationsDisplayLoader
246 objectName: "applicationsDisplayLoader"
247 anchors.fill: parent
249 // When we have a locked app, we only want to show that one app.
250 // FIXME: do this in a less traumatic way. We currently only allow
251 // locked apps in phone mode (see FIXME in Lockscreen component in
252 // this same file). When that changes, we need to do something
253 // nicer here. But this code is currently just to prevent a
254 // theoretical attack where user enters lockedApp mode, then makes
255 // the screen larger (maybe connects to monitor) and tries to enter
256 // tablet mode.
258 property string usageScenario: shell.usageScenario === "phone" || greeter.hasLockedApp
259 ? "phone"
260 : shell.usageScenario
261 readonly property string qmlComponent: {
262 if(shell.mode === "greeter") {
263 return "Stages/ShimStage.qml"
264 } else if (applicationsDisplayLoader.usageScenario === "phone") {
265 return "Stages/PhoneStage.qml";
266 } else if (applicationsDisplayLoader.usageScenario === "tablet") {
267 return "Stages/TabletStage.qml";
268 } else {
269 return "Stages/DesktopStage.qml";
270 }
271 }
272 // TODO: Ensure the current stage is destroyed before the new one gets loaded.
273 // Currently the new one will get loaded while the old is still hanging
274 // around for a bit, which might lead to conflicts where both stages
275 // change the model simultaneously.
276 onQmlComponentChanged: {
277 if (item) item.stageAboutToBeUnloaded();
278 source = qmlComponent;
279 }
281 property bool interactive: (!greeter || !greeter.shown)
282 && panel.indicators.fullyClosed
283 && launcher.progress == 0
284 && !notifications.useModal
286 onInteractiveChanged: { if (interactive) { focus = true; } }
288 Binding {
289 target: applicationsDisplayLoader.item
290 property: "focus"
291 value: true
292 }
293 Binding {
294 target: applicationsDisplayLoader.item
295 property: "objectName"
296 value: "stage"
297 }
298 Binding {
299 target: applicationsDisplayLoader.item
300 property: "dragAreaWidth"
301 value: shell.edgeSize
302 }
303 Binding {
304 target: applicationsDisplayLoader.item
305 property: "maximizedAppTopMargin"
306 // Not just using panel.panelHeight as that changes depending on the focused app.
307 value: panel.indicators.minimizedPanelHeight
308 }
309 Binding {
310 target: applicationsDisplayLoader.item
311 property: "interactive"
312 value: applicationsDisplayLoader.interactive
313 }
314 Binding {
315 target: applicationsDisplayLoader.item
316 property: "spreadEnabled"
317 value: tutorial.spreadEnabled && (!greeter || (!greeter.hasLockedApp && !greeter.shown))
318 }
319 Binding {
320 target: applicationsDisplayLoader.item
321 property: "inverseProgress"
322 value: greeter && greeter.locked ? 0 : launcher.progress
323 }
324 Binding {
325 target: applicationsDisplayLoader.item
326 property: "shellOrientationAngle"
327 value: shell.orientationAngle
328 }
329 Binding {
330 target: applicationsDisplayLoader.item
331 property: "shellOrientation"
332 value: shell.orientation
333 }
334 Binding {
335 target: applicationsDisplayLoader.item
336 property: "orientations"
337 value: shell.orientations
338 }
339 Binding {
340 target: applicationsDisplayLoader.item
341 property: "background"
342 value: wallpaperResolver.background
343 }
344 Binding {
345 target: applicationsDisplayLoader.item
346 property: "nativeWidth"
347 value: shell.nativeWidth
348 }
349 Binding {
350 target: applicationsDisplayLoader.item
351 property: "nativeHeight"
352 value: shell.nativeHeight
353 }
354 Binding {
355 target: applicationsDisplayLoader.item
356 property: "beingResized"
357 value: shell.beingResized
358 }
359 Binding {
360 target: applicationsDisplayLoader.item
361 property: "keepDashRunning"
362 value: launcher.shown || launcher.dashSwipe
363 }
364 Binding {
365 target: applicationsDisplayLoader.item
366 property: "suspended"
367 value: greeter.shown
368 }
369 Binding {
370 target: applicationsDisplayLoader.item
371 property: "altTabPressed"
372 value: physicalKeysMapper.altTabPressed
373 }
374 Binding {
375 target: applicationsDisplayLoader.item
376 property: "leftMargin"
377 value: shell.usageScenario == "desktop" && !settings.autohideLauncher ? launcher.panelWidth: 0
378 }
379 Binding {
380 target: applicationsDisplayLoader.item
381 property: "applicationManager"
382 value: ApplicationManager
383 }
384 Binding {
385 target: applicationsDisplayLoader.item
386 property: "topLevelSurfaceList"
387 value: topLevelSurfaceList
388 }
389 }
390 }
392 InputMethod {
393 id: inputMethod
394 objectName: "inputMethod"
395 anchors {
396 fill: parent
397 topMargin: panel.panelHeight
398 leftMargin: launcher.lockedVisible ? launcher.panelWidth : 0
399 }
400 z: notifications.useModal || panel.indicators.shown || wizard.active || tutorial.running ? overlay.z + 1 : overlay.z - 1
401 }
403 Loader {
404 id: greeterLoader
405 anchors.fill: parent
406 anchors.topMargin: panel.panelHeight
407 sourceComponent: shell.mode != "shell" ? integratedGreeter :
408 Qt.createComponent(Qt.resolvedUrl("Greeter/ShimGreeter.qml"));
409 onLoaded: {
410 item.objectName = "greeter"
411 }
412 }
414 Component {
415 id: integratedGreeter
416 Greeter {
418 hides: [launcher, panel.indicators]
419 tabletMode: shell.usageScenario != "phone"
420 launcherOffset: launcher.progress
421 forcedUnlock: wizard.active
422 background: wallpaperResolver.background
424 // avoid overlapping with Launcher's edge drag area
425 // FIXME: Fix TouchRegistry & friends and remove this workaround
426 // Issue involves launcher's DDA getting disabled on a long
427 // left-edge drag
428 dragHandleLeftMargin: launcher.available ? launcher.dragAreaWidth + 1 : 0
430 onSessionStarted: {
431 launcher.hide();
432 }
434 onTease: {
435 if (!tutorial.running) {
436 launcher.tease();
437 }
438 }
440 onEmergencyCall: startLockedApp("dialer-app")
441 }
442 }
444 Timer {
445 // See powerConnection for why this is useful
446 id: showGreeterDelayed
447 interval: 1
448 onTriggered: {
449 greeter.forceShow();
450 }
451 }
453 Connections {
454 id: callConnection
455 target: callManager
457 onHasCallsChanged: {
458 if (greeter.locked && callManager.hasCalls && greeter.lockedApp !== "dialer-app") {
459 // We just received an incoming call while locked. The
460 // indicator will have already launched dialer-app for us, but
461 // there is a race between "hasCalls" changing and the dialer
462 // starting up. So in case we lose that race, we'll start/
463 // focus the dialer ourselves here too. Even if the indicator
464 // didn't launch the dialer for some reason (or maybe a call
465 // started via some other means), if an active call is
466 // happening, we want to be in the dialer.
467 startLockedApp("dialer-app")
468 }
469 }
470 }
472 Connections {
473 id: powerConnection
474 target: Powerd
476 onStatusChanged: {
477 if (Powerd.status === Powerd.Off && reason !== Powerd.Proximity &&
478 !callManager.hasCalls && !wizard.active) {
479 // We don't want to simply call greeter.showNow() here, because
480 // that will take too long. Qt will delay button event
481 // handling until the greeter is done loading and may think the
482 // user held down the power button the whole time, leading to a
483 // power dialog being shown. Instead, delay showing the
484 // greeter until we've finished handling the event. We could
485 // make the greeter load asynchronously instead, but that
486 // introduces a whole host of timing issues, especially with
487 // its animations. So this is simpler.
488 showGreeterDelayed.start();
489 }
490 }
491 }
493 function showHome() {
494 greeter.notifyUserRequestedApp("unity8-dash");
496 var animate = !lightDM.greeter.active && !stages.shown
497 dash.setCurrentScope(0, animate, false)
498 ApplicationManager.requestFocusApplication("unity8-dash")
499 }
501 function showDash() {
502 if (greeter.notifyShowingDashFromDrag()) {
503 launcher.fadeOut();
504 }
506 if (!greeter.locked && ApplicationManager.focusedApplicationId != "unity8-dash") {
507 ApplicationManager.requestFocusApplication("unity8-dash")
508 launcher.fadeOut();
509 }
510 }
512 Item {
513 id: overlay
514 z: 10
516 anchors.fill: parent
518 Panel {
519 id: panel
520 objectName: "panel"
521 anchors.fill: parent //because this draws indicator menus
522 indicators {
523 hides: [launcher]
524 available: tutorial.panelEnabled
525 && ((!greeter || !greeter.locked) || AccountsService.enableIndicatorsWhileLocked)
526 && (!greeter || !greeter.hasLockedApp)
527 width: parent.width > units.gu(60) ? units.gu(40) : parent.width
529 minimizedPanelHeight: units.gu(3)
530 expandedPanelHeight: units.gu(7)
532 indicatorsModel: Indicators.IndicatorsModel {
533 // tablet and phone both use the same profile
534 profile: "phone"
535 Component.onCompleted: load();
536 }
537 }
539 callHint {
540 greeterShown: greeter.shown
541 }
543 readonly property bool focusedSurfaceIsFullscreen: MirFocusController.focusedSurface
544 ? MirFocusController.focusedSurface.state === Mir.FullscreenState
545 : false
546 fullscreenMode: (focusedSurfaceIsFullscreen && !lightDM.greeter.active && launcher.progress == 0)
547 || greeter.hasLockedApp
548 locked: greeter && greeter.active
549 }
551 Launcher {
552 id: launcher
553 objectName: "launcher"
555 readonly property bool dashSwipe: progress > 0
557 anchors.top: parent.top
558 anchors.topMargin: inverted ? 0 : panel.panelHeight
559 anchors.bottom: parent.bottom
560 width: parent.width
561 dragAreaWidth: shell.edgeSize
562 available: tutorial.launcherEnabled
563 && (!greeter.locked || AccountsService.enableLauncherWhileLocked)
564 && !greeter.hasLockedApp
565 inverted: shell.usageScenario !== "desktop"
566 superPressed: physicalKeysMapper.superPressed
567 superTabPressed: physicalKeysMapper.superTabPressed
568 panelWidth: units.gu(settings.launcherWidth)
569 lockedVisible: shell.usageScenario == "desktop" && !settings.autohideLauncher && !panel.fullscreenMode
571 onShowDashHome: showHome()
572 onDash: showDash()
573 onDashSwipeChanged: {
574 if (dashSwipe) {
575 dash.setCurrentScope(0, false, true)
576 }
577 }
578 onLauncherApplicationSelected: {
579 greeter.notifyUserRequestedApp(appId);
580 shell.activateApplication(appId);
581 }
582 onShownChanged: {
583 if (shown) {
584 panel.indicators.hide()
585 }
586 }
587 onFocusChanged: {
588 if (!focus) {
589 applicationsDisplayLoader.focus = true;
590 }
591 }
593 GlobalShortcut {
594 shortcut: Qt.AltModifier | Qt.Key_F1
595 onTriggered: {
596 launcher.openForKeyboardNavigation();
597 }
598 }
599 GlobalShortcut {
600 shortcut: Qt.MetaModifier | Qt.Key_0
601 onTriggered: {
602 if (LauncherModel.get(9)) {
603 activateApplication(LauncherModel.get(9).appId);
604 }
605 }
606 }
607 Repeater {
608 model: 9
609 GlobalShortcut {
610 shortcut: Qt.MetaModifier | (Qt.Key_1 + index)
611 onTriggered: {
612 if (LauncherModel.get(index)) {
613 activateApplication(LauncherModel.get(index).appId);
614 }
615 }
616 }
617 }
618 }
620 KeyboardShortcutsOverlay {
621 objectName: "shortcutsOverlay"
622 visible: launcher.shortcutHintsShown && width < parent.width - (launcher.lockedVisible ? launcher.panelWidth : 0) - padding
623 && height < parent.height - padding - panel.panelHeight
624 enabled: visible
625 anchors.centerIn: parent
626 anchors.horizontalCenterOffset: launcher.lockedVisible ? launcher.panelWidth/2 : 0
627 anchors.verticalCenterOffset: panel.panelHeight/2
628 opacity: visible? 0.95 : 0
629 Behavior on opacity {
630 OpacityAnimator { duration: UbuntuAnimation.FastDuration; easing: UbuntuAnimation.StandardEasing }
631 }
632 }
634 Tutorial {
635 id: tutorial
636 objectName: "tutorial"
637 anchors.fill: parent
639 paused: callManager.hasCalls || greeter.shown
640 keyboardVisible: inputMethod.state === "shown"
641 usageScenario: shell.usageScenario
642 lastInputTimestamp: inputFilter.lastInputTimestamp
643 launcher: launcher
644 panel: panel
645 stage: applicationsDisplayLoader.item
646 }
648 Wizard {
649 id: wizard
650 objectName: "wizard"
651 anchors.fill: parent
653 function unlockWhenDoneWithWizard() {
654 if (!active) {
655 Connectivity.unlockAllModems();
656 }
657 }
659 Component.onCompleted: unlockWhenDoneWithWizard()
660 onActiveChanged: unlockWhenDoneWithWizard()
661 }
663 MouseArea { // modal notifications prevent interacting with other contents
664 anchors.fill: parent
665 visible: notifications.useModal
666 enabled: visible
667 }
669 Notifications {
670 id: notifications
672 model: NotificationBackend.Model
673 margin: units.gu(1)
674 hasMouse: shell.hasMouse
675 background: wallpaperResolver.background
677 y: topmostIsFullscreen ? 0 : panel.panelHeight
678 height: parent.height - (topmostIsFullscreen ? 0 : panel.panelHeight)
680 states: [
681 State {
682 name: "narrow"
683 when: overlay.width <= units.gu(60)
684 AnchorChanges {
685 target: notifications
686 anchors.left: parent.left
687 anchors.right: parent.right
688 }
689 },
690 State {
691 name: "wide"
692 when: overlay.width > units.gu(60)
693 AnchorChanges {
694 target: notifications
695 anchors.left: undefined
696 anchors.right: parent.right
697 }
698 PropertyChanges { target: notifications; width: units.gu(38) }
699 }
700 ]
701 }
702 }
704 Dialogs {
705 id: dialogs
706 objectName: "dialogs"
707 anchors.fill: parent
708 z: overlay.z + 10
709 usageScenario: shell.usageScenario
710 onPowerOffClicked: {
711 shutdownFadeOutRectangle.enabled = true;
712 shutdownFadeOutRectangle.visible = true;
713 shutdownFadeOut.start();
714 }
715 }
717 Connections {
718 target: SessionBroadcast
719 onShowHome: showHome()
720 }
722 ItemGrabber {
723 id: itemGrabber
724 anchors.fill: parent
725 z: dialogs.z + 10
726 GlobalShortcut { shortcut: Qt.Key_Print; onTriggered: itemGrabber.capture(shell) }
727 Connections {
728 target: applicationsDisplayLoader.item
729 ignoreUnknownSignals: true
730 onItemSnapshotRequested: itemGrabber.capture(item)
731 }
732 }
734 Cursor {
735 id: cursor
736 visible: shell.hasMouse
737 z: itemGrabber.z + 1
739 onPushedLeftBoundary: {
740 if (buttons === Qt.NoButton) {
741 launcher.pushEdge(amount);
742 }
743 }
745 onPushedRightBoundary: {
746 if (buttons === Qt.NoButton && applicationsDisplayLoader.item
747 && applicationsDisplayLoader.item.pushRightEdge) {
748 applicationsDisplayLoader.item.pushRightEdge(amount);
749 }
750 }
752 onMouseMoved: { cursor.opacity = 1; }
753 }
755 // non-visual object
756 KeymapSwitcher {}
758 Rectangle {
759 id: shutdownFadeOutRectangle
760 z: cursor.z + 1
761 enabled: false
762 visible: false
763 color: "black"
764 anchors.fill: parent
765 opacity: 0.0
766 NumberAnimation on opacity {
767 id: shutdownFadeOut
768 from: 0.0
769 to: 1.0
770 onStopped: {
771 if (shutdownFadeOutRectangle.enabled && shutdownFadeOutRectangle.visible) {
772 DBusUnitySessionService.shutdown();
773 }
774 }
775 }
776 }