git.iko.soy/unity8
on f2c2cdb help sign in
unity8/Components/Showable.qml
115 lines 3.0 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
19Item {
20 id: showable
22 property bool available: true
23 property bool shown: true
25 /* If your showable supports on demand content creation/destruction,
26 set this to false when destroyed and true when ready to be shown.
27 NOTE: You should load your content when "required" is true and
28 destroy when "required" is false
29 */
30 property bool created: true
31 property bool required
32 property bool __shouldShow: false
34 property list<QtObject> hides
35 property var showAnimation
36 property var hideAnimation
38 // automatically set the target on showAnimation and hideAnimation to be the
39 // showable itself
40 onShowAnimationChanged: if (showAnimation) showAnimation["target"] = showable
41 onHideAnimationChanged: if (hideAnimation) hideAnimation["target"] = showable
43 Component.onCompleted: required = shown;
45 function __hideOthers() {
46 var i
47 for (i=0; i<hides.length; i++) {
48 hides[i].hide()
49 }
50 }
52 function show() {
53 required = true;
54 if (created) {
55 __reallyShow();
56 } else {
57 __shouldShow = true;
58 }
59 }
61 onCreatedChanged: {
62 if (created && __shouldShow) {
63 __reallyShow();
64 __shouldShow = false;
65 }
66 }
68 function __reallyShow() {
69 if (!available) {
70 return false;
71 }
73 __hideOthers();
75 if (hideAnimation != undefined && hideAnimation.running) {
76 hideAnimation.stop();
77 }
79 if (showAnimation != undefined) {
80 if (!showAnimation.running) {
81 showAnimation.restart()
82 }
83 } else {
84 visible = true;
85 }
87 shown = true;
88 return true;
89 }
91 function hide() {
92 if (showAnimation != undefined && showAnimation.running) {
93 showAnimation.stop()
94 }
95 if (hideAnimation != undefined) {
96 if (!hideAnimation.running) {
97 hideAnimation.restart()
98 }
99 } else {
100 visible = false
101 required = false
102 }
104 shown = false
105 }
107 Connections {
108 target: hideAnimation ? hideAnimation: null
109 onRunningChanged: {
110 if (!hideAnimation.running) {
111 required = false;
112 }
113 }
114 }