git.iko.soy/unity8
on f598fb9 help sign in
unity8/Launcher/Launcher.qml
251 lines 7.1 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import "../Components"
19import Ubuntu.Components 0.1
20import Ubuntu.Gestures 0.1
21import Unity 0.1
22import Unity.Launcher 0.1
24Item {
25 id: root
27 property bool available: true // can be used to disable all interactions
29 property bool teasing: false
30 property int panelWidth: units.gu(8.5)
31 property int dragAreaWidth: units.gu(1)
32 property real progress: dragArea.dragging && dragArea.touchX > panel.width ? dragArea.touchX : 0
34 readonly property bool shown: panel.x > -panel.width
36 // emitted when an application is selected
37 signal launcherApplicationSelected(string desktopFile)
39 // emitted when the apps dash should be shown because of a swipe gesture
40 signal dash()
42 // emitted when the dash icon in the launcher has been tapped
43 signal dashItemSelected()
45 onStateChanged: {
46 if (state == "") {
47 dismissTimer.stop()
48 } else {
49 dismissTimer.restart()
50 }
51 }
53 function hide() {
54 switchToNextState("")
55 }
57 function switchToNextState(state) {
58 animateTimer.nextState = state
59 animateTimer.start();
60 }
62 onTeasingChanged: {
63 if (teasing) {
64 teaseTimer.start();
65 }
66 }
68 Timer {
69 id: teaseTimer
70 interval: 200
71 }
73 Timer {
74 id: dismissTimer
75 interval: 5000
76 onTriggered: {
77 if (!panel.moving) {
78 root.state = ""
79 } else {
80 dismissTimer.restart()
81 }
82 }
83 }
85 // Because the animation on x is disabled while dragging
86 // switching state directly in the drag handlers would not animate
87 // the completion of the hide/reveal gesture. Lets update the state
88 // machine and switch to the final state in the next event loop run
89 Timer {
90 id: animateTimer
91 interval: 1
92 property string nextState: ""
93 onTriggered: {
94 // switching to an intermediate state here to make sure all the
95 // values are restored, even if we were already in the target state
96 root.state = "tmp"
97 root.state = nextState
98 }
99 }
101 MouseArea {
102 id: launcherDragArea
103 enabled: root.state == "visible"
104 anchors.fill: panel
105 anchors.rightMargin: -units.gu(2)
106 drag {
107 axis: Drag.XAxis
108 maximumX: 0
109 target: panel
110 }
112 onReleased: {
113 if (panel.x < -panel.width/3) {
114 root.switchToNextState("")
115 } else {
116 root.switchToNextState("visible")
117 }
118 }
120 }
121 MouseArea {
122 id: closeMouseArea
123 anchors {
124 left: launcherDragArea.right
125 top: parent.top
126 right: parent.right
127 bottom: parent.bottom
128 }
129 enabled: root.state == "visible"
130 onPressed: {
131 root.state = ""
132 }
133 }
135 Rectangle {
136 id: backgroundShade
137 anchors.fill: parent
138 color: "black"
139 opacity: root.state == "visible" ? 0.4 : 0
141 Behavior on opacity { NumberAnimation { duration: 200; easing.type: Easing.OutQuad} }
142 }
144 LauncherPanel {
145 id: panel
146 objectName: "launcherPanel"
147 width: root.panelWidth
148 anchors {
149 top: parent.top
150 bottom: parent.bottom
151 }
152 x: -width
153 model: LauncherModel
155 property bool animate: true
157 onApplicationSelected: {
158 root.state = ""
159 launcherApplicationSelected(desktopFile)
160 }
161 onDashItemSelected: {
162 root.state = ""
163 root.dashItemSelected(index)
164 }
166 onMovingChanged: {
167 if (dismissTimer.running) {
168 dismissTimer.restart();
169 }
170 }
172 Behavior on x {
173 NumberAnimation {
174 // Disabling animation when dragging
175 duration: dragArea.dragging || launcherDragArea.drag.active ? 0 : 300;
176 easing.type: Easing.OutCubic
177 }
178 }
179 }
181 DirectionalDragArea {
182 id: dragArea
184 direction: Direction.Rightwards
186 // values to be tweaked and later removed from here and set in stone as defaults
187 // once we are confident it's all good.
188 maxDeviation: units.gu(1)
189 wideningAngle: 30
190 distanceThreshold: units.gu(3)
191 minSpeed: units.gu(5)
193 enabled: root.available && root.state !== "visible"
194 width: root.dragAreaWidth
195 height: root.height
197 onTouchXChanged: {
198 if (status !== DirectionalDragArea.Recognized)
199 return;
201 // When the gesture finally gets recognized, the finger will likely be
202 // reasonably far from the edge. If we made the panel immediately
203 // follow the finger position it would be visually unpleasant as it
204 // would appear right next to the user's finger out of nowhere.
205 // Instead, we make the panel go towards the user's finger in several
206 // steps. ie., in an animated way.
207 var targetPanelX = Math.min(0, touchX - panel.width)
208 var delta = targetPanelX - panel.x
209 // the trick is not to go all the way (1.0) as it would cause a sudden jump
210 panel.x += 0.4 * delta
211 }
213 onDraggingChanged: {
214 if (!dragging) {
215 if (distance > panel.width / 2) {
216 root.switchToNextState("visible")
217 if (distance > panel.width * 2) {
218 root.dash()
219 }
220 } else {
221 root.switchToNextState("")
222 }
223 }
224 }
225 }
227 states: [
228 State {
229 name: "" // hidden state. Must be the default state ("") because "when:" falls back to this.
230 PropertyChanges {
231 target: panel
232 x: -root.panelWidth
233 }
234 },
235 State {
236 name: "visible"
237 PropertyChanges {
238 target: panel
239 x: 0
240 }
241 },
242 State {
243 name: "teasing"
244 when: root.teasing || teaseTimer.running
245 PropertyChanges {
246 target: panel
247 x: -root.panelWidth + units.gu(2)
248 }
249 }
250 ]