mirror of
https://github.com/zealdocs/zeal.git
synced 2024-09-11 14:25:52 +03:00
qmake: Remove qmake support
This commit is contained in:
parent
a5a66efbfa
commit
7d39f3fbb4
@ -1,5 +0,0 @@
|
||||
SRC_ROOT=$$PWD
|
||||
BUILD_ROOT=$$shadowed($$PWD)
|
||||
|
||||
ZEAL_COMMON_PRI = $$SRC_ROOT/qmake/common.pri
|
||||
ZEAL_LIBRARY_PRI = $$SRC_ROOT/qmake/library.pri
|
@ -1,23 +0,0 @@
|
||||
include($$ZEAL_COMMON_PRI)
|
||||
|
||||
TEMPLATE = aux
|
||||
|
||||
unix:!macx {
|
||||
TARGET = zeal
|
||||
appicons16.files=freedesktop/appicons/16/*
|
||||
appicons24.files=freedesktop/appicons/24/*
|
||||
appicons32.files=freedesktop/appicons/32/*
|
||||
appicons64.files=freedesktop/appicons/64/*
|
||||
appicons128.files=freedesktop/appicons/128/*
|
||||
|
||||
appicons16.path=$$PREFIX/share/icons/hicolor/16x16/apps
|
||||
appicons24.path=$$PREFIX/share/icons/hicolor/24x24/apps
|
||||
appicons32.path=$$PREFIX/share/icons/hicolor/32x32/apps
|
||||
appicons64.path=$$PREFIX/share/icons/hicolor/64x64/apps
|
||||
appicons128.path=$$PREFIX/share/icons/hicolor/128x128/apps
|
||||
|
||||
desktop.files=freedesktop/zeal.desktop
|
||||
desktop.path=$$PREFIX/share/applications
|
||||
|
||||
INSTALLS += appicons16 appicons24 appicons32 appicons64 appicons128 desktop
|
||||
}
|
@ -1,45 +0,0 @@
|
||||
# Shared build options
|
||||
#
|
||||
# This file must be included at the top of every non-subdirs .pro file.
|
||||
# Use:
|
||||
# include($$ZEAL_COMMON_PRI)
|
||||
|
||||
# Compilation settings
|
||||
CONFIG += c++11 silent
|
||||
|
||||
# Shared include path
|
||||
INCLUDEPATH += $$SRC_ROOT/src/libs
|
||||
LIBS = -L$$BUILD_ROOT/.lib
|
||||
|
||||
# QString options
|
||||
DEFINES *= QT_USE_QSTRINGBUILDER
|
||||
DEFINES *= QT_RESTRICTED_CAST_FROM_ASCII
|
||||
DEFINES *= QT_NO_CAST_TO_ASCII
|
||||
DEFINES *= QT_NO_URL_CAST_FROM_STRING
|
||||
|
||||
# Workaround for AppVeyor: Do not warn if the library had to be created.
|
||||
# Based on https://codereview.qt-project.org/150326
|
||||
win32-g++:lessThan(QT_VERSION, "5.6.0") {
|
||||
QMAKE_LIB = ar -rc
|
||||
}
|
||||
|
||||
# Keep build directory clean
|
||||
MOC_DIR = $$BUILD_ROOT/.moc
|
||||
OBJECTS_DIR = $$BUILD_ROOT/.obj
|
||||
RCC_DIR = $$BUILD_ROOT/.rcc
|
||||
UI_DIR = $$BUILD_ROOT/.ui
|
||||
|
||||
# Application version
|
||||
VERSION = 0.5.0
|
||||
DEFINES += ZEAL_VERSION=\\\"$${VERSION}\\\"
|
||||
|
||||
# Portable build
|
||||
CONFIG(zeal_portable) {
|
||||
message("Portable build: Yes.")
|
||||
DEFINES += PORTABLE_BUILD
|
||||
}
|
||||
|
||||
# Unix installation prefix
|
||||
unix:!macx {
|
||||
isEmpty(PREFIX): PREFIX = /usr
|
||||
}
|
@ -1,8 +0,0 @@
|
||||
include($$ZEAL_COMMON_PRI)
|
||||
include($$replace(_PRO_FILE_PWD_, ([^/]+$), \\1/\\1.pri))
|
||||
|
||||
TEMPLATE = lib
|
||||
CONFIG += staticlib
|
||||
|
||||
DESTDIR = $$BUILD_ROOT/.lib
|
||||
TARGET = $$ZEAL_LIB_NAME
|
@ -1,45 +0,0 @@
|
||||
include($$ZEAL_COMMON_PRI)
|
||||
|
||||
TEMPLATE = app
|
||||
|
||||
QT += gui widgets
|
||||
|
||||
SOURCES += \
|
||||
main.cpp
|
||||
|
||||
RESOURCES += \
|
||||
resources/zeal.qrc
|
||||
|
||||
DESTDIR = $$BUILD_ROOT/bin
|
||||
|
||||
unix:!macx {
|
||||
TARGET = zeal
|
||||
target.path = $$PREFIX/bin
|
||||
|
||||
INSTALLS += target
|
||||
}
|
||||
|
||||
win32 {
|
||||
TARGET = zeal
|
||||
RC_ICONS = resources/zeal.ico
|
||||
}
|
||||
|
||||
macx {
|
||||
TARGET = Zeal
|
||||
ICON = resources/zeal.icns
|
||||
}
|
||||
|
||||
# FIXME: Hardcoded link line & cyclic dependencies.
|
||||
LIBS += -lCore -lUi -lRegistry -lUtil
|
||||
|
||||
# Depend on all dependencies of libraries
|
||||
for(lib_dir, $$list($$files($$SRC_ROOT/src/libs/*))) {
|
||||
!equals(lib_dir, $$SRC_ROOT/src/libs/libs.pro) {
|
||||
exists($$lib_dir/$$basename(lib_dir).pri) {
|
||||
include($$lib_dir/$$basename(lib_dir).pri)
|
||||
msvc:PRE_TARGETDEPS += $$BUILD_ROOT/.lib/$${ZEAL_LIB_NAME}.$${QMAKE_EXTENSION_STATICLIB}
|
||||
else:PRE_TARGETDEPS += $$BUILD_ROOT/.lib/lib$${ZEAL_LIB_NAME}.$${QMAKE_EXTENSION_STATICLIB}
|
||||
# LIBS += -l$$ZEAL_LIB_NAME
|
||||
}
|
||||
}
|
||||
}
|
@ -1,11 +0,0 @@
|
||||
ZEAL_LIB_NAME = Core
|
||||
|
||||
QT += concurrent network webkit widgets
|
||||
|
||||
unix:!macx {
|
||||
CONFIG += link_pkgconfig
|
||||
PKGCONFIG += libarchive
|
||||
}
|
||||
win32: {
|
||||
LIBS += -larchive_static -lz
|
||||
}
|
@ -1,4 +0,0 @@
|
||||
include($$ZEAL_LIBRARY_PRI)
|
||||
|
||||
HEADERS += $$files(*.h)
|
||||
SOURCES += $$files(*.cpp)
|
@ -1,7 +0,0 @@
|
||||
TEMPLATE = subdirs
|
||||
|
||||
SUBDIRS += \
|
||||
core \
|
||||
registry \
|
||||
ui \
|
||||
util
|
@ -1,3 +0,0 @@
|
||||
ZEAL_LIB_NAME = Registry
|
||||
|
||||
QT += concurrent
|
@ -1,4 +0,0 @@
|
||||
include($$ZEAL_LIBRARY_PRI)
|
||||
|
||||
HEADERS += $$files(*.h)
|
||||
SOURCES += $$files(*.cpp)
|
@ -1,6 +0,0 @@
|
||||
HEADERS += $$files($$PWD/*.h)
|
||||
SOURCES += $$PWD/qxtglobalshortcut.cpp
|
||||
|
||||
unix:!macx:SOURCES += $$PWD/qxtglobalshortcut_x11.cpp
|
||||
win32:SOURCES += $$PWD/qxtglobalshortcut_win.cpp
|
||||
macx:SOURCES += $$PWD/qxtglobalshortcut_mac.cpp
|
@ -1,15 +0,0 @@
|
||||
ZEAL_LIB_NAME = Ui
|
||||
|
||||
QT += webkitwidgets
|
||||
|
||||
# QxtGlobalShortcut dependencies
|
||||
unix:!macx {
|
||||
QT += x11extras
|
||||
|
||||
CONFIG += link_pkgconfig
|
||||
PKGCONFIG += x11 xcb xcb-keysyms
|
||||
}
|
||||
|
||||
macx {
|
||||
LIBS += -framework Carbon
|
||||
}
|
@ -1,14 +0,0 @@
|
||||
include($$ZEAL_LIBRARY_PRI)
|
||||
|
||||
HEADERS += \
|
||||
$$files(*.h) \
|
||||
$$files(widgets/*.h)
|
||||
|
||||
SOURCES += \
|
||||
$$files(*.cpp) \
|
||||
$$files(widgets/*.cpp)
|
||||
|
||||
FORMS += \
|
||||
$$files(*.ui)
|
||||
|
||||
include(qxtglobalshortcut/qxtglobalshortcut.pri)
|
@ -1,9 +0,0 @@
|
||||
ZEAL_LIB_NAME = Util
|
||||
|
||||
unix:!macx {
|
||||
CONFIG += link_pkgconfig
|
||||
PKGCONFIG += sqlite3
|
||||
}
|
||||
win32: {
|
||||
LIBS += -lsqlite3
|
||||
}
|
@ -1,4 +0,0 @@
|
||||
include($$ZEAL_LIBRARY_PRI)
|
||||
|
||||
HEADERS += $$files(*.h)
|
||||
SOURCES += $$files(*.cpp)
|
10
src/src.pro
10
src/src.pro
@ -1,10 +0,0 @@
|
||||
TEMPLATE = subdirs
|
||||
|
||||
SUBDIRS += \
|
||||
app \
|
||||
libs
|
||||
|
||||
app.subdir = app
|
||||
libs.subdir = libs
|
||||
|
||||
app.depends = libs
|
22
zeal.pro
22
zeal.pro
@ -1,22 +0,0 @@
|
||||
#-------------------------------------------------
|
||||
#
|
||||
# Project created by QtCreator 2013-01-18T22:28:41
|
||||
#
|
||||
#-------------------------------------------------
|
||||
|
||||
lessThan(QT_VERSION, "5.5.1") {
|
||||
error("Qt 5.5.1 or above is required to build Zeal.")
|
||||
}
|
||||
|
||||
TEMPLATE = subdirs
|
||||
|
||||
SUBDIRS += \
|
||||
assets \
|
||||
src
|
||||
|
||||
# Ease access to these files from Qt Creator
|
||||
OTHER_FILES += \
|
||||
.gitignore \
|
||||
.qmake.conf \
|
||||
.shippable.yml \
|
||||
README.md
|
Loading…
Reference in New Issue
Block a user