git.iko.soy/unity8
on b977a40 help sign in
unity8/qml/Shell.qml
694 lines 24 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import QtQuick.Window 2.0
19import AccountsService 0.1
20import GSettings 1.0
21import Unity.Application 0.1
22import Ubuntu.Components 0.1
23import Ubuntu.Components.Popups 1.0
24import Ubuntu.Gestures 0.1
25import Ubuntu.Telephony 0.1 as Telephony
26import Unity.Connectivity 0.1
27import Unity.Launcher 0.1
28import Utils 0.1
29import LightDM 0.1 as LightDM
30import Powerd 0.1
31import SessionBroadcast 0.1
32import "Greeter"
33import "Launcher"
34import "Panel"
35import "Components"
36import "Notifications"
37import "Stages"
38import "Tutorial"
39import "Wizard"
40import Unity.Notifications 1.0 as NotificationBackend
41import Unity.Session 0.1
42import Unity.DashCommunicator 0.1
43import Unity.Indicators 0.1 as Indicators
45Item {
46 id: shell
48 // to be set from outside
49 property int orientationAngle: 0
50 property int orientation
51 property int primaryOrientation
52 property int nativeOrientation
53 property real nativeWidth
54 property real nativeHeight
55 property alias indicatorAreaShowProgress: panel.indicatorAreaShowProgress
56 property bool beingResized
57 property string usageScenario: "phone" // supported values: "phone", "tablet" or "desktop"
58 property string mode: "full-greeter"
59 function updateFocusedAppOrientation() {
60 applicationsDisplayLoader.item.updateFocusedAppOrientation();
61 }
62 function updateFocusedAppOrientationAnimated() {
63 applicationsDisplayLoader.item.updateFocusedAppOrientationAnimated();
64 }
66 // to be read from outside
67 readonly property int mainAppWindowOrientationAngle:
68 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainAppWindowOrientationAngle : 0
70 readonly property bool orientationChangesEnabled: panel.indicators.fullyClosed
71 && (applicationsDisplayLoader.item && applicationsDisplayLoader.item.orientationChangesEnabled)
72 && (!greeter || !greeter.animating)
74 readonly property bool showingGreeter: greeter && greeter.shown
76 property bool startingUp: true
77 Timer { id: finishStartUpTimer; interval: 500; onTriggered: startingUp = false }
79 property int supportedOrientations: {
80 if (startingUp) {
81 // Ensure we don't rotate during start up
82 return Qt.PrimaryOrientation;
83 } else if (greeter && greeter.shown) {
84 return Qt.PrimaryOrientation;
85 } else if (mainApp) {
86 return mainApp.supportedOrientations;
87 } else {
88 // we just don't care
89 return Qt.PortraitOrientation
90 | Qt.LandscapeOrientation
91 | Qt.InvertedPortraitOrientation
92 | Qt.InvertedLandscapeOrientation;
93 }
94 }
96 // For autopilot consumption
97 readonly property string focusedApplicationId: ApplicationManager.focusedApplicationId
99 // internal props from here onwards
100 readonly property var mainApp:
101 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainApp : null
103 // Disable everything while greeter is waiting, so that the user can't swipe
104 // the greeter or launcher until we know whether the session is locked.
105 enabled: greeter && !greeter.waiting
107 property real edgeSize: units.gu(2)
108 property url defaultBackground: Qt.resolvedUrl(shell.width >= units.gu(60) ? "graphics/tablet_background.jpg" : "graphics/phone_background.jpg")
109 property url background: asImageTester.status == Image.Ready ? asImageTester.source
110 : gsImageTester.status == Image.Ready ? gsImageTester.source : defaultBackground
112 readonly property alias greeter: greeterLoader.item
114 function activateApplication(appId) {
115 if (ApplicationManager.findApplication(appId)) {
116 ApplicationManager.requestFocusApplication(appId);
117 } else {
118 var execFlags = shell.usageScenario === "phone" ? ApplicationManager.ForceMainStage
119 : ApplicationManager.NoFlag;
120 ApplicationManager.startApplication(appId, execFlags);
121 }
122 }
124 function startLockedApp(app) {
125 if (greeter.locked) {
126 greeter.lockedApp = app;
127 }
128 shell.activateApplication(app);
129 }
131 // This is a dummy image to detect if the custom AS set wallpaper loads successfully.
132 Image {
133 id: asImageTester
134 source: AccountsService.backgroundFile != undefined && AccountsService.backgroundFile.length > 0 ? AccountsService.backgroundFile : ""
135 height: 0
136 width: 0
137 sourceSize.height: 0
138 sourceSize.width: 0
139 }
141 GSettings {
142 id: backgroundSettings
143 schema.id: "org.gnome.desktop.background"
144 }
146 // This is a dummy image to detect if the custom GSettings set wallpaper loads successfully.
147 Image {
148 id: gsImageTester
149 source: backgroundSettings.pictureUri != undefined && backgroundSettings.pictureUri.length > 0 ? backgroundSettings.pictureUri : ""
150 height: 0
151 width: 0
152 sourceSize.height: 0
153 sourceSize.width: 0
154 }
156 Binding {
157 target: LauncherModel
158 property: "applicationManager"
159 value: ApplicationManager
160 }
162 Component.onCompleted: {
163 Theme.name = "Ubuntu.Components.Themes.SuruGradient"
164 if (ApplicationManager.count > 0) {
165 ApplicationManager.focusApplication(ApplicationManager.get(0).appId);
166 }
167 finishStartUpTimer.start();
168 }
170 VolumeControl {
171 id: volumeControl
172 }
174 DashCommunicator {
175 id: dash
176 objectName: "dashCommunicator"
177 }
179 PhysicalKeysMapper {
180 id: physicalKeysMapper
181 objectName: "physicalKeysMapper"
183 onPowerKeyLongPressed: dialogs.showPowerDialog()
184 onVolumeDownTriggered: volumeControl.volumeDown();
185 onVolumeUpTriggered: volumeControl.volumeUp();
186 onScreenshotTriggered: screenGrabber.capture();
187 }
189 ScreenGrabber {
190 id: screenGrabber
191 z: dialogs.z + 10
192 }
194 WindowKeysFilter {
195 Keys.onPressed: physicalKeysMapper.onKeyPressed(event);
196 Keys.onReleased: physicalKeysMapper.onKeyReleased(event);
197 }
199 HomeKeyWatcher {
200 onActivated: { launcher.fadeOut(); shell.showHome(); }
201 }
203 Item {
204 id: stages
205 objectName: "stages"
206 width: parent.width
207 height: parent.height
209 Connections {
210 target: ApplicationManager
212 // This signal is also fired when we try to focus the current app
213 // again. We rely on this!
214 onFocusedApplicationIdChanged: {
215 var appId = ApplicationManager.focusedApplicationId;
217 if (tutorial.running && appId != "" && appId != "unity8-dash") {
218 // If this happens on first boot, we may be in edge
219 // tutorial or wizard while receiving a call. But a call
220 // is more important than wizard so just bail out of those.
221 tutorial.finish();
222 wizard.hide();
223 }
225 if (appId === "dialer-app" && callManager.hasCalls && greeter.locked) {
226 // If we are in the middle of a call, make dialer lockedApp and show it.
227 // This can happen if user backs out of dialer back to greeter, then
228 // launches dialer again.
229 greeter.lockedApp = appId;
230 }
231 greeter.notifyAppFocused(appId);
233 panel.indicators.hide();
234 }
236 onApplicationAdded: {
237 launcher.hide();
238 }
239 }
241 Loader {
242 id: applicationsDisplayLoader
243 objectName: "applicationsDisplayLoader"
244 anchors.fill: parent
246 // When we have a locked app, we only want to show that one app.
247 // FIXME: do this in a less traumatic way. We currently only allow
248 // locked apps in phone mode (see FIXME in Lockscreen component in
249 // this same file). When that changes, we need to do something
250 // nicer here. But this code is currently just to prevent a
251 // theoretical attack where user enters lockedApp mode, then makes
252 // the screen larger (maybe connects to monitor) and tries to enter
253 // tablet mode.
255 property string usageScenario: shell.usageScenario === "phone" || greeter.hasLockedApp
256 ? "phone"
257 : shell.usageScenario
258 source: {
259 if(shell.mode === "greeter") {
260 return "Stages/ShimStage.qml"
261 } else if (applicationsDisplayLoader.usageScenario === "phone") {
262 return "Stages/PhoneStage.qml";
263 } else if (applicationsDisplayLoader.usageScenario === "tablet") {
264 return "Stages/TabletStage.qml";
265 } else {
266 return "Stages/DesktopStage.qml";
267 }
268 }
270 property bool interactive: tutorial.spreadEnabled
271 && (!greeter || !greeter.shown)
272 && panel.indicators.fullyClosed
273 && launcher.progress == 0
274 && !notifications.useModal
276 onInteractiveChanged: { if (interactive) { focus = true; } }
278 Binding {
279 target: applicationsDisplayLoader.item
280 property: "objectName"
281 value: "stage"
282 }
283 Binding {
284 target: applicationsDisplayLoader.item
285 property: "dragAreaWidth"
286 value: shell.edgeSize
287 }
288 Binding {
289 target: applicationsDisplayLoader.item
290 property: "maximizedAppTopMargin"
291 // Not just using panel.panelHeight as that changes depending on the focused app.
292 value: panel.indicators.minimizedPanelHeight + units.dp(2) // dp(2) for orange line
293 }
294 Binding {
295 target: applicationsDisplayLoader.item
296 property: "interactive"
297 value: applicationsDisplayLoader.interactive
298 }
299 Binding {
300 target: applicationsDisplayLoader.item
301 property: "spreadEnabled"
302 value: tutorial.spreadEnabled && (!greeter || (!greeter.hasLockedApp && !greeter.shown))
303 }
304 Binding {
305 target: applicationsDisplayLoader.item
306 property: "inverseProgress"
307 value: greeter && greeter.locked ? 0 : launcher.progress
308 }
309 Binding {
310 target: applicationsDisplayLoader.item
311 property: "shellOrientationAngle"
312 value: shell.orientationAngle
313 }
314 Binding {
315 target: applicationsDisplayLoader.item
316 property: "shellOrientation"
317 value: shell.orientation
318 }
319 Binding {
320 target: applicationsDisplayLoader.item
321 property: "background"
322 value: shell.background
323 }
324 Binding {
325 target: applicationsDisplayLoader.item
326 property: "shellPrimaryOrientation"
327 value: shell.primaryOrientation
328 }
329 Binding {
330 target: applicationsDisplayLoader.item
331 property: "nativeOrientation"
332 value: shell.nativeOrientation
333 }
334 Binding {
335 target: applicationsDisplayLoader.item
336 property: "nativeWidth"
337 value: shell.nativeWidth
338 }
339 Binding {
340 target: applicationsDisplayLoader.item
341 property: "nativeHeight"
342 value: shell.nativeHeight
343 }
344 Binding {
345 target: applicationsDisplayLoader.item
346 property: "beingResized"
347 value: shell.beingResized
348 }
349 Binding {
350 target: applicationsDisplayLoader.item
351 property: "keepDashRunning"
352 value: launcher.shown || launcher.dashSwipe
353 }
354 Binding {
355 target: applicationsDisplayLoader.item
356 property: "suspended"
357 value: greeter.shown
358 }
359 Binding {
360 target: applicationsDisplayLoader.item
361 property: "altTabPressed"
362 value: physicalKeysMapper.altTabPressed
363 }
364 }
366 Tutorial {
367 id: tutorial
368 objectName: "tutorial"
369 anchors.fill: parent
371 // EdgeDragAreas don't work with mice. So to avoid trapping the user,
372 // we skip the tutorial on the Desktop to avoid using them. The
373 // Desktop doesn't use the same spread design anyway. The tutorial is
374 // all a bit of a placeholder on non-phone form factors right now.
375 // When the design team gives us more guidance, we can do something
376 // more clever here.
377 active: usageScenario != "desktop" && AccountsService.demoEdges
379 paused: LightDM.Greeter.active
380 launcher: launcher
381 panel: panel
382 edgeSize: shell.edgeSize
384 onFinished: {
385 AccountsService.demoEdges = false;
386 active = false; // for immediate response / if AS is having problems
387 }
388 }
389 }
391 InputMethod {
392 id: inputMethod
393 objectName: "inputMethod"
394 anchors { fill: parent; topMargin: panel.panelHeight }
395 z: notifications.useModal || panel.indicators.shown || wizard.active ? overlay.z + 1 : overlay.z - 1
396 }
398 Connections {
399 target: SessionManager
400 onSessionStopping: {
401 if (!session.parentSession && !session.application) {
402 // nothing is using it. delete it right away
403 session.release();
404 }
405 }
406 }
408 Loader {
409 id: greeterLoader
410 anchors.fill: parent
411 anchors.topMargin: panel.panelHeight
412 sourceComponent: shell.mode != "shell" ? integratedGreeter :
413 Qt.createComponent(Qt.resolvedUrl("Greeter/ShimGreeter.qml"));
414 onLoaded: {
415 item.objectName = "greeter"
416 }
417 }
419 Component {
420 id: integratedGreeter
421 Greeter {
423 hides: [launcher, panel.indicators]
424 tabletMode: shell.usageScenario != "phone"
425 launcherOffset: launcher.progress
426 forcedUnlock: tutorial.running
427 background: shell.background
429 // avoid overlapping with Launcher's edge drag area
430 // FIXME: Fix TouchRegistry & friends and remove this workaround
431 // Issue involves launcher's DDA getting disabled on a long
432 // left-edge drag
433 dragHandleLeftMargin: launcher.available ? launcher.dragAreaWidth + 1 : 0
435 onSessionStarted: {
436 launcher.hide();
437 }
439 onTease: {
440 if (!tutorial.running) {
441 launcher.tease();
442 }
443 }
445 onEmergencyCall: startLockedApp("dialer-app")
446 }
447 }
449 Timer {
450 // See powerConnection for why this is useful
451 id: showGreeterDelayed
452 interval: 1
453 onTriggered: {
454 greeter.forceShow();
455 }
456 }
458 Connections {
459 id: callConnection
460 target: callManager
462 onHasCallsChanged: {
463 if (greeter.locked && callManager.hasCalls && greeter.lockedApp !== "dialer-app") {
464 // We just received an incoming call while locked. The
465 // indicator will have already launched dialer-app for us, but
466 // there is a race between "hasCalls" changing and the dialer
467 // starting up. So in case we lose that race, we'll start/
468 // focus the dialer ourselves here too. Even if the indicator
469 // didn't launch the dialer for some reason (or maybe a call
470 // started via some other means), if an active call is
471 // happening, we want to be in the dialer.
472 startLockedApp("dialer-app")
473 }
474 }
475 }
477 Connections {
478 id: powerConnection
479 target: Powerd
481 onStatusChanged: {
482 if (Powerd.status === Powerd.Off && reason !== Powerd.Proximity &&
483 !callManager.hasCalls && !tutorial.running) {
484 // We don't want to simply call greeter.showNow() here, because
485 // that will take too long. Qt will delay button event
486 // handling until the greeter is done loading and may think the
487 // user held down the power button the whole time, leading to a
488 // power dialog being shown. Instead, delay showing the
489 // greeter until we've finished handling the event. We could
490 // make the greeter load asynchronously instead, but that
491 // introduces a whole host of timing issues, especially with
492 // its animations. So this is simpler.
493 showGreeterDelayed.start();
494 }
495 }
496 }
498 function showHome() {
499 if (tutorial.running) {
500 return
501 }
503 greeter.notifyAboutToFocusApp("unity8-dash");
505 var animate = !LightDM.Greeter.active && !stages.shown
506 dash.setCurrentScope(0, animate, false)
507 ApplicationManager.requestFocusApplication("unity8-dash")
508 }
510 function showDash() {
511 if (greeter.notifyShowingDashFromDrag()) {
512 launcher.fadeOut();
513 }
515 if (!greeter.locked && ApplicationManager.focusedApplicationId != "unity8-dash") {
516 ApplicationManager.requestFocusApplication("unity8-dash")
517 launcher.fadeOut();
518 }
519 }
521 Item {
522 id: overlay
523 z: 10
525 anchors.fill: parent
527 Panel {
528 id: panel
529 objectName: "panel"
530 anchors.fill: parent //because this draws indicator menus
531 indicators {
532 hides: [launcher]
533 available: tutorial.panelEnabled
534 && ((!greeter || !greeter.locked) || AccountsService.enableIndicatorsWhileLocked)
535 && (!greeter || !greeter.hasLockedApp)
536 contentEnabled: tutorial.panelContentEnabled
537 width: parent.width > units.gu(60) ? units.gu(40) : parent.width
539 minimizedPanelHeight: units.gu(3)
540 expandedPanelHeight: units.gu(7)
542 indicatorsModel: Indicators.IndicatorsModel {
543 // tablet and phone both use the same profile
544 profile: shell.usageScenario === "desktop" ? "desktop" : "phone"
545 Component.onCompleted: load();
546 }
547 }
549 callHint {
550 greeterShown: greeter.shown
551 }
553 property bool mainAppIsFullscreen: shell.mainApp && shell.mainApp.fullscreen
554 fullscreenMode: (mainAppIsFullscreen && !LightDM.Greeter.active && launcher.progress == 0)
555 || greeter.hasLockedApp
556 }
558 Launcher {
559 id: launcher
560 objectName: "launcher"
562 readonly property bool dashSwipe: progress > 0
564 anchors.top: parent.top
565 anchors.topMargin: inverted ? 0 : panel.panelHeight
566 anchors.bottom: parent.bottom
567 width: parent.width
568 dragAreaWidth: shell.edgeSize
569 available: tutorial.launcherEnabled
570 && (!greeter.locked || AccountsService.enableLauncherWhileLocked)
571 && !greeter.hasLockedApp
572 inverted: shell.usageScenario !== "desktop"
573 shadeBackground: !tutorial.running
575 onShowDashHome: showHome()
576 onDash: showDash()
577 onDashSwipeChanged: {
578 if (dashSwipe) {
579 dash.setCurrentScope(0, false, true)
580 }
581 }
582 onLauncherApplicationSelected: {
583 if (!tutorial.running) {
584 greeter.notifyAboutToFocusApp(appId);
585 shell.activateApplication(appId)
586 }
587 }
588 onShownChanged: {
589 if (shown) {
590 panel.indicators.hide()
591 }
592 }
593 }
595 Wizard {
596 id: wizard
597 objectName: "wizard"
598 anchors.fill: parent
599 background: shell.background
601 function unlockWhenDoneWithWizard() {
602 if (!active) {
603 Connectivity.unlockAllModems();
604 }
605 }
607 Component.onCompleted: unlockWhenDoneWithWizard()
608 onActiveChanged: unlockWhenDoneWithWizard()
609 }
611 Rectangle {
612 id: modalNotificationBackground
614 visible: notifications.useModal
615 color: "#000000"
616 anchors.fill: parent
617 opacity: 0.9
619 MouseArea {
620 anchors.fill: parent
621 }
622 }
624 Notifications {
625 id: notifications
627 model: NotificationBackend.Model
628 margin: units.gu(1)
630 y: topmostIsFullscreen ? 0 : panel.panelHeight
631 height: parent.height - (topmostIsFullscreen ? 0 : panel.panelHeight)
633 states: [
634 State {
635 name: "narrow"
636 when: overlay.width <= units.gu(60)
637 AnchorChanges {
638 target: notifications
639 anchors.left: parent.left
640 anchors.right: parent.right
641 }
642 },
643 State {
644 name: "wide"
645 when: overlay.width > units.gu(60)
646 AnchorChanges {
647 target: notifications
648 anchors.left: undefined
649 anchors.right: parent.right
650 }
651 PropertyChanges { target: notifications; width: units.gu(38) }
652 }
653 ]
654 }
655 }
657 Dialogs {
658 id: dialogs
659 objectName: "dialogs"
660 anchors.fill: parent
661 z: overlay.z + 10
662 onPowerOffClicked: {
663 shutdownFadeOutRectangle.enabled = true;
664 shutdownFadeOutRectangle.visible = true;
665 shutdownFadeOut.start();
666 }
667 }
669 Connections {
670 target: SessionBroadcast
671 onShowHome: showHome()
672 }
674 Rectangle {
675 id: shutdownFadeOutRectangle
676 z: screenGrabber.z + 10
677 enabled: false
678 visible: false
679 color: "black"
680 anchors.fill: parent
681 opacity: 0.0
682 NumberAnimation on opacity {
683 id: shutdownFadeOut
684 from: 0.0
685 to: 1.0
686 onStopped: {
687 if (shutdownFadeOutRectangle.enabled && shutdownFadeOutRectangle.visible) {
688 DBusUnitySessionService.Shutdown();
689 }
690 }
691 }
692 }