git.iko.soy/unity8
on c1843bf help sign in
unity8/qml/Panel/Panel.qml
235 lines 7.8 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import Unity.Application 0.1
20import "../Components"
21import "../Components/PanelState"
22import ".."
24Item {
25 id: root
26 readonly property real panelHeight: indicatorArea.y + d.indicatorHeight
27 property alias indicators: __indicators
28 property alias callHint: __callHint
29 property bool fullscreenMode: false
30 property real indicatorAreaShowProgress: 1.0
31 property bool locked: false
33 MouseArea {
34 anchors.fill: parent
35 anchors.topMargin: panelHeight
36 visible: !indicators.fullyClosed
37 enabled: visible
38 onClicked: if (indicators.fullyOpened) indicators.hide();
39 hoverEnabled: true // should also eat hover events, otherwise they will pass through
40 }
42 Binding {
43 target: PanelState
44 property: "panelHeight"
45 value: indicators.minimizedPanelHeight
46 }
48 Item {
49 id: indicatorArea
50 objectName: "indicatorArea"
52 anchors.fill: parent
54 transform: Translate {
55 y: indicators.state === "initial"
56 ? (1.0 - indicatorAreaShowProgress) * -d.indicatorHeight
57 : 0
58 }
60 BorderImage {
61 id: indicatorsDropShadow
62 anchors {
63 fill: indicators
64 leftMargin: -units.gu(1)
65 bottomMargin: -units.gu(1)
66 }
67 visible: !indicators.fullyClosed
68 source: "graphics/rectangular_dropshadow.sci"
69 }
71 BorderImage {
72 id: panelDropShadow
73 anchors {
74 fill: indicatorAreaBackground
75 bottomMargin: -units.gu(1)
76 }
77 visible: PanelState.dropShadow && !callHint.visible
78 source: "graphics/rectangular_dropshadow.sci"
79 }
81 Rectangle {
82 id: indicatorAreaBackground
83 color: callHint.visible ? UbuntuColors.green : theme.palette.normal.background
84 anchors {
85 top: parent.top
86 left: parent.left
87 right: parent.right
88 }
89 height: indicators.minimizedPanelHeight
91 Behavior on color { ColorAnimation { duration: UbuntuAnimation.FastDuration } }
92 }
94 MouseArea {
95 anchors {
96 top: parent.top
97 left: parent.left
98 right: indicators.left
99 }
100 height: indicators.minimizedPanelHeight
101 hoverEnabled: true
102 onClicked: callHint.visible ? callHint.showLiveCall() : PanelState.focusMaximizedApp()
103 onDoubleClicked: PanelState.maximize()
105 // WindowControlButtons inside the mouse area, otherwise QML doesn't grok nested hover events :/
106 // cf. https://bugreports.qt.io/browse/QTBUG-32909
107 WindowControlButtons {
108 id: windowControlButtons
109 objectName: "panelWindowControlButtons"
110 anchors {
111 left: parent.left
112 top: parent.top
113 leftMargin: units.gu(1)
114 topMargin: units.gu(0.5)
115 bottomMargin: units.gu(0.5)
116 }
117 height: indicators.minimizedPanelHeight - anchors.topMargin - anchors.bottomMargin
118 visible: PanelState.buttonsVisible && parent.containsMouse && !root.locked && !callHint.visible
119 active: PanelState.buttonsVisible
120 onClose: PanelState.close()
121 onMinimize: PanelState.minimize()
122 onMaximize: PanelState.maximize()
123 }
124 }
126 IndicatorsMenu {
127 id: __indicators
128 objectName: "indicators"
130 anchors {
131 top: parent.top
132 right: parent.right
133 }
135 shown: false
136 width: root.width - (windowControlButtons.visible ? windowControlButtons.width + titleLabel.width : 0)
137 minimizedPanelHeight: units.gu(3)
138 expandedPanelHeight: units.gu(7)
139 openedHeight: root.height
141 overFlowWidth: {
142 if (callHint.visible) {
143 return Math.max(root.width - (callHint.width + units.gu(2)), 0)
144 }
145 return root.width
146 }
147 enableHint: !callHint.active && !fullscreenMode
148 showOnClick: !callHint.visible
149 panelColor: indicatorAreaBackground.color
151 onShowTapped: {
152 if (callHint.active) {
153 callHint.showLiveCall();
154 }
155 }
156 }
158 Label {
159 id: titleLabel
160 objectName: "windowDecorationTitle"
161 anchors {
162 left: parent.left
163 right: __indicators.left
164 top: parent.top
165 leftMargin: units.gu(1)
166 rightMargin: units.gu(1)
167 topMargin: units.gu(0.5)
168 bottomMargin: units.gu(0.5)
169 }
170 color: PanelState.buttonsVisible ? "#ffffff" : "#5d5d5d"
171 height: indicators.minimizedPanelHeight - anchors.topMargin - anchors.bottomMargin
172 visible: !windowControlButtons.visible && !root.locked && !callHint.visible
173 verticalAlignment: Text.AlignVCenter
174 fontSize: "medium"
175 font.weight: Font.Normal
176 text: PanelState.title
177 elide: Text.ElideRight
178 maximumLineCount: 1
179 }
181 // TODO here would the Locally integrated menus come
183 ActiveCallHint {
184 id: __callHint
185 anchors {
186 top: parent.top
187 left: parent.left
188 }
189 height: indicators.minimizedPanelHeight
190 visible: active && indicators.state == "initial"
191 }
192 }
194 QtObject {
195 id: d
196 objectName: "panelPriv"
197 readonly property real indicatorHeight: indicators.minimizedPanelHeight
198 }
200 states: [
201 State {
202 name: "onscreen" //fully opaque and visible at top edge of screen
203 when: !fullscreenMode
204 PropertyChanges {
205 target: indicatorArea;
206 anchors.topMargin: 0
207 opacity: 1;
208 }
209 },
210 State {
211 name: "offscreen" //pushed off screen
212 when: fullscreenMode
213 PropertyChanges {
214 target: indicatorArea;
215 anchors.topMargin: indicators.state === "initial" ? -d.indicatorHeight : 0
216 opacity: indicators.fullyClosed ? 0.0 : 1.0
217 }
218 PropertyChanges {
219 target: indicators.showDragHandle;
220 anchors.bottomMargin: -units.gu(1)
221 }
222 }
223 ]
225 transitions: [
226 Transition {
227 to: "onscreen"
228 UbuntuNumberAnimation { target: indicatorArea; properties: "anchors.topMargin,opacity" }
229 },
230 Transition {
231 to: "offscreen"
232 UbuntuNumberAnimation { target: indicatorArea; properties: "anchors.topMargin,opacity" }
233 }
234 ]