git.iko.soy/unity8
on dbb8563 help sign in
unity8/qml/Components/Dialogs.qml
260 lines 8.1 kB history raw
1/*
2 * Copyright (C) 2014-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
19import Unity.Application 0.1
20import Unity.Session 0.1
21import GlobalShortcut 1.0
22import Ubuntu.Components 1.3
23import Unity.Platform 1.0
24import Utils 0.1
25import "../Greeter"
27Item {
28 id: root
30 // to be set from outside, useful mostly for testing purposes
31 property var unitySessionService: DBusUnitySessionService
32 property var closeAllApps: function() {
33 while (true) {
34 var app = ApplicationManager.get(0);
35 if (app === null) {
36 break;
37 }
38 ApplicationManager.stopApplication(app.appId);
39 }
40 }
41 property string usageScenario
43 signal powerOffClicked();
45 function showPowerDialog() {
46 d.showPowerDialog();
47 }
49 onUsageScenarioChanged: {
50 if (usageScenario != "desktop" && legacyAppsModel.count > 0 && !d.modeSwitchWarningPopup) {
51 var comp = Qt.createComponent(Qt.resolvedUrl("ModeSwitchWarningDialog.qml"))
52 d.modeSwitchWarningPopup = comp.createObject(root, {model: legacyAppsModel});
53 d.modeSwitchWarningPopup.forceClose.connect(function() {
54 for (var i = legacyAppsModel.count - 1; i >= 0; i--) {
55 ApplicationManager.stopApplication(legacyAppsModel.get(i).appId);
56 }
57 d.modeSwitchWarningPopup.hide();
58 d.modeSwitchWarningPopup.destroy();
59 d.modeSwitchWarningPopup = null;
60 })
61 } else if (usageScenario == "desktop" && d.modeSwitchWarningPopup) {
62 d.modeSwitchWarningPopup.hide();
63 d.modeSwitchWarningPopup.destroy();
64 d.modeSwitchWarningPopup = null;
65 }
66 }
68 ApplicationsFilterModel {
69 id: legacyAppsModel
70 applicationsModel: ApplicationManager
71 filterTouchApps: true
72 }
74 GlobalShortcut { // reboot/shutdown dialog
75 shortcut: Qt.Key_PowerDown
76 active: Platform.isPC
77 onTriggered: root.unitySessionService.RequestShutdown()
78 }
80 GlobalShortcut { // reboot/shutdown dialog
81 shortcut: Qt.Key_PowerOff
82 active: Platform.isPC
83 onTriggered: root.unitySessionService.RequestShutdown()
84 }
86 GlobalShortcut { // sleep
87 shortcut: Qt.Key_Sleep
88 onTriggered: root.unitySessionService.Suspend()
89 }
91 GlobalShortcut { // hibernate
92 shortcut: Qt.Key_Hibernate
93 onTriggered: root.unitySessionService.Hibernate()
94 }
96 GlobalShortcut { // logout/lock dialog
97 shortcut: Qt.Key_LogOff
98 onTriggered: root.unitySessionService.RequestLogout()
99 }
101 GlobalShortcut { // logout/lock dialog
102 shortcut: Qt.ControlModifier|Qt.AltModifier|Qt.Key_Delete
103 onTriggered: root.unitySessionService.RequestLogout()
104 }
106 GlobalShortcut { // lock screen
107 shortcut: Qt.Key_ScreenSaver
108 onTriggered: lightDM.greeter.showGreeter()
109 }
111 GlobalShortcut { // lock screen
112 shortcut: Qt.ControlModifier|Qt.AltModifier|Qt.Key_L
113 onTriggered: lightDM.greeter.showGreeter()
114 }
116 QtObject {
117 id: d // private stuff
118 objectName: "dialogsPrivate"
120 property var modeSwitchWarningPopup: null
122 function showPowerDialog() {
123 if (!dialogLoader.active) {
124 dialogLoader.sourceComponent = powerDialogComponent;
125 dialogLoader.focus = true;
126 dialogLoader.active = true;
127 }
128 }
129 }
131 Loader {
132 id: dialogLoader
133 objectName: "dialogLoader"
134 anchors.fill: parent
135 active: false
136 }
138 LightDM {id: lightDM} // Provide backend access
140 Component {
141 id: logoutDialogComponent
142 ShellDialog {
143 id: logoutDialog
144 title: i18n.ctr("Title: Lock/Log out dialog", "Log out")
145 text: i18n.tr("Are you sure you want to log out?")
146 Button {
147 text: i18n.ctr("Button: Lock the system", "Lock")
148 onClicked: {
149 lightDM.greeter.showGreeter()
150 logoutDialog.hide();
151 }
152 }
153 Button {
154 text: i18n.ctr("Button: Log out from the system", "Log Out")
155 onClicked: {
156 unitySessionService.logout();
157 logoutDialog.hide();
158 }
159 }
160 Button {
161 text: i18n.tr("Cancel")
162 onClicked: {
163 logoutDialog.hide();
164 }
165 }
166 }
167 }
169 Component {
170 id: rebootDialogComponent
171 ShellDialog {
172 id: rebootDialog
173 title: i18n.ctr("Title: Reboot dialog", "Reboot")
174 text: i18n.tr("Are you sure you want to reboot?")
175 Button {
176 text: i18n.tr("No")
177 onClicked: {
178 rebootDialog.hide();
179 }
180 color: UbuntuColors.lightGrey
181 }
182 Button {
183 text: i18n.tr("Yes")
184 onClicked: {
185 root.closeAllApps();
186 unitySessionService.reboot();
187 rebootDialog.hide();
188 }
189 color: UbuntuColors.red
190 }
191 }
192 }
194 Component {
195 id: powerDialogComponent
196 ShellDialog {
197 id: powerDialog
198 title: i18n.ctr("Title: Power off/Restart dialog", "Power")
199 text: i18n.tr("Are you sure you would like\nto power off?")
200 Button {
201 text: i18n.ctr("Button: Power off the system", "Power off")
202 onClicked: {
203 root.closeAllApps();
204 powerDialog.hide();
205 root.powerOffClicked();
206 }
207 color: UbuntuColors.red
208 }
209 Button {
210 text: i18n.ctr("Button: Restart the system", "Restart")
211 onClicked: {
212 root.closeAllApps();
213 unitySessionService.reboot();
214 powerDialog.hide();
215 }
216 color: UbuntuColors.lightGrey
217 }
218 Button {
219 text: i18n.tr("Cancel")
220 onClicked: {
221 powerDialog.hide();
222 }
223 color: UbuntuColors.lightGrey
224 }
225 }
226 }
228 Connections {
229 target: root.unitySessionService
231 onLogoutRequested: {
232 // Display a dialog to ask the user to confirm.
233 if (!dialogLoader.active) {
234 dialogLoader.sourceComponent = logoutDialogComponent;
235 dialogLoader.focus = true;
236 dialogLoader.active = true;
237 }
238 }
240 onShutdownRequested: {
241 // Display a dialog to ask the user to confirm.
242 showPowerDialog();
243 }
245 onRebootRequested: {
246 // Display a dialog to ask the user to confirm.
248 // display a combined reboot/shutdown dialog, sadly the session indicator calls rather the "Reboot()" method
249 // than shutdown when clicking on the "Shutdown..." menu item
250 // FIXME: when/if session indicator is fixed, put the rebootDialogComponent here
251 showPowerDialog();
252 }
254 onLogoutReady: {
255 root.closeAllApps();
256 Qt.quit();
257 unitySessionService.endSession();
258 }
259 }