shrub/pkg/arvo/tests/lib/dprint.hoon

::  This library contains unit tests for doccords.
::
/+  *test, *dprint
::
=>  =>
    ::  This core is for testing core and chapter docs.
    :>    core-summary
    :>
    :>  core-description
    |%  %core-test
    :>    chapter-summary
    :>
    :>  chapter-description
    +|  %chapter-test
    ++  empty  ~
    --
  ::
  :>    arms used for testing arm documentation
  |%  %test-arms
  +|  %types
  +$  arm-dox  [tape what what what]
  +$  core-dox  [tape what]
  +$  chapter-dox  [tape what]
  ::
  +|  %helper-functions
  ++  get-item
    |=  a=(list term)
    ^-  item
    +:(find-item-in-type a -:!>(.) %.y)
  ::
  ++  get-arm-dox
    |=  a=(list term)
    ^-  arm-dox
    =/  itm=item  (get-item a)
    ?>  ?=([%arm *] itm)
    [name adoc pdoc cdoc]:itm
  ::
  ++  get-core-dox
    |=  a=(list term)
    ^-  core-dox
    =/  itm=item  (get-item a)
    ?>  ?=([%core *] itm)
    [name docs]:itm
  ::
  ++  get-chapter-dox
    |=  a=(list term)
    ^-  chapter-dox
    =/  itm=item  (get-item a)
    ?>  ?=([%chapter *] itm)
    [name docs]:itm
  ::
  +|  %docs-for-arms
  ++  no-doc  ~
  ::
  :>  arm-doc
  ++  arm-adoc-pre  ~
  ::
  ++  arm-adoc-post  :<  arm-doc
    ~
  ::
  ++  arm-pdoc-pre
    :>  product-doc
    'foo'
  ++  arm-pdoc-post
    'foo'  :<  product-doc
  ::
  ++  arm-cdoc-pre
    |%
    :>  core-doc
    ++  $  ~
    --
  ::
  ++  arm-cdoc-post
    |%
    ++  $  :<  core-doc
      ~
    --
  ::
  :>  arm-doc
  ++  arm-adoc-pdoc-pre-pre
    :>  product-doc
    'foo'
  ::
  ++  arm-adoc-pdoc-post-pre  :<  arm-doc
    :>  product-doc
    'foo'
  ::
  ++  arm-adoc-pdoc-post-post  :<  arm-doc
    'foo'  :<  product-doc
  ::
  :>  arm-doc
  ++  arm-adoc-cdoc-pre-pre
    |%
    :>  core-doc
    ++  $  ~
    --
  ::
  ++  arm-adoc-cdoc-post-pre  :<  arm-doc
    |%
    :>  core-doc
    ++  $  ~
    --
  ::
  ++  arm-adoc-cdoc-post-post  :<  arm-doc
    |%
    ++  $  :<  core-doc
      ~
    --
  ::
  ++  arm-pdoc-cdoc-pre-pre
    :>  product-doc
    |%
    :>  core-doc
    ++  $  ~
    --
  ++  arm-pdoc-cdoc-post-pre
    |%
    :>  core-doc
    ++  $  ~
    --  :<  product-doc
  ::
  ++  arm-pdoc-cdoc-post-post
    |%
    ++  $  :<  core-doc
      ~
    --  :<  product-doc
  ::
  :>  arm-doc
  ++  arm-adoc-pdoc-cdoc-pre-pre-pre
    :>  product-doc
    |%
    :>  core-doc
    ++  $  ~
    --
  ::
  ++  arm-adoc-pdoc-cdoc-post-pre-pre  :<  arm-doc
    :>  product-doc
    |%
    :>  core-doc
    ++  $  ~
    --
  ::
  :>  arm-doc
  ++  arm-adoc-pdoc-cdoc-pre-post-pre
    |%
    :>  core-doc
    ++  $  ~
    --  :<  product-doc
  ::
  :>  arm-doc
  ++  arm-adoc-pdoc-cdoc-pre-pre-post
    :>  product-doc
    |%
    ++  $  :<  core-doc
      ~
    --
  ::
  ++  arm-adoc-pdoc-cdoc-post-post-pre  :<  arm-doc
    |%
    :>  core-doc
    ++  $  ~
    --  :<  product-doc
  ::
  ++  arm-adoc-pdoc-cdoc-post-pre-post  :<  arm-doc
    :>  product-doc
    |%
    ++  $  :<  core-doc
      ~
    --
  ::
  :>  arm-doc
  ++  arm-adoc-pdoc-cdoc-pre-post-post
    |%
    ++  $  :<  core-doc
      ~
    --  :<  product-doc
  ::
  ++  arm-adoc-pdoc-cdoc-post-post-post  :<  arm-doc
    |%
    ++  $  :<  core-doc
      ~
    --  :<  product-doc
  ::
  --
