git.iko.soy/unity8
on bedf8bc help sign in
unity8/qml/Dash/GenericScopeView.qml
856 lines 38 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import Ubuntu.Components.Popups 1.3
20import "../Components/SearchHistoryModel"
21import Utils 0.1
22import Unity 0.2
23import Dash 0.1
24import "../Components"
25import "../Components/ListItems" as ListItems
27FocusScope {
28 id: scopeView
30 property bool forceNonInteractive: false
31 property var scope: null
32 property UnitySortFilterProxyModel categories: categoryFilter
33 property bool isCurrent: false
34 property alias moving: categoryView.moving
35 property bool hasBackAction: false
36 property bool enableHeightBehaviorOnNextCreation: false
37 property var categoryView: categoryView
38 readonly property alias subPageShown: subPageLoader.subPageShown
39 readonly property alias extraPanelShown: peExtraPanel.visible
40 property int paginationCount: 0
41 property int paginationIndex: 0
42 property bool visibleToParent: false
43 property alias pageHeaderTotallyVisible: categoryView.pageHeaderTotallyVisible
44 property var holdingList: null
45 property bool wasCurrentOnMoveStart: false
46 property var filtersPopover: null
48 property var scopeStyle: ScopeStyle {
49 style: scope ? scope.customizations : {}
50 }
52 readonly property bool processing: scope ? (scope.searchInProgress || scope.activationInProgress || subPageLoader.processing) : false
54 signal backClicked()
56 onScopeChanged: {
57 floatingSeeLess.companionBase = null;
58 }
60 function positionAtBeginning() {
61 categoryView.positionAtBeginning()
62 }
64 function showHeader() {
65 categoryView.showHeader()
66 }
68 function closePreview() {
69 subPageLoader.closeSubPage()
70 }
72 function resetSearch() {
73 categoryView.pageHeader.resetSearch()
74 }
76 property var maybePreviewResult;
77 property string maybePreviewCategoryId;
79 function clearMaybePreviewData() {
80 scopeView.maybePreviewResult = undefined;
81 scopeView.maybePreviewCategoryId = "";
82 }
84 function itemClicked(result, categoryId) {
85 scopeView.maybePreviewResult = result;
86 scopeView.maybePreviewCategoryId = categoryId;
88 scope.activate(result, categoryId);
89 }
91 function itemPressedAndHeld(result, categoryId) {
92 clearMaybePreviewData();
94 openPreview(result, categoryId);
95 }
97 function openPreview(result, categoryId) {
98 var previewModel = scope.preview(result, categoryId);
99 if (previewModel) {
100 subPageLoader.previewModel = previewModel;
101 subPageLoader.openSubPage("preview");
102 }
103 }
105 Binding {
106 target: scope
107 property: "isActive"
108 value: isCurrent && !subPageLoader.open && (Qt.application.state == Qt.ApplicationActive)
109 }
111 UnitySortFilterProxyModel {
112 id: categoryFilter
113 model: scope ? scope.categories : null
114 dynamicSortFilter: true
115 filterRole: Categories.RoleCount
116 filterRegExp: /^0$/
117 invertMatch: true
118 }
120 onIsCurrentChanged: {
121 if (!holdingList || !holdingList.moving) {
122 wasCurrentOnMoveStart = scopeView.isCurrent;
123 }
124 categoryView.pageHeader.resetSearch();
125 subPageLoader.closeSubPage();
126 if (filtersPopover) {
127 PopupUtils.close(filtersPopover)
128 scopeView.filtersPopover = null;
129 }
130 }
132 Binding {
133 target: scopeView.scope
134 property: "searchQuery"
135 value: categoryView.pageHeader.searchQuery
136 when: isCurrent
137 }
139 Binding {
140 target: categoryView.pageHeader
141 property: "searchQuery"
142 value: scopeView.scope ? scopeView.scope.searchQuery : ""
143 when: isCurrent
144 }
146 Connections {
147 target: scopeView.scope
148 onShowDash: subPageLoader.closeSubPage()
149 onHideDash: subPageLoader.closeSubPage()
150 onPreviewRequested: { // (QVariant const& result)
151 if (result === scopeView.maybePreviewResult) {
152 openPreview(result,
153 scopeView.maybePreviewCategoryId);
155 clearMaybePreviewData();
156 }
157 }
158 }
160 Connections {
161 target: holdingList
162 onMovingChanged: {
163 if (!moving) {
164 wasCurrentOnMoveStart = scopeView.isCurrent;
165 }
166 }
167 }
169 Rectangle {
170 anchors.fill: parent
171 color: scopeView.scopeStyle ? scopeView.scopeStyle.background : "transparent"
172 visible: color != "transparent"
173 }
175 ScopeListView {
176 id: categoryView
177 objectName: "categoryListView"
178 interactive: !forceNonInteractive
180 x: subPageLoader.open ? -width : 0
181 visible: x != -width
182 Behavior on x { UbuntuNumberAnimation { } }
183 width: parent.width
184 height: floatingSeeLess.visible ? parent.height - floatingSeeLess.height + floatingSeeLess.yOffset
185 : parent.height
186 clip: height != parent.height
188 model: scopeView.categories
189 forceNoClip: subPageLoader.open
190 pixelAligned: true
192 property string expandedCategoryId: ""
193 property int runMaximizeAfterSizeChanges: 0
195 readonly property bool pageHeaderTotallyVisible:
196 ((headerItemShownHeight == 0 && categoryView.contentY <= categoryView.originY) || (headerItemShownHeight == categoryView.pageHeader.height))
198 onExpandedCategoryIdChanged: {
199 var firstCreated = firstCreatedIndex();
200 var shrinkingAny = false;
201 var shrinkHeightDifference = 0;
202 for (var i = 0; i < createdItemCount(); ++i) {
203 var baseItem = item(firstCreated + i);
204 if (baseItem.expandable) {
205 var shouldExpand = baseItem.category === expandedCategoryId;
206 if (shouldExpand != baseItem.expanded) {
207 var animate = false;
208 if (!subPageLoader.open) {
209 var animateShrinking = !shouldExpand && baseItem.y + baseItem.item.collapsedHeight + baseItem.seeAllButton.height < categoryView.height;
210 var animateGrowing = shouldExpand && baseItem.y + baseItem.height < categoryView.height;
211 animate = shrinkingAny || animateShrinking || animateGrowing;
212 }
214 if (!shouldExpand) {
215 shrinkingAny = true;
216 shrinkHeightDifference = baseItem.item.expandedHeight - baseItem.item.collapsedHeight;
217 }
219 if (shouldExpand && !subPageLoader.open) {
220 if (!shrinkingAny) {
221 categoryView.maximizeVisibleArea(firstCreated + i, baseItem.item.expandedHeight + baseItem.seeAllButton.height);
222 } else {
223 // If the space that shrinking is smaller than the one we need to grow we'll call maximizeVisibleArea
224 // after the shrink/grow animation ends
225 var growHeightDifference = baseItem.item.expandedHeight - baseItem.item.collapsedHeight;
226 if (growHeightDifference > shrinkHeightDifference) {
227 runMaximizeAfterSizeChanges = 2;
228 } else {
229 runMaximizeAfterSizeChanges = 0;
230 }
231 }
232 }
234 baseItem.expand(shouldExpand, animate);
235 }
236 }
237 }
238 }
240 delegate: DashCategoryBase {
241 id: baseItem
242 objectName: "dashCategory" + category
244 property Item seeAllButton: seeAll
246 readonly property bool expandable: {
247 if (categoryView.model.count === 1) return false;
248 if (cardTool.template && cardTool.template["collapsed-rows"] === 0) return false;
249 if (item && item.expandedHeight > item.collapsedHeight) return true;
250 return false;
251 }
252 property bool expanded: false
253 readonly property string category: categoryId
254 readonly property string headerLink: model.headerLink
255 readonly property var item: rendererLoader.item
257 function expand(expand, animate) {
258 heightBehaviour.enabled = animate;
259 expanded = expand;
260 }
262 CardTool {
263 id: cardTool
264 objectName: "cardTool"
265 count: results ? results.count : 0
266 template: model.renderer
267 components: model.components
268 viewWidth: parent.width
269 }
271 onExpandableChanged: {
272 // This can happen with the VJ that doesn't know how height it will be on creation
273 // so doesn't set expandable until a bit too late for onLoaded
274 if (expandable) {
275 var shouldExpand = baseItem.category === categoryView.expandedCategoryId;
276 baseItem.expand(shouldExpand, false /*animate*/);
277 }
278 }
280 onHeightChanged: rendererLoader.updateRanges();
281 onYChanged: rendererLoader.updateRanges();
283 Loader {
284 id: rendererLoader
285 anchors {
286 top: parent.top
287 left: parent.left
288 right: parent.right
289 topMargin: name != "" ? 0 : units.gu(2)
290 }
292 Behavior on height {
293 id: heightBehaviour
294 enabled: false
295 animation: UbuntuNumberAnimation {
296 duration: UbuntuAnimation.FastDuration
297 onRunningChanged: {
298 if (!running) {
299 heightBehaviour.enabled = false
300 if (categoryView.runMaximizeAfterSizeChanges > 0) {
301 categoryView.runMaximizeAfterSizeChanges--;
302 if (categoryView.runMaximizeAfterSizeChanges == 0) {
303 var firstCreated = categoryView.firstCreatedIndex();
304 for (var i = 0; i < categoryView.createdItemCount(); ++i) {
305 var baseItem = categoryView.item(firstCreated + i);
306 if (baseItem.category === categoryView.expandedCategoryId) {
307 categoryView.maximizeVisibleArea(firstCreated + i, baseItem.item.expandedHeight + baseItem.seeAllButton.height);
308 break;
309 }
310 }
311 }
312 }
313 }
314 }
315 }
316 }
318 readonly property bool expanded: baseItem.expanded || !baseItem.expandable
319 height: expanded ? item.expandedHeight : item.collapsedHeight
321 source: {
322 switch (cardTool.categoryLayout) {
323 case "carousel": return "CardCarousel.qml";
324 case "vertical-journal": return "CardVerticalJournal.qml";
325 case "horizontal-list": return "CardHorizontalList.qml";
326 case "grid":
327 default: return "CardGrid.qml";
328 }
329 }
331 onLoaded: {
332 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
333 item.enableHeightBehavior = scopeView.enableHeightBehaviorOnNextCreation;
334 scopeView.enableHeightBehaviorOnNextCreation = false;
335 }
336 item.model = Qt.binding(function() { return results })
337 item.objectName = Qt.binding(function() { return categoryId })
338 item.scopeStyle = scopeView.scopeStyle;
339 if (baseItem.expandable) {
340 var shouldExpand = baseItem.category === categoryView.expandedCategoryId;
341 baseItem.expand(shouldExpand, false /*animate*/);
342 }
343 updateRanges();
344 clickScopeSizingHacks();
345 if (scope && (scope.id === "clickscope" || scope.id === "libertine-scope.ubuntu_libertine-scope")) {
346 if (isLibertineContainerCategory() || categoryId === "predefined" || categoryId === "local") {
347 cardTool.artShapeSize = Qt.binding(function() { return Qt.size(units.gu(8), units.gu(7.5)) });
348 cardTool.artShapeStyle = "icon";
349 } else {
350 // Should be ubuntu store icon
351 cardTool.artShapeStyle = "flat";
352 item.backgroundShapeStyle = "shadow";
353 }
354 }
355 item.cardTool = cardTool;
356 }
358 Component.onDestruction: {
359 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
360 scopeView.enableHeightBehaviorOnNextCreation = item.enableHeightBehaviorOnNextCreation;
361 }
362 }
363 // FIXME: directly connecting to onUnitsChanged cause a compile error:
364 // Cannot assign to non-existent property "onUnitsChanged"
365 // Until the units object is reworked to properly do all we need, let's go through a intermediate property
366 property int pxpgu: units.gu(1);
367 onPxpguChanged: clickScopeSizingHacks();
369 // Returns true if the current category pertains to a Libertine container
370 function isLibertineContainerCategory() {
371 return scope && scope.id === "libertine-scope.ubuntu_libertine-scope" && categoryId !== "hint";
372 }
374 function clickScopeSizingHacks() {
375 if (scope &&
376 ((scope.id === "clickscope" && (categoryId === "predefined" || categoryId === "local")) ||
377 isLibertineContainerCategory())) {
378 // Yeah, hackish :/
379 if (scopeView.width > units.gu(45)) {
380 if (scopeView.width >= units.gu(70)) {
381 cardTool.cardWidth = units.gu(11);
382 item.minimumHorizontalSpacing = units.gu(5);
383 return;
384 } else {
385 cardTool.cardWidth = units.gu(10);
386 }
387 } else {
388 cardTool.cardWidth = units.gu(12);
389 }
390 item.minimumHorizontalSpacing = item.defaultMinimumHorizontalSpacing;
391 }
392 }
394 Connections {
395 target: rendererLoader.item
396 onClicked: { // (int index, var result, var item, var itemModel)
397 scopeView.itemClicked(result, baseItem.category);
398 }
400 onPressAndHold: { // (int index, var result, var itemModel)
401 scopeView.itemPressedAndHeld(result, baseItem.category);
402 }
404 onAction: { // (int index, var result, var actionId)
405 scope.activateAction(result, baseItem.category, actionId);
406 }
408 function categoryItemCount() {
409 var categoryItemCount = -1;
410 if (!rendererLoader.expanded && !seeAllLabel.visible && target.collapsedItemCount > 0) {
411 categoryItemCount = target.collapsedItemCount;
412 }
413 return categoryItemCount;
414 }
415 }
416 Connections {
417 target: categoryView
418 onOriginYChanged: rendererLoader.updateRanges();
419 onContentYChanged: rendererLoader.updateRanges();
420 onHeightChanged: rendererLoader.updateRanges();
421 onContentHeightChanged: rendererLoader.updateRanges();
422 }
423 Connections {
424 target: scopeView
425 onIsCurrentChanged: rendererLoader.updateRanges();
426 onVisibleToParentChanged: rendererLoader.updateRanges();
427 onWidthChanged: rendererLoader.clickScopeSizingHacks();
428 }
429 Connections {
430 target: holdingList
431 onMovingChanged: if (!moving) rendererLoader.updateRanges();
432 }
434 function updateRanges() {
435 // Don't want to create stress by requesting more items during scope
436 // changes so unless you're not part of the visible scopes just return.
437 // For the visible scopes we need to do some work, the previously non visible
438 // scope needs to adjust its ranges so that we define the new visible range,
439 // that still means no creation/destruction of delegates, it's just about changing
440 // the culling of the items so they are actually visible
441 if (holdingList && holdingList.moving && !scopeView.visibleToParent) {
442 return;
443 }
445 if (categoryView.moving) {
446 // Do not update the range if we are overshooting up or down, since we'll come back
447 // to the stable position and delete/create items without any reason
448 if (categoryView.contentY < categoryView.originY) {
449 return;
450 } else if (categoryView.contentHeight - categoryView.originY > categoryView.height &&
451 categoryView.contentY + categoryView.height > categoryView.contentHeight) {
452 return;
453 }
454 }
456 if (item && item.hasOwnProperty("displayMarginBeginning")) {
457 var buffer = wasCurrentOnMoveStart ? categoryView.height * 1.5 : 0;
458 var onViewport = baseItem.y + baseItem.height > 0 &&
459 baseItem.y < categoryView.height;
460 var onBufferViewport = baseItem.y + baseItem.height > -buffer &&
461 baseItem.y < categoryView.height + buffer;
463 if (item.growsVertically) {
464 // A item view creates its delegates synchronously from
465 // -displayMarginBeginning
466 // to
467 // height + displayMarginEnd
468 // Around that area it adds the cacheBuffer area where delegates are created async
469 //
470 // We adjust displayMarginBeginning and displayMarginEnd so
471 // * In non visible scopes nothing is considered visible and we set cacheBuffer
472 // so that creates the items that would be in the viewport asynchronously
473 // * For the current scope set the visible range to the viewport and then
474 // use cacheBuffer to create extra items for categoryView.height * 1.5
475 // to make scrolling nicer by mantaining a higher number of
476 // cached items
477 // * For non current but visible scopes (i.e. when the user changes from one scope
478 // to the next, we set the visible range to the viewport so
479 // items are not culled (invisible) but still use no cacheBuffer
480 // (it will be set once the scope is the current one)
481 var displayMarginBeginning = baseItem.y + rendererLoader.anchors.topMargin;
482 displayMarginBeginning = -Math.max(-displayMarginBeginning, 0);
483 displayMarginBeginning = -Math.min(-displayMarginBeginning, baseItem.height);
484 displayMarginBeginning = Math.round(displayMarginBeginning);
485 var displayMarginEnd = -baseItem.height + seeAll.height + categoryView.height - baseItem.y;
486 displayMarginEnd = -Math.max(-displayMarginEnd, 0);
487 displayMarginEnd = -Math.min(-displayMarginEnd, baseItem.height);
488 displayMarginEnd = Math.round(displayMarginEnd);
490 if (onBufferViewport && (scopeView.isCurrent || scopeView.visibleToParent)) {
491 item.displayMarginBeginning = displayMarginBeginning;
492 item.displayMarginEnd = displayMarginEnd;
493 if (holdingList && holdingList.moving) {
494 // If we are moving we need to reset the cache buffer of the
495 // view that was not visible (i.e. !wasCurrentOnMoveStart) to 0 since
496 // otherwise the cache buffer we had set to preload the items of the
497 // visible range will trigger some item creations and we want move to
498 // be as smooth as possible meaning no need creations
499 if (!wasCurrentOnMoveStart) {
500 item.cacheBuffer = 0;
501 }
502 } else {
503 // Protect us against cases where the item hasn't yet been positioned
504 if (!(categoryView.contentY === 0 && baseItem.y === 0 && index !== 0)) {
505 item.cacheBuffer = categoryView.height * 1.5;
506 }
507 }
508 } else {
509 var visibleRange = baseItem.height + displayMarginEnd + displayMarginBeginning;
510 if (visibleRange < 0) {
511 item.displayMarginBeginning = displayMarginBeginning;
512 item.displayMarginEnd = displayMarginEnd;
513 item.cacheBuffer = 0;
514 } else {
515 // This should be visibleRange/2 in each of the properties
516 // but some item views still (like GridView) like creating sync delegates even if
517 // the visible range is 0 so let's make sure the visible range is negative
518 item.displayMarginBeginning = displayMarginBeginning - visibleRange;
519 item.displayMarginEnd = displayMarginEnd - visibleRange;
520 item.cacheBuffer = visibleRange;
521 }
522 }
523 } else {
524 if (!onBufferViewport) {
525 // If not on the buffered viewport, don't load anything
526 item.displayMarginBeginning = 0;
527 item.displayMarginEnd = -item.innerWidth;
528 item.cacheBuffer = 0;
529 } else {
530 if (onViewport && (scopeView.isCurrent || scopeView.visibleToParent)) {
531 // If on the buffered viewport and the viewport and the on a visible scope
532 // Set displayMargin so that cards are rendered
533 // And if not moving the parent list also give it some extra asynchronously
534 // buffering
535 item.displayMarginBeginning = 0;
536 item.displayMarginEnd = 0;
537 if (holdingList && holdingList.moving) {
538 // If we are moving we need to reset the cache buffer of the
539 // view that was not visible (i.e. !wasCurrentOnMoveStart) to 0 since
540 // otherwise the cache buffer we had set to preload the items of the
541 // visible range will trigger some item creations and we want move to
542 // be as smooth as possible meaning no need creations
543 if (!wasCurrentOnMoveStart) {
544 item.cacheBuffer = 0;
545 }
546 } else {
547 item.cacheBuffer = baseItem.width * 1.5;
548 }
549 } else {
550 // If on the buffered viewport but either not in the real viewport
551 // or in the viewport of the non current scope, use displayMargin + cacheBuffer
552 // to render asynchronously the width of cards
553 item.displayMarginBeginning = 0;
554 item.displayMarginEnd = -item.innerWidth;
555 item.cacheBuffer = item.innerWidth;
556 }
557 }
558 }
559 }
560 }
561 }
563 AbstractButton {
564 id: seeAll
565 objectName: "seeAll"
566 anchors {
567 top: rendererLoader.bottom
568 left: parent.left
569 right: parent.right
570 }
571 height: baseItem.expandable && !baseItem.headerLink ? seeAllLabel.font.pixelSize + units.gu(4) : 0
572 visible: height != 0
574 onClicked: {
575 if (categoryView.expandedCategoryId !== baseItem.category) {
576 categoryView.expandedCategoryId = baseItem.category;
577 floatingSeeLess.companionBase = baseItem;
578 } else {
579 categoryView.expandedCategoryId = "";
580 }
581 }
583 Label {
584 id: seeAllLabel
585 text: baseItem.expanded ? i18n.tr("Show less") : i18n.tr("Show all")
586 anchors {
587 centerIn: parent
588 verticalCenterOffset: units.gu(-0.5)
589 }
590 fontSize: "small"
591 font.weight: Font.Bold
592 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
593 }
594 }
596 Image {
597 visible: index != 0
598 anchors {
599 top: parent.top
600 left: parent.left
601 right: parent.right
602 }
603 fillMode: Image.Stretch
604 source: "graphics/dash_divider_top_lightgrad.png"
605 z: -1
606 }
608 Image {
609 // FIXME Should not rely on model.count but view.count, but ListViewWithPageHeader doesn't expose it yet.
610 visible: index != categoryView.model.count - 1
611 anchors {
612 bottom: seeAll.bottom
613 left: parent.left
614 right: parent.right
615 }
616 fillMode: Image.Stretch
617 source: "graphics/dash_divider_top_darkgrad.png"
618 z: -1
619 }
620 }
622 sectionProperty: "name"
623 sectionDelegate: ListItems.Header {
624 objectName: "dashSectionHeader" + (delegate ? delegate.category : "")
625 property int delegateIndex: -1
626 readonly property var delegate: categoryView.item(delegateIndex)
627 width: categoryView.width
628 height: text != "" ? units.gu(5) : 0
629 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
630 iconName: delegate && delegate.headerLink ? "go-next" : ""
631 onClicked: {
632 if (delegate.headerLink) scopeView.scope.performQuery(delegate.headerLink);
633 }
634 }
636 pageHeader: DashPageHeader {
637 objectName: "scopePageHeader"
638 width: parent.width
639 title: scopeView.scope ? scopeView.scope.name : ""
640 extraPanel: peExtraPanel
641 searchHistory: SearchHistoryModel
642 searchHint: scopeView.scope && scopeView.scope.searchHint || i18n.ctr("Label: Hint for dash search line edit", "Search")
643 scopeHasFilters: scopeView.scope.filters != null
644 activeFiltersCount: scopeView.scope.activeFiltersCount
645 showBackButton: scopeView.hasBackAction
646 searchEntryEnabled: true
647 settingsEnabled: scopeView.scope && scopeView.scope.settings && scopeView.scope.settings.count > 0 || false
648 favoriteEnabled: scopeView.scope && scopeView.scope.id !== "clickscope"
649 favorite: scopeView.scope && scopeView.scope.favorite
650 navigationTag: scopeView.scope ? scopeView.scope.primaryNavigationTag : ""
651 scopeStyle: scopeView.scopeStyle
652 paginationCount: scopeView.paginationCount
653 paginationIndex: scopeView.paginationIndex
655 onBackClicked: scopeView.backClicked()
656 onSettingsClicked: subPageLoader.openSubPage("settings")
657 onFavoriteClicked: scopeView.scope.favorite = !scopeView.scope.favorite
658 onSearchTextFieldFocused: scopeView.showHeader()
659 onClearSearch: { // keepPanelOpen
660 var panelOpen = peExtraPanel.visible;
661 resetSearch(keepPanelOpen);
662 scopeView.scope.resetPrimaryNavigationTag();
663 peExtraPanel.resetNavigation();
664 if ((panelOpen || searchHistory.count > 0) && keepPanelOpen) {
665 openPopup();
666 }
667 }
668 onShowFiltersPopup: { // item
669 extraPanel.visible = false;
670 scopeView.filtersPopover = PopupUtils.open(Qt.resolvedUrl("FiltersPopover.qml"), item, { "contentWidth": Qt.binding(function() { return scopeView.width - units.gu(2); } ) } );
671 scopeView.filtersPopover.Component.onDestruction.connect(function () {
672 categoryView.pageHeader.closePopup(false, true);
673 categoryView.pageHeader.unfocus(true); // remove the focus from the search field
674 })
675 }
676 }
678 PageHeaderExtraPanel {
679 id: peExtraPanel
680 objectName: "peExtraPanel"
681 width: parent.width >= units.gu(60) ? units.gu(40) : parent.width
682 anchors {
683 top: categoryView.pageHeader.bottom
684 topMargin: -categoryView.pageHeader.signatureLineHeight
685 }
686 z: 1
687 visible: false
689 searchHistory: SearchHistoryModel
690 scope: scopeView.scope
691 windowHeight: scopeView.height
693 onHistoryItemClicked: {
694 SearchHistoryModel.addQuery(text);
695 categoryView.pageHeader.searchQuery = text;
696 categoryView.pageHeader.unfocus();
697 }
699 onDashNavigationLeafClicked: {
700 categoryView.pageHeader.closePopup();
701 categoryView.pageHeader.unfocus();
702 }
704 onExtraPanelOptionSelected: {
705 categoryView.pageHeader.closePopup();
706 categoryView.pageHeader.unfocus();
707 }
708 }
709 }
711 Item {
712 id: pullToRefreshClippingItem
713 anchors.left: parent.left
714 anchors.right: parent.right
715 anchors.bottom: parent.bottom
716 height: parent.height - pullToRefresh.contentY - categoryView.pageHeader.height
717 clip: true
719 PullToRefresh {
720 id: pullToRefresh
721 objectName: "pullToRefresh"
722 target: categoryView
724 readonly property real contentY: categoryView.contentY - categoryView.originY
725 y: -contentY - units.gu(5)
727 onRefresh: {
728 refreshing = true
729 scopeView.scope.refresh()
730 }
731 anchors.left: parent.left
732 anchors.right: parent.right
734 Connections {
735 target: scopeView
736 onProcessingChanged: if (!scopeView.processing) pullToRefresh.refreshing = false
737 }
739 style: PullToRefreshScopeStyle {
740 anchors.fill: parent
741 activationThreshold: Math.min(units.gu(14), scopeView.height / 5)
742 }
743 }
744 }
746 AbstractButton {
747 id: floatingSeeLess
748 objectName: "floatingSeeLess"
750 property Item companionTo: companionBase ? companionBase.seeAllButton : null
751 property Item companionBase: null
752 property bool showBecausePosition: false
753 property real yOffset: 0
755 anchors {
756 left: categoryView.left
757 right: categoryView.right
758 }
759 y: parent.height - height + yOffset
760 height: seeLessLabel.font.pixelSize + units.gu(4)
761 visible: companionTo && showBecausePosition
763 onClicked: categoryView.expandedCategoryId = "";
765 function updateVisibility() {
766 var companionPos = companionTo.mapToItem(floatingSeeLess, 0, 0);
767 showBecausePosition = companionPos.y > 0;
769 var posToBase = floatingSeeLess.mapToItem(companionBase, 0, -yOffset).y;
770 yOffset = Math.max(0, companionBase.item.collapsedHeight - posToBase);
771 yOffset = Math.min(yOffset, height);
773 if (!showBecausePosition && categoryView.expandedCategoryId === "") {
774 companionBase = null;
775 }
776 }
778 Label {
779 id: seeLessLabel
780 text: i18n.tr("Show less")
781 anchors {
782 centerIn: parent
783 verticalCenterOffset: units.gu(-0.5)
784 }
785 fontSize: "small"
786 font.weight: Font.Bold
787 color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
788 }
790 Connections {
791 target: floatingSeeLess.companionTo ? categoryView : null
792 onContentYChanged: floatingSeeLess.updateVisibility();
793 }
795 Connections {
796 target: floatingSeeLess.companionTo
797 onYChanged: floatingSeeLess.updateVisibility();
798 }
799 }
801 Loader {
802 id: subPageLoader
803 objectName: "subPageLoader"
804 visible: x != width
805 width: parent.width
806 height: parent.height
807 anchors.left: categoryView.right
809 property bool open: false
810 property var scope: scopeView.scope
811 property var scopeStyle: scopeView.scopeStyle
812 property int initialIndex: -1
813 property var previewModel;
815 readonly property bool processing: item && item.processing || false
816 readonly property int count: item && item.count || 0
817 readonly property var currentItem: item && item.currentItem || null
819 property string subPage: ""
820 readonly property bool subPageShown: visible && status === Loader.Ready
822 function openSubPage(page) {
823 subPage = page;
824 }
826 function closeSubPage() {
827 open = false;
828 }
830 source: switch(subPage) {
831 case "preview": return "PreviewView.qml";
832 case "settings": return "ScopeSettingsPage.qml";
833 default: return "";
834 }
836 onLoaded: {
837 item.scope = Qt.binding(function() { return subPageLoader.scope; } )
838 item.scopeStyle = Qt.binding(function() { return subPageLoader.scopeStyle; } )
839 if (subPage == "preview") {
840 item.open = Qt.binding(function() { return subPageLoader.open; } )
841 item.previewModel = subPageLoader.previewModel;
842 subPageLoader.previewModel = null;
843 }
844 open = true;
845 }
847 onOpenChanged: categoryView.pageHeader.unfocus()
849 onVisibleChanged: if (!visible) subPage = ""
851 Connections {
852 target: subPageLoader.item
853 onBackClicked: subPageLoader.closeSubPage()
854 }
855 }