git.iko.soy/unity8
on cf44c47 help sign in
unity8/GreeterShell.qml
168 lines 4.8 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Application 0.1
19import LightDM 0.1 as LightDM
20import "Greeter"
21import "Launcher"
22import "Panel"
23import "Components"
24import "Components/Math.js" as MathLocal
26BasicShell {
27 id: shell
29 function activateApplication(desktopFile, argument) {
30 greeter.login()
31 // TODO: support opening the app once inside user's session
32 }
34 Lockscreen {
35 id: lockscreen
36 hides: [launcher, panel.indicators]
37 shown: false
38 enabled: true
39 showAnimation: StandardAnimation { property: "opacity"; to: 1 }
40 hideAnimation: StandardAnimation { property: "opacity"; to: 0 }
41 y: panel.panelHeight
42 x: required ? 0 : - width
43 width: parent.width
44 height: parent.height - panel.panelHeight
45 background: shell.background
47 onUnlocked: lockscreen.hide()
48 onCancel: greeter.show()
50 Component.onCompleted: {
51 if (LightDM.Users.count == 1) {
52 LightDM.Greeter.authenticate(LightDM.Users.data(0, LightDM.UserRoles.NameRole))
53 }
54 }
55 }
57 Connections {
58 target: LightDM.Greeter
60 onShowPrompt: {
61 if (LightDM.Users.count == 1) {
62 // TODO: There's no better way for now to determine if its a PIN or a passphrase.
63 if (text == "PIN") {
64 lockscreen.alphaNumeric = false
65 } else {
66 lockscreen.alphaNumeric = true
67 }
68 lockscreen.placeholderText = i18n.tr("Please enter %1").arg(text);
69 lockscreen.show();
70 }
71 }
72 }
74 Greeter {
75 id: greeter
76 objectName: "greeter"
78 available: true
79 hides: [launcher, panel.indicators]
80 shown: true
82 y: panel.panelHeight
83 width: parent.width
84 height: parent.height - panel.panelHeight
86 dragHandleWidth: shell.edgeSize
88 function login() {
89 enabled = false;
90 LightDM.Greeter.startSessionSync();
91 }
93 onShownChanged: {
94 if (shown) {
95 lockscreen.reset();
96 // If there is only one user, we start authenticating with that one here.
97 // If there are more users, the Greeter will handle that
98 if (LightDM.Users.count == 1) {
99 LightDM.Greeter.authenticate(LightDM.Users.data(0, LightDM.UserRoles.NameRole));
100 }
101 greeter.forceActiveFocus();
102 }
103 else if (LightDM.Greeter.promptless)
104 login();
105 }
107 onUnlocked: login()
109 onLeftTeaserPressedChanged: {
110 if (leftTeaserPressed) {
111 launcher.tease();
112 }
113 }
114 }
116 InputFilterArea {
117 anchors.fill: parent
118 blockInput: true
119 }
121 Revealer {
122 id: greeterRevealer
123 objectName: "greeterRevealer"
125 property real animatedProgress: MathLocal.clamp(-dragPosition / closedValue, 0, 1)
126 target: greeter
127 width: greeter.width
128 height: greeter.height
129 handleSize: shell.edgeSize
130 orientation: Qt.Horizontal
131 enabled: !greeter.locked
132 }
134 Item {
135 id: overlay
137 anchors.fill: parent
139 Panel {
140 id: panel
141 anchors.fill: parent //because this draws indicator menus
142 indicatorsMenuWidth: parent.width > units.gu(60) ? units.gu(40) : parent.width
143 indicators {
144 hides: [launcher]
145 }
146 fullscreenMode: false
147 searchVisible: false
148 }
150 Launcher {
151 id: launcher
153 anchors.top: parent.top
154 anchors.bottom: parent.bottom
155 width: parent.width
156 dragAreaWidth: shell.edgeSize
157 available: greeter.narrowMode
158 onLauncherApplicationSelected: {
159 shell.activateApplication(name)
160 }
161 onShownChanged: {
162 if (shown) {
163 panel.indicators.hide()
164 }
165 }
166 }
167 }