::
:>    contains the actual tests to be run by -test
|%  %dprint-tests
++  test-no-doc
  %+  expect-eq
    !>  ^-  arm-dox
    ["no-doc" *what *what *what]
  ::
    !>  (get-arm-dox ~[%no-doc])
::
++  test-adoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-pre" `['arm-doc' ~] *what *what]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-post" `['arm-doc' ~] *what *what]
    ::
      !>  (get-arm-dox ~[%arm-adoc-post])
  ==
::
++  test-pdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-pdoc-pre" *what `['product-doc' ~] *what]
    ::
      !>  (get-arm-dox ~[%arm-pdoc-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-pdoc-post" *what `['product-doc' ~] *what]
    ::
      !>  (get-arm-dox ~[%arm-pdoc-post])
  ==
::
++  test-cdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-cdoc-pre" *what *what `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-cdoc-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-cdoc-post" *what *what `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-cdoc-post])
  ==
::
++  test-adoc-pdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-pdoc-pre-pre" `['arm-doc' ~] `['product-doc' ~] *what]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-pre-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-pdoc-post-pre" `['arm-doc' ~] `['product-doc' ~] *what]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-post-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-pdoc-post-post" `['arm-doc' ~] `['product-doc' ~] *what]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-post-post])
  ==
::
++  test-adoc-cdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-cdoc-pre-pre" `['arm-doc' ~] *what `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-adoc-cdoc-pre-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-cdoc-post-pre" `['arm-doc' ~] *what `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-adoc-cdoc-post-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-adoc-cdoc-post-post" `['arm-doc' ~] *what `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-adoc-cdoc-post-post])
  ==
::
++  test-pdoc-cdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-pdoc-cdoc-pre-pre" *what `['product-doc' ~] `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-pdoc-cdoc-pre-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-pdoc-cdoc-post-pre" *what `['product-doc' ~] `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-pdoc-cdoc-post-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      ["arm-pdoc-cdoc-post-post" *what `['product-doc' ~] `['core-doc' ~]]
    ::
      !>  (get-arm-dox ~[%arm-pdoc-cdoc-post-post])
  ==
::
++  test-adoc-pdoc-cdoc
  ;:  weld
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-pre-pre-pre"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-pre-pre-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-post-pre-pre"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-post-pre-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-pre-post-pre"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-pre-post-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-pre-pre-post"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-pre-pre-post])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-post-post-pre"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-post-post-pre])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-post-pre-post"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-post-pre-post])
    ::
    %+  expect-eq
      !>  ^-  arm-dox
      :^    "arm-adoc-pdoc-cdoc-pre-post-post"
          `['arm-doc' ~]
        `['product-doc' ~]
      `['core-doc' ~]
    ::
      !>  (get-arm-dox ~[%arm-adoc-pdoc-cdoc-pre-post-post])
  ==
::
++  test-core
  %+  expect-eq
    !>  ^-  core-dox
    ["core-test" `['core-summary' ~[~[[%.y 'core-description']]]]]
  ::
    !>  (get-core-dox ~[%core-test])
::
++  test-chapter
  %+  expect-eq
    !>  ^-  chapter-dox
    ["chapter-test" `['chapter-summary' ~[~[[%.y 'chapter-description']]]]]
  ::
    !>  (get-chapter-dox ~[%core-test %chapter-test])
::
--