git.iko.soy/unity8
on c7d6ea9 help sign in
unity8/Dash/GenericScopeView.qml
329 lines 12 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Components 0.1
19import "../Components"
20import "../Components/ListItems" as ListItems
22ScopeView {
23 id: scopeView
24 readonly property alias previewShown: previewLoader.onScreen
25 property bool enableHeightBehaviorOnNextCreation: false
27 onIsCurrentChanged: {
28 pageHeader.resetSearch();
29 previewLoader.open = false;
30 }
32 onMovementStarted: categoryView.showHeader()
34 onPositionedAtBeginning: categoryView.positionAtBeginning()
36 Binding {
37 target: scopeView.scope
38 property: "searchQuery"
39 value: pageHeader.searchQuery
40 }
42 Binding {
43 target: pageHeader
44 property: "searchQuery"
45 value: scopeView.scope.searchQuery
46 }
48 Connections {
49 target: panel
50 onSearchClicked: if (isCurrent) {
51 pageHeader.triggerSearch()
52 categoryView.showHeader()
53 }
54 }
56 Connections {
57 target: scopeView.scope
58 onShowDash: previewLoader.open = false;
59 onHideDash: previewLoader.open = false;
60 }
62 ScopeListView {
63 id: categoryView
64 objectName: "categoryListView"
65 anchors.fill: parent
66 model: scopeView.categories
67 forceNoClip: previewLoader.onScreen
69 onAtYEndChanged: if (atYEnd) endReached()
70 onMovingChanged: if (moving && atYEnd) endReached()
72 property string expandedCategoryId: ""
74 delegate: ListItems.Base {
75 highlightWhenPressed: false
77 readonly property bool expandable: rendererLoader.item ? rendererLoader.item.expandable : false
78 readonly property bool filtered: rendererLoader.item ? rendererLoader.item.filter : true
79 readonly property string category: categoryId
81 Loader {
82 id: rendererLoader
83 anchors {
84 top: parent.top
85 left: parent.left
86 right: parent.right
87 }
89 source: getRenderer(model.renderer, model.contentType, model.rendererHint)
91 onLoaded: {
92 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
93 item.enableHeightBehavior = scopeView.enableHeightBehaviorOnNextCreation;
94 scopeView.enableHeightBehaviorOnNextCreation = false;
95 }
96 if (source.toString().indexOf("Apps/RunningApplicationsGrid.qml") != -1) {
97 // TODO: the running apps grid doesn't support standard scope results model yet
98 item.firstModel = Qt.binding(function() { return results.firstModel })
99 item.secondModel = Qt.binding(function() { return results.secondModel })
100 } else {
101 item.model = Qt.binding(function() { return results })
102 }
103 item.objectName = Qt.binding(function() { return categoryId })
104 if (item.expandable) {
105 var shouldFilter = categoryId != categoryView.expandedCategoryId;
106 if (shouldFilter != item.filter) {
107 item.filter = shouldFilter;
108 }
109 }
110 }
112 Component.onDestruction: {
113 if (item.enableHeightBehavior !== undefined && item.enableHeightBehaviorOnNextCreation !== undefined) {
114 scopeView.enableHeightBehaviorOnNextCreation = item.enableHeightBehaviorOnNextCreation;
115 }
116 }
118 Connections {
119 target: rendererLoader.item
120 onClicked: {
121 effect.positionPx = mapToItem(categoryView, 0, itemY).y
122 scopeView.scope.activate(delegateItem.model.uri,
123 delegateItem.model.icon,
124 delegateItem.model.category,
125 0,
126 delegateItem.model.mimetype,
127 delegateItem.model.title,
128 delegateItem.model.comment,
129 delegateItem.model.dndUri,
130 delegateItem.model.metadata)
131 }
132 onPressAndHold: {
133 effect.positionPx = mapToItem(categoryView, 0, itemY).y
134 scopeView.scope.preview( delegateItem.model.uri,
135 delegateItem.model.icon,
136 delegateItem.model.category,
137 0,
138 delegateItem.model.mimetype,
139 delegateItem.model.title,
140 delegateItem.model.comment,
141 delegateItem.model.dndUri,
142 delegateItem.model.metadata)
143 }
144 }
145 Connections {
146 target: categoryView
147 onExpandedCategoryIdChanged: {
148 var item = rendererLoader.item;
149 if (item.expandable) {
150 var shouldFilter = categoryId != categoryView.expandedCategoryId;
151 if (shouldFilter != item.filter) {
152 // If the filter animation will be seen start it, otherwise, just flip the switch
153 var shrinkingVisible = shouldFilter && y + item.collapsedHeight < categoryView.height;
154 var growingVisible = !shouldFilter && y + height < categoryView.height;
155 if (shrinkingVisible || growingVisible) {
156 item.startFilterAnimation(shouldFilter)
157 } else {
158 item.filter = shouldFilter;
159 }
160 if (!shouldFilter) {
161 categoryView.maximizeVisibleArea(index, item.uncollapsedHeight);
162 }
163 }
164 }
165 }
166 }
167 }
168 }
170 sectionProperty: "name"
171 sectionDelegate: ListItems.Header {
172 property var delegate: categoryView.item(delegateIndex)
173 width: categoryView.width
174 text: section
175 image: {
176 if (delegate && delegate.expandable)
177 return delegate.filtered ? "graphics/header_handlearrow.png" : "graphics/header_handlearrow2.png"
178 return "";
179 }
180 onClicked: {
181 if (categoryView.expandedCategoryId != delegate.category)
182 categoryView.expandedCategoryId = delegate.category;
183 else
184 categoryView.expandedCategoryId = "";
185 }
186 }
187 pageHeader: PageHeader {
188 id: pageHeader
189 objectName: "pageHeader"
190 width: categoryView.width
191 text: scopeView.scope.name
192 searchEntryEnabled: true
193 scope: scopeView.scope
194 }
195 }
197 function getDefaultRendererId(contentType) {
198 switch (contentType) {
199 default: return "grid";
200 }
201 }
203 function getRenderer(rendererId, contentType, rendererHint) {
204 if (rendererId == "default") {
205 rendererId = getDefaultRendererId(contentType);
206 }
207 switch (rendererId) {
208 case "grid": {
209 switch (contentType) {
210 case "video": return "Generic/GenericFilterGridPotrait.qml";
211 case "music": return "Music/MusicFilterGrid.qml";
212 case "apps": {
213 if (rendererHint == "toggled")
214 return "Apps/DashPluginFilterGrid.qml";
215 else
216 return "Generic/GenericFilterGrid.qml";
217 }
218 case "weather": return "Generic/WeatherFilterGrid.qml";
219 default: return "Generic/GenericFilterGrid.qml";
220 }
221 }
222 case "carousel": {
223 switch (contentType) {
224 case "music": return "Music/MusicCarousel.qml";
225 default: return "Generic/GenericCarousel.qml";
226 }
227 }
228 case "special": {
229 switch (contentType) {
230 case "apps": return "Apps/RunningApplicationsGrid.qml";
231 default: return "Generic/GenericFilterGrid.qml";
232 }
233 }
234 default: return "Generic/GenericFilterGrid.qml";
235 }
236 }
238 OpenEffect {
239 id: effect
240 anchors {
241 fill: parent
242 bottomMargin: -bottomOverflow
243 }
244 sourceItem: categoryView
246 enabled: gap > 0.0
248 topGapPx: (1 - gap) * positionPx
249 topOpacity: (1 - gap * 1.2)
250 bottomGapPx: positionPx + gap * (targetBottomGapPx - positionPx)
251 bottomOverflow: units.gu(20)
252 bottomOpacity: 1 - (gap * 0.8)
254 property int targetBottomGapPx: height - units.gu(8) - bottomOverflow
255 property real gap: previewLoader.open ? 1.0 : 0.0
257 Behavior on gap {
258 NumberAnimation {
259 duration: 200
260 easing.type: Easing.InOutQuad
261 onRunningChanged: {
262 if (!previewLoader.open && !running) {
263 previewLoader.onScreen = false
264 }
265 }
266 }
267 }
268 }
270 Connections {
271 target: scopeView.scope
272 onPreviewReady: {
273 previewLoader.previewData = preview
274 previewLoader.open = true
275 }
276 }
278 PreviewDelegateMapper {
279 id: previewDelegateMapper
280 }
282 Connections {
283 ignoreUnknownSignals: true
284 target: previewLoader.valid ? previewLoader.item : null
285 onClose: {
286 previewLoader.open = false
287 }
288 }
290 Loader {
291 objectName: "previewLoader"
292 id: previewLoader
293 property var previewData
294 height: effect.bottomGapPx - effect.topGapPx
295 anchors {
296 top: parent.top
297 topMargin: effect.topGapPx
298 left: parent.left
299 right: parent.right
300 }
301 source: onScreen ? previewDelegateMapper.map(previewLoader.previewData.rendererName) : ""
303 property bool open: false
304 property bool onScreen: false
305 property bool valid: item !== null
307 onOpenChanged: {
308 if (open) {
309 onScreen = true
310 }
311 }
313 onLoaded: {
314 item.previewData = Qt.binding(function() { return previewLoader.previewData })
315 }
316 }
318 // TODO: Move as InverseMouseArea to DashPreview
319 MouseArea {
320 enabled: previewLoader.onScreen
321 anchors {
322 fill: parent
323 topMargin: effect.bottomGapPx
324 }
325 onClicked: {
326 previewLoader.open = false;
327 }
328 }